theory Re

  imports "Main" 

begin

section {* Sequential Composition of Sets *}

definition

  Sequ :: "string set \<Rightarrow> string set \<Rightarrow> string set" ("_ ;; _" [100,100] 100)

where 

  "A ;; B = {s1 @ s2 | s1 s2. s1 \<in> A \<and> s2 \<in> B}"

fun spow where

  "spow s 0 = []"

| "spow s (Suc n) = s @ spow s n"

text {* Two Simple Properties about Sequential Composition *}

lemma seq_empty [simp]:

  shows "A ;; {[]} = A"

  and   "{[]} ;; A = A"

by (simp_all add: Sequ_def)

lemma seq_null [simp]:

  shows "A ;; {} = {}"

  and   "{} ;; A = {}"

by (simp_all add: Sequ_def)

lemma seq_image:

  assumes "\<forall>s1 s2. f (s1 @ s2) = (f s1) @ (f s2)"

  shows "f ` (A ;; B) = (f ` A) ;; (f ` B)"

apply(auto simp add: Sequ_def image_def)

apply(rule_tac x="f s1" in exI)

apply(rule_tac x="f s2" in exI)

using assms

apply(auto)

apply(rule_tac x="xa @ xb" in exI)

using assms

apply(auto)

done

section {* Kleene Star for Sets *}

inductive_set

  Star :: "string set \<Rightarrow> string set" ("_\<star>" [101] 102)

  for A :: "string set"

where

  start[intro]: "[] \<in> A\<star>"

| step[intro]:  "\<lbrakk>s1 \<in> A; s2 \<in> A\<star>\<rbrakk> \<Longrightarrow> s1 @ s2 \<in> A\<star>"

fun 

  pow :: "string set \<Rightarrow> nat \<Rightarrow> string set" ("_ \<up> _" [100,100] 100)

where

  "A \<up> 0 = {[]}"

| "A \<up> (Suc n) = A ;; (A \<up> n)"  

lemma star1: 

  shows "s \<in> A\<star> \<Longrightarrow> \<exists>n. s \<in> A \<up> n"

  apply(induct rule: Star.induct)

  apply (metis Re.pow.simps(1) insertI1)

  apply(auto)

  apply(rule_tac x="Suc n" in exI)

  apply(auto simp add: Sequ_def)

  done

lemma star2:

  shows "s \<in> A \<up> n \<Longrightarrow> s \<in> A\<star>"

  apply(induct n arbitrary: s)

  apply (metis Re.pow.simps(1) Star.simps empty_iff insertE)

  apply(auto simp add: Sequ_def)

  done

lemma star3:

  shows "A\<star> = (\<Union>i. A \<up> i)"

using star1 star2

apply(auto)

done

lemma star4:

  shows "s \<in> A \<up> n \<Longrightarrow> \<exists>ss. s = concat ss \<and> (\<forall>s' \<in> set ss. s' \<in> A)"

  apply(induct n arbitrary: s)

  apply(auto simp add: Sequ_def)

  apply(rule_tac x="[]" in exI)

  apply(auto)

  apply(drule_tac x="s2" in meta_spec)

  apply(auto)

by (metis concat.simps(2) insertE set_simps(2))

lemma star5:

  assumes "f [] = []"

  assumes "\<forall>s1 s2. f (s1 @ s2) = (f s1) @ (f s2)"

  shows "(f ` A) \<up> n = f ` (A \<up> n)"

apply(induct n)

apply(simp add: assms)

apply(simp)

apply(subst seq_image[OF assms(2)])

apply(simp)

done

lemma star6:

  assumes "f [] = []"

  assumes "\<forall>s1 s2. f (s1 @ s2) = (f s1) @ (f s2)"

  shows "(f ` A)\<star> = f ` (A\<star>)"

apply(simp add: star3)

apply(simp add: image_UN)

apply(subst star5[OF assms])

apply(simp)

done

lemma star_decomp: 

  assumes a: "c # x \<in> A\<star>" 

  shows "\<exists>a b. x = a @ b \<and> c # a \<in> A \<and> b \<in> A\<star>"

using a

by (induct x\<equiv>"c # x" rule: Star.induct) 

   (auto simp add: append_eq_Cons_conv)

section {* Regular Expressions *}

datatype rexp =

  NULL

| EMPTY

| CHAR char

| SEQ rexp rexp

| ALT rexp rexp

| STAR rexp

section {* Semantics of Regular Expressions *}

fun

  L :: "rexp \<Rightarrow> string set"

