theory LexerExt

  imports Main

begin

section {* Sequential Composition of Languages *}

definition

  Sequ :: "string set \<Rightarrow> string set \<Rightarrow> string set" ("_ ;; _" [100,100] 100)

where 

  "A ;; B = {s1 @ s2 | s1 s2. s1 \<in> A \<and> s2 \<in> B}"

text {* Two Simple Properties about Sequential Composition *}

lemma Sequ_empty [simp]:

  shows "A ;; {[]} = A"

  and   "{[]} ;; A = A"

by (simp_all add: Sequ_def)

lemma Sequ_null [simp]:

  shows "A ;; {} = {}"

  and   "{} ;; A = {}"

by (simp_all add: Sequ_def)

lemma Sequ_assoc: 

  shows "A ;; (B ;; C) = (A ;; B) ;; C"

apply(auto simp add: Sequ_def)

apply(metis append_assoc)

apply(metis)

done

lemma Sequ_UNION: 

  shows "(\<Union>x\<in>A. B ;; C x) = B ;; (\<Union>x\<in>A. C x)"

by (auto simp add: Sequ_def)

section {* Semantic Derivative (Left Quotient) of Languages *}

definition

  Der :: "char \<Rightarrow> string set \<Rightarrow> string set"

where

  "Der c A \<equiv> {s. c # s \<in> A}"

definition

  Ders :: "string \<Rightarrow> string set \<Rightarrow> string set"

where

  "Ders s A \<equiv> {s'. s @ s' \<in> A}"

lemma Der_null [simp]:

  shows "Der c {} = {}"

unfolding Der_def

by auto

lemma Der_empty [simp]:

  shows "Der c {[]} = {}"

unfolding Der_def

by auto

lemma Der_char [simp]:

  shows "Der c {[d]} = (if c = d then {[]} else {})"

unfolding Der_def

by auto

lemma Der_union [simp]:

  shows "Der c (A \<union> B) = Der c A \<union> Der c B"

unfolding Der_def

by auto

lemma Der_UNION: 

  shows "Der c (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. Der c (B x))"

by (auto simp add: Der_def)

section {* Power operation for Sets *}

fun 

  Pow :: "string set \<Rightarrow> nat \<Rightarrow> string set" ("_ \<up> _" [101, 102] 101)

where

   "A \<up> 0 = {[]}"

|  "A \<up> (Suc n) = A ;; (A \<up> n)"

lemma Pow_empty [simp]:

  shows "[] \<in> A \<up> n \<longleftrightarrow> (n = 0 \<or> [] \<in> A)"

by(induct n) (auto simp add: Sequ_def)

lemma Der_Pow [simp]:

  shows "Der c (A \<up> (Suc n)) = 

     (Der c A) ;; (A \<up> n) \<union> (if [] \<in> A then Der c (A \<up> n) else {})"

unfolding Der_def Sequ_def 

by(auto simp add: Cons_eq_append_conv Sequ_def)

lemma Der_Pow_subseteq:

  assumes "[] \<in> A"  

  shows "Der c (A \<up> n) \<subseteq> (Der c A) ;; (A \<up> n)"

using assms

apply(induct n)

apply(simp add: Sequ_def Der_def)

apply(simp)

apply(rule conjI)

apply (smt Sequ_def append_Nil2 mem_Collect_eq Sequ_assoc subsetI)

apply(subgoal_tac "((Der c A) ;; (A \<up> n)) \<subseteq> ((Der c A) ;; (A ;; (A \<up> n)))")

apply(auto)[1]

by (smt Sequ_def append_Nil2 mem_Collect_eq Sequ_assoc subsetI)

lemma test:

  shows "(\<Union>x\<le>Suc n. Der c (A \<up> x)) = (\<Union>x\<le>n. Der c A ;; A \<up> x)"

apply(induct n)

apply(simp)

apply(auto)[1]

apply(case_tac xa)

apply(simp)

apply(simp)

apply(auto)[1]

apply(case_tac "[] \<in> A")

apply(simp)

apply(simp)

by (smt Der_Pow Der_Pow_subseteq UN_insert atMost_Suc sup.orderE sup_bot.right_neutral)

lemma test2:

  shows "(\<Union>x\<in>(Suc ` A). Der c (B \<up> x)) = (\<Union>x\<in>A. Der c B ;; B \<up> x)"

apply(auto)[1]

apply(case_tac "[] \<in> B")

apply(simp)

using Der_Pow_subseteq apply blast

apply(simp)

done

section {* Kleene Star for Languages *}

definition 

  Star :: "string set \<Rightarrow> string set" ("_\<star>" [101] 102) where

  "A\<star> = (\<Union>n. A \<up> n)"

lemma Star_empty [intro]:

  shows "[] \<in> A\<star>"

unfolding Star_def

by auto

lemma Star_step [intro]:

  assumes "s1 \<in> A" "s2 \<in> A\<star>"

  shows "s1 @ s2 \<in> A\<star>"

proof -

  from assms obtain n where "s1 \<in>A" "s2 \<in> A \<up> n"

  unfolding Star_def by auto

  then have "s1 @ s2 \<in> A ;; (A \<up> n)"

  by (auto simp add: Sequ_def)

  then have "s1 @ s2 \<in> A \<up> (Suc n)"

  by simp

  then show "s1 @ s2 \<in> A\<star>" 

  unfolding Star_def 

  by (auto simp del: Pow.simps)

qed

lemma star_cases:

  shows "A\<star> = {[]} \<union> A ;; A\<star>"

unfolding Star_def

apply(simp add: Sequ_def)

apply(auto)

apply(case_tac xa)

apply(auto simp add: Sequ_def)

apply(rule_tac x="Suc xa" in exI)

apply(auto simp add: Sequ_def)

done

lemma Der_Star1:

  shows "Der c (A ;; A\<star>) = (Der c A) ;; A\<star>"

proof -

  have "(Der c A) ;; A\<star> = (Der c A) ;; (\<Union>n. A \<up> n)"

  unfolding Star_def by simp

  also have "... = (\<Union>n. Der c A ;; A \<up> n)"

  unfolding Sequ_UNION by simp

  also have "... = (\<Union>x\<in>(Suc ` UNIV). Der c (A \<up> x))"

  unfolding test2 by simp

  also have "... = (\<Union>n. Der c (A \<up> (Suc n)))"

  by (simp)

  also have "... = Der c (\<Union>n. A \<up> (Suc n))"

  unfolding Der_UNION by simp

  also have "... = Der c (A ;; (\<Union>n. A \<up> n))"

  by (simp only: Pow.simps Sequ_UNION)

  finally show "Der c (A ;; A\<star>) = (Der c A) ;; A\<star>"

  unfolding Star_def[symmetric] by blast 

qed

lemma Der_star [simp]:

  shows "Der c (A\<star>) = (Der c A) ;; A\<star>"

proof -    

  have "Der c (A\<star>) = Der c ({[]} \<union> A ;; A\<star>)"  

    by (simp only: star_cases[symmetric])

  also have "... = Der c (A ;; A\<star>)"

    by (simp only: Der_union Der_empty) (simp)

  also have "... =  (Der c A) ;; A\<star>"

    using Der_Star1 by simp

  finally show "Der c (A\<star>) = (Der c A) ;; A\<star>" .

qed

section {* Regular Expressions *}

datatype rexp =

  ZERO

| ONE

| CHAR char

| SEQ rexp rexp

| ALT rexp rexp

| STAR rexp

| UPNTIMES rexp nat

| NTIMES rexp nat

| FROMNTIMES rexp nat

| NMTIMES rexp nat nat

section {* Semantics of Regular Expressions *}

fun

  L :: "rexp \<Rightarrow> string set"

where

  "L (ZERO) = {}"

| "L (ONE) = {[]}"

| "L (CHAR c) = {[c]}"

| "L (SEQ r1 r2) = (L r1) ;; (L r2)"

| "L (ALT r1 r2) = (L r1) \<union> (L r2)"

| "L (STAR r) = (L r)\<star>"

| "L (UPNTIMES r n) = (\<Union>i\<in> {..n} . (L r) \<up> i)"

| "L (NTIMES r n) = (L r) \<up> n"

| "L (FROMNTIMES r n) = (\<Union>i\<in> {n..} . (L r) \<up> i)"

| "L (NMTIMES r n m) = (\<Union>i\<in>{n..m} . (L r) \<up> i)" 

section {* Nullable, Derivatives *}

fun

 nullable :: "rexp \<Rightarrow> bool"

where

  "nullable (ZERO) = False"

| "nullable (ONE) = True"

| "nullable (CHAR c) = False"

| "nullable (ALT r1 r2) = (nullable r1 \<or> nullable r2)"

| "nullable (SEQ r1 r2) = (nullable r1 \<and> nullable r2)"

| "nullable (STAR r) = True"

| "nullable (UPNTIMES r n) = True"

| "nullable (NTIMES r n) = (if n = 0 then True else nullable r)"

| "nullable (FROMNTIMES r n) = (if n = 0 then True else nullable r)"

| "nullable (NMTIMES r n m) = (if m < n then False else (if n = 0 then True else nullable r))"

fun

 der :: "char \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "der c (ZERO) = ZERO"

| "der c (ONE) = ZERO"