where

  "L (NULL) = {}"

| "L (EMPTY) = {[]}"

| "L (CHAR c) = {[c]}"

| "L (SEQ r1 r2) = (L r1) ;; (L r2)"

| "L (ALT r1 r2) = (L r1) \<union> (L r2)"

| "L (STAR r) = (L r)\<star>"

fun

 nullable :: "rexp \<Rightarrow> bool"

where

  "nullable (NULL) = False"

| "nullable (EMPTY) = True"

| "nullable (CHAR c) = False"

| "nullable (ALT r1 r2) = (nullable r1 \<or> nullable r2)"

| "nullable (SEQ r1 r2) = (nullable r1 \<and> nullable r2)"

| "nullable (STAR r1) = True"

lemma nullable_correctness:

  shows "nullable r  \<longleftrightarrow> [] \<in> (L r)"

apply (induct r) 

apply(auto simp add: Sequ_def) 

done

section {* Values *}

datatype val = 

  Void

| Char char

| Seq val val

| Right val

| Left val

| Star "val list"

section {* The string behind a value *}

fun 

  flat :: "val \<Rightarrow> string"

where

  "flat (Void) = []"

| "flat (Char c) = [c]"

| "flat (Left v) = flat v"

| "flat (Right v) = flat v"

| "flat (Seq v1 v2) = (flat v1) @ (flat v2)"

| "flat (Star []) = []"

| "flat (Star (v#vs)) = (flat v) @ (flat (Star vs))" 

section {* Relation between values and regular expressions *}

inductive 

  Prf :: "val \<Rightarrow> rexp \<Rightarrow> bool" ("\<turnstile> _ : _" [100, 100] 100)

where

 "\<lbrakk>\<turnstile> v1 : r1; \<turnstile> v2 : r2\<rbrakk> \<Longrightarrow> \<turnstile> Seq v1 v2 : SEQ r1 r2"

| "\<turnstile> v1 : r1 \<Longrightarrow> \<turnstile> Left v1 : ALT r1 r2"

| "\<turnstile> v2 : r2 \<Longrightarrow> \<turnstile> Right v2 : ALT r1 r2"

| "\<turnstile> Void : EMPTY"

| "\<turnstile> Char c : CHAR c"

| "\<turnstile> Star [] : STAR r"

| "\<lbrakk>\<turnstile> v : r; \<turnstile> Star vs : STAR r\<rbrakk> \<Longrightarrow> \<turnstile> Star (v#vs) : STAR r"

lemma not_nullable_flat:

  assumes "\<turnstile> v : r" "\<not>nullable r"

  shows "flat v \<noteq> []"

using assms

apply(induct)

apply(auto)

done

lemma Prf_flat_L:

  assumes "\<turnstile> v : r" shows "flat v \<in> L r"

using assms

apply(induct v r rule: Prf.induct)

apply(auto simp add: Sequ_def)

done

lemma Prf_Star_flat_L:

  assumes "\<turnstile> v : STAR r" shows "flat v \<in> (L r)\<star>"

using assms

apply(induct v r\<equiv>"STAR r" arbitrary: r rule: Prf.induct)

apply(auto)

apply(simp add: star3)

apply(auto)

apply(rule_tac x="Suc x" in exI)

apply(auto simp add: Sequ_def)

apply(rule_tac x="flat v" in exI)

apply(rule_tac x="flat (Star vs)" in exI)

apply(auto)

by (metis Prf_flat_L)

lemma L_flat_Prf:

  "L(r) = {flat v | v. \<turnstile> v : r}"

apply(induct r)

apply(auto dest: Prf_flat_L simp add: Sequ_def)

apply (metis Prf.intros(4) flat.simps(1))

apply (metis Prf.intros(5) flat.simps(2))

apply (metis Prf.intros(1) flat.simps(5))

apply (metis Prf.intros(2) flat.simps(3))

apply (metis Prf.intros(3) flat.simps(4))

apply(erule Prf.cases)

apply(auto)

apply(simp add: star3)

apply(auto)

sorry

section {* Greedy Ordering according to Frisch/Cardelli *}

inductive 

  GrOrd :: "val \<Rightarrow> val \<Rightarrow> bool" ("_ gr\<succ> _")

where 

  "v1 gr\<succ> v1' \<Longrightarrow> (Seq v1 v2) gr\<succ> (Seq v1' v2')"

| "v2 gr\<succ> v2' \<Longrightarrow> (Seq v1 v2) gr\<succ> (Seq v1 v2')"