| "der c (CHAR d) = (if c = d then ONE else ZERO)"

| "der c (ALT r1 r2) = ALT (der c r1) (der c r2)"

| "der c (SEQ r1 r2) = 

     (if nullable r1

      then ALT (SEQ (der c r1) r2) (der c r2)

      else SEQ (der c r1) r2)"

| "der c (STAR r) = SEQ (der c r) (STAR r)"

| "der c (UPNTIMES r 0) = ZERO"

| "der c (UPNTIMES r (Suc n)) = SEQ (der c r) (UPNTIMES r n)"

| "der c (NTIMES r 0) = ZERO"

| "der c (NTIMES r (Suc n)) = SEQ (der c r) (NTIMES r n)"

| "der c (FROMNTIMES r 0) = SEQ (der c r) (FROMNTIMES r 0)"

| "der c (FROMNTIMES r (Suc n)) = SEQ (der c r) (FROMNTIMES r n)"

| "der c (NMTIMES r n m) = 

     (if m < n then ZERO 

      else (if n = 0 then (if m = 0 then ZERO else 

                           SEQ (der c r) (UPNTIMES r (m - 1))) else 

                           SEQ (der c r) (NMTIMES r (n - 1) (m - 1))))" 

fun 

 ders :: "string \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "ders [] r = r"

| "ders (c # s) r = ders s (der c r)"

lemma nullable_correctness:

  shows "nullable r  \<longleftrightarrow> [] \<in> (L r)"

apply(induct r) 

apply(auto simp add: Sequ_def) 

done

lemma Der_Pow_notin:

  assumes "[] \<notin> A"

  shows "Der c (A \<up> (Suc n)) = (Der c A) ;; (A \<up> n)"

using assms

by(simp)

lemma der_correctness:

  shows "L (der c r) = Der c (L r)"

apply(induct c r rule: der.induct) 

apply(simp_all add: nullable_correctness)[7]

apply(simp only: der.simps L.simps)

apply(simp only: Der_UNION)

apply(simp only: Sequ_UNION[symmetric])

apply(simp add: test)

apply(simp)

(* NTIMES *)

apply(simp only: L.simps der.simps)

apply(simp)

apply(rule impI)

apply (simp add: Der_Pow_subseteq sup_absorb1)

(* FROMNTIMES *)

apply(simp only: der.simps)

apply(simp only: L.simps)

apply(simp)

using Der_star Star_def apply auto[1]

apply(simp only: der.simps)

apply(simp only: L.simps)

apply(simp add: Der_UNION)

apply(subst Sequ_UNION[symmetric])

apply(subst test2[symmetric])

apply(subgoal_tac "(Suc ` {n..}) = {Suc n..}")

apply simp

apply(auto simp add: image_def)[1]

using Suc_le_D apply blast

(* NMTIMES *)

apply(case_tac "n \<le> m")

prefer 2

apply(simp only: der.simps if_True)

apply(simp only: L.simps)

apply(simp)

apply(auto)

apply(subst (asm) Sequ_UNION[symmetric])

apply(subst (asm) test[symmetric])

apply(auto simp add: Der_UNION)[1]

apply(auto simp add: Der_UNION)[1]

apply(subst Sequ_UNION[symmetric])

apply(subst test[symmetric])

apply(auto)[1]

apply(subst (asm) Sequ_UNION[symmetric])

apply(subst (asm) test2[symmetric])

apply(auto simp add: Der_UNION)[1]

apply(subst Sequ_UNION[symmetric])

apply(subst test2[symmetric])

apply(auto simp add: Der_UNION)[1]

done

lemma ders_correctness:

  shows "L (ders s r) = Ders s (L r)"

apply(induct s arbitrary: r)

apply(simp_all add: Ders_def der_correctness Der_def)

done

lemma ders_ZERO:

  shows "ders s (ZERO) = ZERO"

apply(induct s)

apply(simp_all)

done

lemma ders_ONE:

  shows "ders s (ONE) = (if s = [] then ONE else ZERO)"

apply(induct s)

apply(simp_all add: ders_ZERO)

done

lemma ders_CHAR:

  shows "ders s (CHAR c) = (if s = [c] then ONE else 

                           (if s = [] then (CHAR c) else ZERO))"

apply(induct s)

apply(simp_all add: ders_ZERO ders_ONE)

done

lemma  ders_ALT:

  shows "ders s (ALT r1 r2) = ALT (ders s r1) (ders s r2)"

apply(induct s arbitrary: r1 r2)

apply(simp_all)

done

section {* Values *}

datatype val = 

  Void

| Char char

| Seq val val

| Right val

| Left val

| Stars "val list"

section {* The string behind a value *}

fun 

  flat :: "val \<Rightarrow> string"

where

  "flat (Void) = []"

| "flat (Char c) = [c]"

| "flat (Left v) = flat v"

| "flat (Right v) = flat v"

| "flat (Seq v1 v2) = (flat v1) @ (flat v2)"

| "flat (Stars []) = []"

| "flat (Stars (v#vs)) = (flat v) @ (flat (Stars vs))" 

lemma flat_Stars [simp]:

 "flat (Stars vs) = concat (map flat vs)"

by (induct vs) (auto)

section {* Relation between values and regular expressions *}

inductive 

  Prf :: "val \<Rightarrow> rexp \<Rightarrow> bool" ("\<turnstile> _ : _" [100, 100] 100)

where

 "\<lbrakk>\<turnstile> v1 : r1; \<turnstile> v2 : r2\<rbrakk> \<Longrightarrow> \<turnstile> Seq v1 v2 : SEQ r1 r2"

| "\<turnstile> v1 : r1 \<Longrightarrow> \<turnstile> Left v1 : ALT r1 r2"

| "\<turnstile> v2 : r2 \<Longrightarrow> \<turnstile> Right v2 : ALT r1 r2"

| "\<turnstile> Void : ONE"

| "\<turnstile> Char c : CHAR c"

| "\<lbrakk>\<forall>v \<in> set vs. \<turnstile> v : r\<rbrakk> \<Longrightarrow> \<turnstile> Stars vs : STAR r"

| "\<lbrakk>\<forall>v \<in> set vs. \<turnstile> v : r; length vs \<le> n\<rbrakk> \<Longrightarrow> \<turnstile> Stars vs : UPNTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs. \<turnstile> v : r; length vs = n\<rbrakk> \<Longrightarrow> \<turnstile> Stars vs : NTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs. \<turnstile> v : r; length vs \<ge> n\<rbrakk> \<Longrightarrow> \<turnstile> Stars vs : FROMNTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs. \<turnstile> v : r; length vs \<ge> n; length vs \<le> m\<rbrakk> \<Longrightarrow> \<turnstile> Stars vs : NMTIMES r n m"

inductive_cases Prf_elims:

  "\<turnstile> v : ZERO"

  "\<turnstile> v : SEQ r1 r2"

  "\<turnstile> v : ALT r1 r2"

  "\<turnstile> v : ONE"

  "\<turnstile> v : CHAR c"

(*  "\<turnstile> vs : STAR r"*)

lemma Prf_STAR:

   assumes "\<forall>v\<in>set vs. \<turnstile> v : r \<and> flat v \<in> L r"  

   shows "concat (map flat vs) \<in> L r\<star>"

using assms 

apply(induct vs)

apply(auto)

done

lemma Prf_Pow:

  assumes "\<forall>v\<in>set vs. \<turnstile> v : r \<and> flat v \<in> L r" 

  shows "concat (map flat vs) \<in> L r \<up> length vs"

using assms

apply(induct vs)

apply(auto simp add: Sequ_def)

done

lemma Prf_flat_L:

  assumes "\<turnstile> v : r" shows "flat v \<in> L r"

using assms

apply(induct v r rule: Prf.induct)

apply(auto simp add: Sequ_def)

apply(rule Prf_STAR)

apply(simp)

apply(rule_tac x="length vs" in bexI)

apply(rule Prf_Pow)

apply(simp)

apply(simp)

apply(rule Prf_Pow)

apply(simp)

apply(rule_tac x="length vs" in bexI)

apply(rule Prf_Pow)

apply(simp)

apply(simp)

apply(rule_tac x="length vs" in bexI)

apply(rule Prf_Pow)

apply(simp)

apply(simp)

done

lemma Star_Pow:

  assumes "s \<in> A \<up> n"

  shows "\<exists>ss. concat ss = s \<and> (\<forall>s \<in> set ss. s \<in> A) \<and> (length ss = n)"

using assms

apply(induct n arbitrary: s)

apply(auto simp add: Sequ_def)

apply(drule_tac x="s2" in meta_spec)

apply(auto)

apply(rule_tac x="s1#ss" in exI)

apply(simp)

done

lemma Star_string:

  assumes "s \<in> A\<star>"

  shows "\<exists>ss. concat ss = s \<and> (\<forall>s \<in> set ss. s \<in> A)"

using assms

apply(auto simp add: Star_def)

using Star_Pow by blast

lemma Star_val:

  assumes "\<forall>s\<in>set ss. \<exists>v. s = flat v \<and> \<turnstile> v : r"

  shows "\<exists>vs. concat (map flat vs) = concat ss \<and> (\<forall>v\<in>set vs. \<turnstile> v : r)"

using assms

apply(induct ss)