| "v1 gr\<succ> v2 \<Longrightarrow> (Left v1) gr\<succ> (Left v2)"

| "v1 gr\<succ> v2 \<Longrightarrow> (Right v1) gr\<succ> (Right v2)"

| "(Left v2) gr\<succ>(Right v1)"

| "(Char c) gr\<succ> (Char c)"

| "(Void) gr\<succ> (Void)"

lemma Gr_refl:

  assumes "\<turnstile> v : r"

  shows "v gr\<succ> v"

using assms

apply(induct)

apply(auto intro: GrOrd.intros)

done

lemma Gr_total:

  assumes "\<turnstile> v1 : r" "\<turnstile> v2 : r"

  shows "v1 gr\<succ> v2 \<or> v2 gr\<succ> v1"

using assms

apply(induct v1 r arbitrary: v2 rule: Prf.induct)

apply(rotate_tac 4)

apply(erule Prf.cases)

apply(simp_all)[5]

apply(clarify)

apply (metis GrOrd.intros(1) GrOrd.intros(2))

apply(rotate_tac 2)

apply(erule Prf.cases)

apply(simp_all)

apply(clarify)

apply (metis GrOrd.intros(3))

apply(clarify)

apply (metis GrOrd.intros(5))

apply(rotate_tac 2)

apply(erule Prf.cases)

apply(simp_all)

apply(clarify)

apply (metis GrOrd.intros(5))

apply(clarify)

apply (metis GrOrd.intros(4))

apply(erule Prf.cases)

apply(simp_all)

apply (metis GrOrd.intros(7))

apply(erule Prf.cases)

apply(simp_all)

apply (metis GrOrd.intros(6))

done

lemma Gr_trans: 

  assumes "v1 gr\<succ> v2" "v2 gr\<succ> v3" 

  and     "\<turnstile> v1 : r" "\<turnstile> v2 : r" "\<turnstile> v3 : r"

  shows "v1 gr\<succ> v3"

using assms

apply(induct r arbitrary: v1 v2 v3)

apply(erule Prf.cases)

apply(simp_all)[5]

apply(erule Prf.cases)

apply(simp_all)[5]

apply(erule Prf.cases)

apply(simp_all)[5]

apply(erule Prf.cases)

apply(simp_all)[5]

apply(erule Prf.cases)

apply(simp_all)[5]

defer

(* ALT case *)

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply (metis GrOrd.intros(3))

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply (metis GrOrd.intros(5))

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply (metis GrOrd.intros(5))

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply (metis GrOrd.intros(4))

(* SEQ case *)

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(erule Prf.cases)

apply(simp_all (no_asm_use))[5]

apply(clarify)

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply(clarify)

apply (metis GrOrd.intros(1))

apply (metis GrOrd.intros(1))

apply(erule GrOrd.cases)

apply(simp_all (no_asm_use))[7]

apply (metis GrOrd.intros(1))

by (metis GrOrd.intros(1) Gr_refl)

section {* Values Sets *}

definition prefix :: "string \<Rightarrow> string \<Rightarrow> bool" ("_ \<sqsubseteq> _" [100, 100] 100)

where

  "s1 \<sqsubseteq> s2 \<equiv> \<exists>s3. s1 @ s3 = s2"

definition sprefix :: "string \<Rightarrow> string \<Rightarrow> bool" ("_ \<sqsubset> _" [100, 100] 100)

where

  "s1 \<sqsubset> s2 \<equiv> (s1 \<sqsubseteq> s2 \<and> s1 \<noteq> s2)"

lemma length_sprefix:

  "s1 \<sqsubset> s2 \<Longrightarrow> length s1 < length s2"

unfolding sprefix_def prefix_def

by (auto)

definition Prefixes :: "string \<Rightarrow> string set" where

  "Prefixes s \<equiv> {sp. sp \<sqsubseteq> s}"

definition Suffixes :: "string \<Rightarrow> string set" where

  "Suffixes s \<equiv> rev ` (Prefixes (rev s))"

lemma Suffixes_in: 

  "\<exists>s1. s1 @ s2 = s3 \<Longrightarrow> s2 \<in> Suffixes s3"

unfolding Suffixes_def Prefixes_def prefix_def image_def

apply(auto)

by (metis rev_rev_ident)

lemma Prefixes_Cons:

  "Prefixes (c # s) = {[]} \<union> {c # sp | sp. sp \<in> Prefixes s}"

unfolding Prefixes_def prefix_def

apply(auto simp add: append_eq_Cons_conv) 

done

lemma finite_Prefixes:

  "finite (Prefixes s)"

apply(induct s)

apply(auto simp add: Prefixes_def prefix_def)[1]

apply(simp add: Prefixes_Cons)

done

lemma finite_Suffixes:

  "finite (Suffixes s)"

unfolding Suffixes_def

apply(rule finite_imageI)

apply(rule finite_Prefixes)

done

lemma prefix_Cons:

  "((c # s1) \<sqsubseteq> (c # s2)) = (s1 \<sqsubseteq> s2)"

apply(auto simp add: prefix_def)

done

lemma prefix_append:

  "((s @ s1) \<sqsubseteq> (s @ s2)) = (s1 \<sqsubseteq> s2)"

apply(induct s)

apply(simp)

apply(simp add: prefix_Cons)

done

definition Values :: "rexp \<Rightarrow> string \<Rightarrow> val set" where

  "Values r s \<equiv> {v. \<turnstile> v : r \<and> flat v \<sqsubseteq> s}"

definition rest :: "val \<Rightarrow> string \<Rightarrow> string" where

  "rest v s \<equiv> drop (length (flat v)) s"

lemma rest_Suffixes:

  "rest v s \<in> Suffixes s"

unfolding rest_def

by (metis Suffixes_in append_take_drop_id)

lemma Values_recs:

  "Values (NULL) s = {}"

  "Values (EMPTY) s = {Void}"

  "Values (CHAR c) s = (if [c] \<sqsubseteq> s then {Char c} else {})" 

  "Values (ALT r1 r2) s = {Left v | v. v \<in> Values r1 s} \<union> {Right v | v. v \<in> Values r2 s}"

  "Values (SEQ r1 r2) s = {Seq v1 v2 | v1 v2. v1 \<in> Values r1 s \<and> v2 \<in> Values r2 (rest v1 s)}"

unfolding Values_def

apply(auto)

(*NULL*)

apply(erule Prf.cases)

apply(simp_all)[5]

(*EMPTY*)

apply(erule Prf.cases)

apply(simp_all)[5]

apply(rule Prf.intros)

apply (metis append_Nil prefix_def)

(*CHAR*)

apply(erule Prf.cases)

apply(simp_all)[5]

apply(rule Prf.intros)

apply(erule Prf.cases)

apply(simp_all)[5]

(*ALT*)

apply(erule Prf.cases)

apply(simp_all)[5]

apply (metis Prf.intros(2))

apply (metis Prf.intros(3))

(*SEQ*)

apply(erule Prf.cases)

apply(simp_all)[5]

apply (simp add: append_eq_conv_conj prefix_def rest_def)

apply (metis Prf.intros(1))

apply (simp add: append_eq_conv_conj prefix_def rest_def)

done

lemma Values_finite:

  "finite (Values r s)"

apply(induct r arbitrary: s)

apply(simp_all add: Values_recs)

thm finite_surj

apply(rule_tac f="\<lambda>(x, y). Seq x y" and 

               A="{(v1, v2) | v1 v2. v1 \<in> Values r1 s \<and> v2 \<in> Values r2 (rest v1 s)}" in finite_surj)

prefer 2

apply(auto)[1]

apply(rule_tac B="\<Union>sp \<in> Suffixes s. {(v1, v2). v1 \<in> Values r1 s \<and> v2 \<in> Values r2 sp}" in finite_subset)

apply(auto)[1]

apply (metis rest_Suffixes)

apply(rule finite_UN_I)

apply(rule finite_Suffixes)

apply(simp)

done

section {* Sulzmann functions *}

fun 

  mkeps :: "rexp \<Rightarrow> val"

where

  "mkeps(EMPTY) = Void"

| "mkeps(SEQ r1 r2) = Seq (mkeps r1) (mkeps r2)"

| "mkeps(ALT r1 r2) = (if nullable(r1) then Left (mkeps r1) else Right (mkeps r2))"

section {* Derivatives *}

fun

 der :: "char \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "der c (NULL) = NULL"

| "der c (EMPTY) = NULL"

| "der c (CHAR c') = (if c = c' then EMPTY else NULL)"

| "der c (ALT r1 r2) = ALT (der c r1) (der c r2)"

| "der c (SEQ r1 r2) = 

     (if nullable r1

      then ALT (SEQ (der c r1) r2) (der c r2)

      else SEQ (der c r1) r2)"

fun 

 ders :: "string \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "ders [] r = r"