theory Myhill_1
imports Main Folds While_Combinator
begin
section {* Preliminary definitions *}
types lang = "string set"
text {* Sequential composition of two languages *}
definition
Seq :: "lang \<Rightarrow> lang \<Rightarrow> lang" (infixr ";;" 100)
where
"A ;; B = {s\<^isub>1 @ s\<^isub>2 | s\<^isub>1 s\<^isub>2. s\<^isub>1 \<in> A \<and> s\<^isub>2 \<in> B}"
text {* Some properties of operator @{text ";;"}. *}
lemma seq_add_left:
assumes a: "A = B"
shows "C ;; A = C ;; B"
using a by simp
lemma seq_union_distrib_right:
shows "(A \<union> B) ;; C = (A ;; C) \<union> (B ;; C)"
unfolding Seq_def by auto
lemma seq_union_distrib_left:
shows "C ;; (A \<union> B) = (C ;; A) \<union> (C ;; B)"
unfolding Seq_def by auto
lemma seq_intro:
assumes a: "x \<in> A" "y \<in> B"
shows "x @ y \<in> A ;; B "
using a by (auto simp: Seq_def)
lemma seq_assoc:
shows "(A ;; B) ;; C = A ;; (B ;; C)"
unfolding Seq_def
apply(auto)
apply(blast)
by (metis append_assoc)
lemma seq_empty [simp]:
shows "A ;; {[]} = A"
and "{[]} ;; A = A"
by (simp_all add: Seq_def)
text {* Power and Star of a language *}
fun
pow :: "lang \<Rightarrow> nat \<Rightarrow> lang" (infixl "\<up>" 100)
where
"A \<up> 0 = {[]}"
| "A \<up> (Suc n) = A ;; (A \<up> n)"
definition
Star :: "lang \<Rightarrow> lang" ("_\<star>" [101] 102)
where
"A\<star> \<equiv> (\<Union>n. A \<up> n)"
lemma star_start[intro]:
shows "[] \<in> A\<star>"
proof -
have "[] \<in> A \<up> 0" by auto
then show "[] \<in> A\<star>" unfolding Star_def by blast
qed
lemma star_step [intro]:
assumes a: "s1 \<in> A"
and b: "s2 \<in> A\<star>"
shows "s1 @ s2 \<in> A\<star>"
proof -
from b obtain n where "s2 \<in> A \<up> n" unfolding Star_def by auto
then have "s1 @ s2 \<in> A \<up> (Suc n)" using a by (auto simp add: Seq_def)
then show "s1 @ s2 \<in> A\<star>" unfolding Star_def by blast
qed
lemma star_induct[consumes 1, case_names start step]:
assumes a: "x \<in> A\<star>"
and b: "P []"
and c: "\<And>s1 s2. \<lbrakk>s1 \<in> A; s2 \<in> A\<star>; P s2\<rbrakk> \<Longrightarrow> P (s1 @ s2)"
shows "P x"
proof -
from a obtain n where "x \<in> A \<up> n" unfolding Star_def by auto
then show "P x"
by (induct n arbitrary: x)
(auto intro!: b c simp add: Seq_def Star_def)
qed
lemma star_intro1:
assumes a: "x \<in> A\<star>"
and b: "y \<in> A\<star>"
shows "x @ y \<in> A\<star>"
using a b
by (induct rule: star_induct) (auto)
lemma star_intro2:
assumes a: "y \<in> A"
shows "y \<in> A\<star>"
proof -
from a have "y @ [] \<in> A\<star>" by blast
then show "y \<in> A\<star>" by simp
qed
lemma star_intro3:
assumes a: "x \<in> A\<star>"
and b: "y \<in> A"
shows "x @ y \<in> A\<star>"
using a b by (blast intro: star_intro1 star_intro2)
lemma star_cases:
shows "A\<star> = {[]} \<union> A ;; A\<star>"
proof
{ fix x
have "x \<in> A\<star> \<Longrightarrow> x \<in> {[]} \<union> A ;; A\<star>"
unfolding Seq_def
by (induct rule: star_induct) (auto)
}
then show "A\<star> \<subseteq> {[]} \<union> A ;; A\<star>" by auto
next
show "{[]} \<union> A ;; A\<star> \<subseteq> A\<star>"
unfolding Seq_def by auto
qed
lemma star_decom:
assumes a: "x \<in> A\<star>" "x \<noteq> []"
shows "\<exists>a b. x = a @ b \<and> a \<noteq> [] \<and> a \<in> A \<and> b \<in> A\<star>"
using a
by (induct rule: star_induct) (blast)+
lemma
shows seq_Union_left: "B ;; (\<Union>n. A \<up> n) = (\<Union>n. B ;; (A \<up> n))"
and seq_Union_right: "(\<Union>n. A \<up> n) ;; B = (\<Union>n. (A \<up> n) ;; B)"
unfolding Seq_def by auto
lemma seq_pow_comm:
shows "A ;; (A \<up> n) = (A \<up> n) ;; A"
by (induct n) (simp_all add: seq_assoc[symmetric])
lemma seq_star_comm:
shows "A ;; A\<star> = A\<star> ;; A"
unfolding Star_def seq_Union_left
unfolding seq_pow_comm seq_Union_right
by simp
text {* Two lemmas about the length of strings in @{text "A \<up> n"} *}
lemma pow_length:
assumes a: "[] \<notin> A"
and b: "s \<in> A \<up> Suc n"
shows "n < length s"
using b
proof (induct n arbitrary: s)
case 0
have "s \<in> A \<up> Suc 0" by fact
with a have "s \<noteq> []" by auto
then show "0 < length s" by auto
next
case (Suc n)
have ih: "\<And>s. s \<in> A \<up> Suc n \<Longrightarrow> n < length s" by fact
have "s \<in> A \<up> Suc (Suc n)" by fact
then obtain s1 s2 where eq: "s = s1 @ s2" and *: "s1 \<in> A" and **: "s2 \<in> A \<up> Suc n"
by (auto simp add: Seq_def)
from ih ** have "n < length s2" by simp
moreover have "0 < length s1" using * a by auto
ultimately show "Suc n < length s" unfolding eq
by (simp only: length_append)
qed
lemma seq_pow_length:
assumes a: "[] \<notin> A"
and b: "s \<in> B ;; (A \<up> Suc n)"
shows "n < length s"
proof -
from b obtain s1 s2 where eq: "s = s1 @ s2" and *: "s2 \<in> A \<up> Suc n"
unfolding Seq_def by auto
from * have " n < length s2" by (rule pow_length[OF a])
then show "n < length s" using eq by simp
qed
section {* A modified version of Arden's lemma *}
text {* A helper lemma for Arden *}
lemma arden_helper:
assumes eq: "X = X ;; A \<union> B"
shows "X = X ;; (A \<up> Suc n) \<union> (\<Union>m\<in>{0..n}. B ;; (A \<up> m))"
proof (induct n)
case 0
show "X = X ;; (A \<up> Suc 0) \<union> (\<Union>(m::nat)\<in>{0..0}. B ;; (A \<up> m))"
using eq by simp
next
case (Suc n)
have ih: "X = X ;; (A \<up> Suc n) \<union> (\<Union>m\<in>{0..n}. B ;; (A \<up> m))" by fact
also have "\<dots> = (X ;; A \<union> B) ;; (A \<up> Suc n) \<union> (\<Union>m\<in>{0..n}. B ;; (A \<up> m))" using eq by simp
also have "\<dots> = X ;; (A \<up> Suc (Suc n)) \<union> (B ;; (A \<up> Suc n)) \<union> (\<Union>m\<in>{0..n}. B ;; (A \<up> m))"
by (simp add: seq_union_distrib_right seq_assoc)
also have "\<dots> = X ;; (A \<up> Suc (Suc n)) \<union> (\<Union>m\<in>{0..Suc n}. B ;; (A \<up> m))"
by (auto simp add: le_Suc_eq)
finally show "X = X ;; (A \<up> Suc (Suc n)) \<union> (\<Union>m\<in>{0..Suc n}. B ;; (A \<up> m))" .
qed
theorem arden:
assumes nemp: "[] \<notin> A"
shows "X = X ;; A \<union> B \<longleftrightarrow> X = B ;; A\<star>"
proof
assume eq: "X = B ;; A\<star>"
have "A\<star> = {[]} \<union> A\<star> ;; A"
unfolding seq_star_comm[symmetric]
by (rule star_cases)
then have "B ;; A\<star> = B ;; ({[]} \<union> A\<star> ;; A)"
by (rule seq_add_left)
also have "\<dots> = B \<union> B ;; (A\<star> ;; A)"
unfolding seq_union_distrib_left by simp
also have "\<dots> = B \<union> (B ;; A\<star>) ;; A"
by (simp only: seq_assoc)
finally show "X = X ;; A \<union> B"
using eq by blast
next
assume eq: "X = X ;; A \<union> B"
{ fix n::nat
have "B ;; (A \<up> n) \<subseteq> X" using arden_helper[OF eq, of "n"] by auto }
then have "B ;; A\<star> \<subseteq> X"
unfolding Seq_def Star_def UNION_def by auto
moreover
{ fix s::string
obtain k where "k = length s" by auto
then have not_in: "s \<notin> X ;; (A \<up> Suc k)"
using seq_pow_length[OF nemp] by blast
assume "s \<in> X"
then have "s \<in> X ;; (A \<up> Suc k) \<union> (\<Union>m\<in>{0..k}. B ;; (A \<up> m))"
using arden_helper[OF eq, of "k"] by auto
then have "s \<in> (\<Union>m\<in>{0..k}. B ;; (A \<up> m))" using not_in by auto
moreover
have "(\<Union>m\<in>{0..k}. B ;; (A \<up> m)) \<subseteq> (\<Union>n. B ;; (A \<up> n))" by auto
ultimately
have "s \<in> B ;; A\<star>"
unfolding seq_Union_left Star_def by auto }
then have "X \<subseteq> B ;; A\<star>" by auto
ultimately
show "X = B ;; A\<star>" by simp
qed
section {* Regular Expressions *}
datatype rexp =
NULL
| EMPTY
| CHAR char
| SEQ rexp rexp
| ALT rexp rexp
| STAR rexp
text {*
The function @{text L} is overloaded, with the idea that @{text "L x"}
evaluates to the language represented by the object @{text x}.
*}
consts L:: "'a \<Rightarrow> lang"
overloading L_rexp \<equiv> "L:: rexp \<Rightarrow> lang"
begin
fun
L_rexp :: "rexp \<Rightarrow> lang"
where
"L_rexp (NULL) = {}"
| "L_rexp (EMPTY) = {[]}"
| "L_rexp (CHAR c) = {[c]}"
| "L_rexp (SEQ r1 r2) = (L_rexp r1) ;; (L_rexp r2)"
| "L_rexp (ALT r1 r2) = (L_rexp r1) \<union> (L_rexp r2)"
| "L_rexp (STAR r) = (L_rexp r)\<star>"
end
text {* ALT-combination of a set or regulare expressions *}
abbreviation
Setalt ("\<Uplus>_" [1000] 999)
where
"\<Uplus>A \<equiv> folds ALT NULL A"
text {*
For finite sets, @{term Setalt} is preserved under @{term L}.
*}
lemma folds_alt_simp [simp]:
fixes rs::"rexp set"
assumes a: "finite rs"
shows "L (\<Uplus>rs) = \<Union> (L ` rs)"
unfolding folds_def
apply(rule set_eqI)
apply(rule someI2_ex)
apply(rule_tac finite_imp_fold_graph[OF a])
apply(erule fold_graph.induct)
apply(auto)
done
section {* Direction @{text "finite partition \<Rightarrow> regular language"} *}
text {* Just a technical lemma for collections and pairs *}
lemma Pair_Collect[simp]:
shows "(x, y) \<in> {(x, y). P x y} \<longleftrightarrow> P x y"
by simp
text {* Myhill-Nerode relation *}
definition
str_eq_rel :: "lang \<Rightarrow> (string \<times> string) set" ("\<approx>_" [100] 100)
where
"\<approx>A \<equiv> {(x, y). (\<forall>z. x @ z \<in> A \<longleftrightarrow> y @ z \<in> A)}"
text {*
Among the equivalence clases of @{text "\<approx>A"}, the set @{text "finals A"}
singles out those which contains the strings from @{text A}.
*}
definition
finals :: "lang \<Rightarrow> lang set"
where
"finals A \<equiv> {\<approx>A `` {x} | x . x \<in> A}"
lemma lang_is_union_of_finals:
shows "A = \<Union> finals A"
unfolding finals_def
unfolding Image_def
unfolding str_eq_rel_def
apply(auto)
apply(drule_tac x = "[]" in spec)
apply(auto)
done
lemma finals_in_partitions:
shows "finals A \<subseteq> (UNIV // \<approx>A)"
unfolding finals_def quotient_def
by auto
section {* Equational systems *}
text {* The two kinds of terms in the rhs of equations. *}
datatype rhs_item =
Lam "rexp" (* Lambda-marker *)
| Trn "lang" "rexp" (* Transition *)
overloading L_rhs_item \<equiv> "L:: rhs_item \<Rightarrow> lang"
begin
fun L_rhs_item:: "rhs_item \<Rightarrow> lang"
where
"L_rhs_item (Lam r) = L r"
| "L_rhs_item (Trn X r) = X ;; L r"
end
overloading L_rhs \<equiv> "L:: rhs_item set \<Rightarrow> lang"
begin
fun L_rhs:: "rhs_item set \<Rightarrow> lang"
where
"L_rhs rhs = \<Union> (L ` rhs)"
end
lemma L_rhs_union_distrib:
fixes A B::"rhs_item set"
shows "L A \<union> L B = L (A \<union> B)"
by simp
text {* Transitions between equivalence classes *}
definition
transition :: "lang \<Rightarrow> char \<Rightarrow> lang \<Rightarrow> bool" ("_ \<Turnstile>_\<Rightarrow>_" [100,100,100] 100)
where
"Y \<Turnstile>c\<Rightarrow> X \<equiv> Y ;; {[c]} \<subseteq> X"
text {* Initial equational system *}
definition
"Init_rhs CS X \<equiv>
if ([] \<in> X) then
{Lam EMPTY} \<union> {Trn Y (CHAR c) | Y c. Y \<in> CS \<and> Y \<Turnstile>c\<Rightarrow> X}
else
{Trn Y (CHAR c)| Y c. Y \<in> CS \<and> Y \<Turnstile>c\<Rightarrow> X}"
definition
"Init CS \<equiv> {(X, Init_rhs CS X) | X. X \<in> CS}"
section {* Arden Operation on equations *}
text {*
The function @{text "attach_rexp r item"} SEQ-composes @{text r} to the
right of every rhs-item.
*}
fun
append_rexp :: "rexp \<Rightarrow> rhs_item \<Rightarrow> rhs_item"
where
"append_rexp r (Lam rexp) = Lam (SEQ rexp r)"
| "append_rexp r (Trn X rexp) = Trn X (SEQ rexp r)"
definition
"append_rhs_rexp rhs rexp \<equiv> (append_rexp rexp) ` rhs"
definition
"Arden X rhs \<equiv>
append_rhs_rexp (rhs - {Trn X r | r. Trn X r \<in> rhs}) (STAR (\<Uplus> {r. Trn X r \<in> rhs}))"
section {* Substitution Operation on equations *}
text {*
Suppose and equation @{text "X = xrhs"}, @{text "Subst"} substitutes
all occurences of @{text "X"} in @{text "rhs"} by @{text "xrhs"}.
*}
definition
"Subst rhs X xrhs \<equiv>
(rhs - {Trn X r | r. Trn X r \<in> rhs}) \<union> (append_rhs_rexp xrhs (\<Uplus> {r. Trn X r \<in> rhs}))"
text {*
@{text "eqs_subst ES X xrhs"} substitutes @{text xrhs} into every
equation of the equational system @{text ES}.
*}
types esystem = "(lang \<times> rhs_item set) set"
definition
Subst_all :: "esystem \<Rightarrow> lang \<Rightarrow> rhs_item set \<Rightarrow> esystem"
where
"Subst_all ES X xrhs \<equiv> {(Y, Subst yrhs X xrhs) | Y yrhs. (Y, yrhs) \<in> ES}"
text {*
The following term @{text "remove ES Y yrhs"} removes the equation
@{text "Y = yrhs"} from equational system @{text "ES"} by replacing
all occurences of @{text "Y"} by its definition (using @{text "eqs_subst"}).
The @{text "Y"}-definition is made non-recursive using Arden's transformation
@{text "arden_variate Y yrhs"}.
*}
definition
"Remove ES X xrhs \<equiv>
Subst_all (ES - {(X, xrhs)}) X (Arden X xrhs)"
section {* While-combinator *}
text {*
The following term @{text "Iter X ES"} represents one iteration in the while loop.
It arbitrarily chooses a @{text "Y"} different from @{text "X"} to remove.
*}
definition
"Iter X ES \<equiv> (let (Y, yrhs) = SOME (Y, yrhs). (Y, yrhs) \<in> ES \<and> X \<noteq> Y
in Remove ES Y yrhs)"
lemma IterI2:
assumes "(Y, yrhs) \<in> ES"
and "X \<noteq> Y"
and "\<And>Y yrhs. \<lbrakk>(Y, yrhs) \<in> ES; X \<noteq> Y\<rbrakk> \<Longrightarrow> Q (Remove ES Y yrhs)"
shows "Q (Iter X ES)"
unfolding Iter_def using assms
by (rule_tac a="(Y, yrhs)" in someI2) (auto)
text {*
The following term @{text "Reduce X ES"} repeatedly removes characteriztion equations
for unknowns other than @{text "X"} until one is left.
*}
abbreviation
"Cond ES \<equiv> card ES \<noteq> 1"
definition
"Solve X ES \<equiv> while Cond (Iter X) ES"
text {*
Since the @{text "while"} combinator from HOL library is used to implement @{text "Solve X ES"},
the induction principle @{thm [source] while_rule} is used to proved the desired properties
of @{text "Solve X ES"}. For this purpose, an invariant predicate @{text "invariant"} is defined
in terms of a series of auxilliary predicates:
*}
section {* Invariants *}
text {* Every variable is defined at most once in @{text ES}. *}
definition
"distinct_equas ES \<equiv>
\<forall> X rhs rhs'. (X, rhs) \<in> ES \<and> (X, rhs') \<in> ES \<longrightarrow> rhs = rhs'"
text {*
Every equation in @{text ES} (represented by @{text "(X, rhs)"})
is valid, i.e. @{text "X = L rhs"}.
*}
definition
"valid_eqns ES \<equiv> \<forall>(X, rhs) \<in> ES. X = L rhs"
text {*
@{text "rhs_nonempty rhs"} requires regular expressions occuring in
transitional items of @{text "rhs"} do not contain empty string. This is
necessary for the application of Arden's transformation to @{text "rhs"}.
*}
definition
"rhs_nonempty rhs \<equiv> (\<forall> Y r. Trn Y r \<in> rhs \<longrightarrow> [] \<notin> L r)"
text {*
The following @{text "ardenable ES"} requires that Arden's transformation
is applicable to every equation of equational system @{text "ES"}.
*}
definition
"ardenable ES \<equiv> \<forall>(X, rhs) \<in> ES. rhs_nonempty rhs"
text {*
@{text "finite_rhs ES"} requires every equation in @{text "rhs"}
be finite.
*}
definition
"finite_rhs ES \<equiv> \<forall>(X, rhs) \<in> ES. finite rhs"
lemma finite_rhs_def2:
"finite_rhs ES = (\<forall> X rhs. (X, rhs) \<in> ES \<longrightarrow> finite rhs)"
unfolding finite_rhs_def by auto
text {*
@{text "classes_of rhs"} returns all variables (or equivalent classes)
occuring in @{text "rhs"}.
*}
definition
"classes_of rhs \<equiv> {X | X r. Trn X r \<in> rhs}"
text {*
@{text "lefts_of ES"} returns all variables defined by an
equational system @{text "ES"}.
*}
definition
"lhss ES \<equiv> {Y | Y yrhs. (Y, yrhs) \<in> ES}"
text {*
The following @{text "self_contained ES"} requires that every variable occuring
on the right hand side of equations is already defined by some equation in @{text "ES"}.
*}
definition
"self_contained ES \<equiv> \<forall>(X, xrhs) \<in> ES. classes_of xrhs \<subseteq> lhss ES"
text {*
The invariant @{text "invariant(ES)"} is a conjunction of all the previously defined constaints.
*}
definition
"invariant ES \<equiv> finite ES
\<and> finite_rhs ES
\<and> valid_eqns ES
\<and> distinct_equas ES
\<and> ardenable ES
\<and> self_contained ES"
lemma invariantI:
assumes "valid_eqns ES" "finite ES" "distinct_equas ES" "ardenable ES"
"finite_rhs ES" "self_contained ES"
shows "invariant ES"
using assms by (simp add: invariant_def)
subsection {* The proof of this direction *}
subsubsection {* Basic properties *}
text {*
The following are some basic properties of the above definitions.
*}
lemma finite_Trn:
assumes fin: "finite rhs"
shows "finite {r. Trn Y r \<in> rhs}"
proof -
have "finite {Trn Y r | Y r. Trn Y r \<in> rhs}"
by (rule rev_finite_subset[OF fin]) (auto)
then have "finite ((\<lambda>(Y, r). Trn Y r) ` {(Y, r) | Y r. Trn Y r \<in> rhs})"
by (simp add: image_Collect)
then have "finite {(Y, r) | Y r. Trn Y r \<in> rhs}"
by (erule_tac finite_imageD) (simp add: inj_on_def)
then show "finite {r. Trn Y r \<in> rhs}"
by (erule_tac f="snd" in finite_surj) (auto simp add: image_def)
qed
lemma finite_Lam:
assumes fin: "finite rhs"
shows "finite {r. Lam r \<in> rhs}"
proof -
have "finite {Lam r | r. Lam r \<in> rhs}"
by (rule rev_finite_subset[OF fin]) (auto)
then show "finite {r. Lam r \<in> rhs}"
apply(simp add: image_Collect[symmetric])
apply(erule finite_imageD)
apply(auto simp add: inj_on_def)
done
qed
lemma rexp_of_empty:
assumes finite: "finite rhs"
and nonempty: "rhs_nonempty rhs"
shows "[] \<notin> L (\<Uplus> {r. Trn X r \<in> rhs})"
using finite nonempty rhs_nonempty_def
using finite_Trn[OF finite]
by auto
lemma lang_of_rexp_of:
assumes finite:"finite rhs"
shows "L ({Trn X r| r. Trn X r \<in> rhs}) = X ;; (L (\<Uplus>{r. Trn X r \<in> rhs}))"
proof -
have "finite {r. Trn X r \<in> rhs}"
by (rule finite_Trn[OF finite])
then show ?thesis
apply(auto simp add: Seq_def)
apply(rule_tac x = "s\<^isub>1" in exI, rule_tac x = "s\<^isub>2" in exI)
apply(auto)
apply(rule_tac x= "Trn X xa" in exI)
apply(auto simp add: Seq_def)
done
qed
lemma lang_of_append:
"L (append_rexp r rhs_item) = L rhs_item ;; L r"
by (induct rule: append_rexp.induct)
(auto simp add: seq_assoc)
lemma lang_of_append_rhs:
"L (append_rhs_rexp rhs r) = L rhs ;; L r"
unfolding append_rhs_rexp_def
by (auto simp add: Seq_def lang_of_append)
lemma classes_of_union_distrib:
shows "classes_of (A \<union> B) = classes_of A \<union> classes_of B"
by (auto simp add: classes_of_def)
lemma lhss_union_distrib:
shows "lhss (A \<union> B) = lhss A \<union> lhss B"
by (auto simp add: lhss_def)
subsubsection {* Intialization *}
text {*
The following several lemmas until @{text "init_ES_satisfy_invariant"} shows that
the initial equational system satisfies invariant @{text "invariant"}.
*}
lemma defined_by_str:
assumes "s \<in> X" "X \<in> UNIV // \<approx>A"
shows "X = \<approx>A `` {s}"
using assms
unfolding quotient_def Image_def str_eq_rel_def
by auto
lemma every_eqclass_has_transition:
assumes has_str: "s @ [c] \<in> X"
and in_CS: "X \<in> UNIV // \<approx>A"
obtains Y where "Y \<in> UNIV // \<approx>A" and "Y ;; {[c]} \<subseteq> X" and "s \<in> Y"
proof -
def Y \<equiv> "\<approx>A `` {s}"
have "Y \<in> UNIV // \<approx>A"
unfolding Y_def quotient_def by auto
moreover
have "X = \<approx>A `` {s @ [c]}"
using has_str in_CS defined_by_str by blast
then have "Y ;; {[c]} \<subseteq> X"
unfolding Y_def Image_def Seq_def
unfolding str_eq_rel_def
by clarsimp
moreover
have "s \<in> Y" unfolding Y_def
unfolding Image_def str_eq_rel_def by simp
ultimately show thesis using that by blast
qed
lemma l_eq_r_in_eqs:
assumes X_in_eqs: "(X, rhs) \<in> Init (UNIV // \<approx>A)"
shows "X = L rhs"
proof
show "X \<subseteq> L rhs"
proof
fix x
assume "(1)": "x \<in> X"
show "x \<in> L rhs"
proof (cases "x = []")
assume empty: "x = []"
thus ?thesis using X_in_eqs "(1)"
by (auto simp: Init_def Init_rhs_def)
next
assume not_empty: "x \<noteq> []"
then obtain clist c where decom: "x = clist @ [c]"
by (case_tac x rule:rev_cases, auto)
have "X \<in> UNIV // \<approx>A" using X_in_eqs by (auto simp:Init_def)
then obtain Y
where "Y \<in> UNIV // \<approx>A"
and "Y ;; {[c]} \<subseteq> X"
and "clist \<in> Y"
using decom "(1)" every_eqclass_has_transition by blast
hence
"x \<in> L {Trn Y (CHAR c)| Y c. Y \<in> UNIV // \<approx>A \<and> Y \<Turnstile>c\<Rightarrow> X}"
unfolding transition_def
using "(1)" decom
by (simp, rule_tac x = "Trn Y (CHAR c)" in exI, simp add:Seq_def)
thus ?thesis using X_in_eqs "(1)"
by (simp add: Init_def Init_rhs_def)
qed
qed
next
show "L rhs \<subseteq> X" using X_in_eqs
by (auto simp:Init_def Init_rhs_def transition_def)
qed
lemma test:
assumes X_in_eqs: "(X, rhs) \<in> Init (UNIV // \<approx>A)"
shows "X = \<Union> (L ` rhs)"
using assms
by (drule_tac l_eq_r_in_eqs) (simp)
lemma finite_Init_rhs:
assumes finite: "finite CS"
shows "finite (Init_rhs CS X)"
proof-
have "finite {Trn Y (CHAR c) |Y c. Y \<in> CS \<and> Y ;; {[c]} \<subseteq> X}" (is "finite ?A")
proof -
def S \<equiv> "{(Y, c)| Y c. Y \<in> CS \<and> Y ;; {[c]} \<subseteq> X}"
def h \<equiv> "\<lambda> (Y, c). Trn Y (CHAR c)"
have "finite (CS \<times> (UNIV::char set))" using finite by auto
hence "finite S" using S_def
by (rule_tac B = "CS \<times> UNIV" in finite_subset, auto)
moreover have "?A = h ` S" by (auto simp: S_def h_def image_def)
ultimately show ?thesis
by auto
qed
thus ?thesis by (simp add:Init_rhs_def transition_def)
qed
lemma Init_ES_satisfies_invariant:
assumes finite_CS: "finite (UNIV // \<approx>A)"
shows "invariant (Init (UNIV // \<approx>A))"
proof (rule invariantI)
show "valid_eqns (Init (UNIV // \<approx>A))"
unfolding valid_eqns_def
using l_eq_r_in_eqs by auto
show "finite (Init (UNIV // \<approx>A))" using finite_CS
unfolding Init_def by simp
show "distinct_equas (Init (UNIV // \<approx>A))"
unfolding distinct_equas_def Init_def by simp
show "ardenable (Init (UNIV // \<approx>A))"
unfolding ardenable_def Init_def Init_rhs_def rhs_nonempty_def
by auto
show "finite_rhs (Init (UNIV // \<approx>A))"
using finite_Init_rhs[OF finite_CS]
unfolding finite_rhs_def Init_def by auto
show "self_contained (Init (UNIV // \<approx>A))"
unfolding self_contained_def Init_def Init_rhs_def classes_of_def lhss_def
by auto
qed
subsubsection {* Interation step *}
text {*
From this point until @{text "iteration_step"},
the correctness of the iteration step @{text "Iter X ES"} is proved.
*}
lemma Arden_keeps_eq:
assumes l_eq_r: "X = L rhs"
and not_empty: "[] \<notin> L (\<Uplus>{r. Trn X r \<in> rhs})"
and finite: "finite rhs"
shows "X = L (Arden X rhs)"
proof -
def A \<equiv> "L (\<Uplus>{r. Trn X r \<in> rhs})"
def b \<equiv> "rhs - {Trn X r | r. Trn X r \<in> rhs}"
def B \<equiv> "L b"
have "X = B ;; A\<star>"
proof-
have "L rhs = L({Trn X r | r. Trn X r \<in> rhs} \<union> b)" by (auto simp: b_def)
also have "\<dots> = X ;; A \<union> B"
unfolding L_rhs_union_distrib[symmetric]
by (simp only: lang_of_rexp_of finite B_def A_def)
finally show ?thesis
using l_eq_r not_empty
apply(rule_tac arden[THEN iffD1])
apply(simp add: A_def)
apply(simp)
done
qed
moreover have "L (Arden X rhs) = B ;; A\<star>"
by (simp only:Arden_def L_rhs_union_distrib lang_of_append_rhs
B_def A_def b_def L_rexp.simps seq_union_distrib_left)
ultimately show ?thesis by simp
qed
lemma append_keeps_finite:
"finite rhs \<Longrightarrow> finite (append_rhs_rexp rhs r)"
by (auto simp:append_rhs_rexp_def)
lemma Arden_keeps_finite:
"finite rhs \<Longrightarrow> finite (Arden X rhs)"
by (auto simp:Arden_def append_keeps_finite)
lemma append_keeps_nonempty:
"rhs_nonempty rhs \<Longrightarrow> rhs_nonempty (append_rhs_rexp rhs r)"
apply (auto simp:rhs_nonempty_def append_rhs_rexp_def)
by (case_tac x, auto simp:Seq_def)
lemma nonempty_set_sub:
"rhs_nonempty rhs \<Longrightarrow> rhs_nonempty (rhs - A)"
by (auto simp:rhs_nonempty_def)
lemma nonempty_set_union:
"\<lbrakk>rhs_nonempty rhs; rhs_nonempty rhs'\<rbrakk> \<Longrightarrow> rhs_nonempty (rhs \<union> rhs')"
by (auto simp:rhs_nonempty_def)
lemma Arden_keeps_nonempty:
"rhs_nonempty rhs \<Longrightarrow> rhs_nonempty (Arden X rhs)"
by (simp only:Arden_def append_keeps_nonempty nonempty_set_sub)
lemma Subst_keeps_nonempty:
"\<lbrakk>rhs_nonempty rhs; rhs_nonempty xrhs\<rbrakk> \<Longrightarrow> rhs_nonempty (Subst rhs X xrhs)"
by (simp only:Subst_def append_keeps_nonempty nonempty_set_union nonempty_set_sub)
lemma Subst_keeps_eq:
assumes substor: "X = L xrhs"
and finite: "finite rhs"
shows "L (Subst rhs X xrhs) = L rhs" (is "?Left = ?Right")
proof-
def A \<equiv> "L (rhs - {Trn X r | r. Trn X r \<in> rhs})"
have "?Left = A \<union> L (append_rhs_rexp xrhs (\<Uplus>{r. Trn X r \<in> rhs}))"
unfolding Subst_def
unfolding L_rhs_union_distrib[symmetric]
by (simp add: A_def)
moreover have "?Right = A \<union> L ({Trn X r | r. Trn X r \<in> rhs})"
proof-
have "rhs = (rhs - {Trn X r | r. Trn X r \<in> rhs}) \<union> ({Trn X r | r. Trn X r \<in> rhs})" by auto
thus ?thesis
unfolding A_def
unfolding L_rhs_union_distrib
by simp
qed
moreover have "L (append_rhs_rexp xrhs (\<Uplus>{r. Trn X r \<in> rhs})) = L ({Trn X r | r. Trn X r \<in> rhs})"
using finite substor by (simp only:lang_of_append_rhs lang_of_rexp_of)
ultimately show ?thesis by simp
qed
lemma Subst_keeps_finite_rhs:
"\<lbrakk>finite rhs; finite yrhs\<rbrakk> \<Longrightarrow> finite (Subst rhs Y yrhs)"
by (auto simp:Subst_def append_keeps_finite)
lemma Subst_all_keeps_finite:
assumes finite:"finite (ES:: (string set \<times> rhs_item set) set)"
shows "finite (Subst_all ES Y yrhs)"
proof -
have "finite {(Ya, Subst yrhsa Y yrhs) |Ya yrhsa. (Ya, yrhsa) \<in> ES}"
(is "finite ?A")
proof-
def eqns' \<equiv> "{(Ya::lang, yrhsa) | Ya yrhsa. (Ya, yrhsa) \<in> ES}"
def h \<equiv> "\<lambda>(Ya::lang, yrhsa). (Ya, Subst yrhsa Y yrhs)"
have "finite (h ` eqns')" using finite h_def eqns'_def by auto
moreover have "?A = h ` eqns'" by (auto simp:h_def eqns'_def)
ultimately show ?thesis by auto
qed
thus ?thesis by (simp add:Subst_all_def)
qed
lemma Subst_all_keeps_finite_rhs:
"\<lbrakk>finite_rhs ES; finite yrhs\<rbrakk> \<Longrightarrow> finite_rhs (Subst_all ES Y yrhs)"
by (auto intro:Subst_keeps_finite_rhs simp add:Subst_all_def finite_rhs_def)
lemma append_rhs_keeps_cls:
"classes_of (append_rhs_rexp rhs r) = classes_of rhs"
apply (auto simp:classes_of_def append_rhs_rexp_def)
apply (case_tac xa, auto simp:image_def)
by (rule_tac x = "SEQ ra r" in exI, rule_tac x = "Trn x ra" in bexI, simp+)
lemma Arden_removes_cl:
"classes_of (Arden Y yrhs) = classes_of yrhs - {Y}"
apply (simp add:Arden_def append_rhs_keeps_cls)
by (auto simp:classes_of_def)
lemma lhss_keeps_cls:
"lhss (Subst_all ES Y yrhs) = lhss ES"
by (auto simp:lhss_def Subst_all_def)
lemma Subst_updates_cls:
"X \<notin> classes_of xrhs \<Longrightarrow>
classes_of (Subst rhs X xrhs) = classes_of rhs \<union> classes_of xrhs - {X}"
apply (simp only:Subst_def append_rhs_keeps_cls classes_of_union_distrib)
by (auto simp:classes_of_def)
lemma Subst_all_keeps_self_contained:
assumes sc: "self_contained (ES \<union> {(Y, yrhs)})" (is "self_contained ?A")
shows "self_contained (Subst_all ES Y (Arden Y yrhs))"
(is "self_contained ?B")
proof-
{ fix X xrhs'
assume "(X, xrhs') \<in> ?B"
then obtain xrhs
where xrhs_xrhs': "xrhs' = Subst xrhs Y (Arden Y yrhs)"
and X_in: "(X, xrhs) \<in> ES" by (simp add:Subst_all_def, blast)
have "classes_of xrhs' \<subseteq> lhss ?B"
proof-
have "lhss ?B = lhss ES" by (auto simp add:lhss_def Subst_all_def)
moreover have "classes_of xrhs' \<subseteq> lhss ES"
proof-
have "classes_of xrhs' \<subseteq>
classes_of xrhs \<union> classes_of (Arden Y yrhs) - {Y}"
proof-
have "Y \<notin> classes_of (Arden Y yrhs)"
using Arden_removes_cl by simp
thus ?thesis using xrhs_xrhs' by (auto simp:Subst_updates_cls)
qed
moreover have "classes_of xrhs \<subseteq> lhss ES \<union> {Y}" using X_in sc
apply (simp only:self_contained_def lhss_union_distrib)
by (drule_tac x = "(X, xrhs)" in bspec, auto simp:lhss_def)
moreover have "classes_of (Arden Y yrhs) \<subseteq> lhss ES \<union> {Y}"
using sc
by (auto simp add:Arden_removes_cl self_contained_def lhss_def)
ultimately show ?thesis by auto
qed
ultimately show ?thesis by simp
qed
} thus ?thesis by (auto simp only:Subst_all_def self_contained_def)
qed
lemma Subst_all_satisfies_invariant:
assumes invariant_ES: "invariant (ES \<union> {(Y, yrhs)})"
shows "invariant (Subst_all ES Y (Arden Y yrhs))"
proof (rule invariantI)
have Y_eq_yrhs: "Y = L yrhs"
using invariant_ES by (simp only:invariant_def valid_eqns_def, blast)
have finite_yrhs: "finite yrhs"
using invariant_ES by (auto simp:invariant_def finite_rhs_def)
have nonempty_yrhs: "rhs_nonempty yrhs"
using invariant_ES by (auto simp:invariant_def ardenable_def)
show "valid_eqns (Subst_all ES Y (Arden Y yrhs))"
proof-
have "Y = L (Arden Y yrhs)"
using Y_eq_yrhs invariant_ES finite_yrhs
using finite_Trn[OF finite_yrhs]
apply(rule_tac Arden_keeps_eq)
apply(simp_all)
unfolding invariant_def ardenable_def rhs_nonempty_def
apply(auto)
done
thus ?thesis using invariant_ES
unfolding invariant_def finite_rhs_def2 valid_eqns_def Subst_all_def
by (auto simp add: Subst_keeps_eq simp del: L_rhs.simps)
qed
show "finite (Subst_all ES Y (Arden Y yrhs))"
using invariant_ES by (simp add:invariant_def Subst_all_keeps_finite)
show "distinct_equas (Subst_all ES Y (Arden Y yrhs))"
using invariant_ES
by (auto simp:distinct_equas_def Subst_all_def invariant_def)
show "ardenable (Subst_all ES Y (Arden Y yrhs))"
proof -
{ fix X rhs
assume "(X, rhs) \<in> ES"
hence "rhs_nonempty rhs" using prems invariant_ES
by (auto simp add:invariant_def ardenable_def)
with nonempty_yrhs
have "rhs_nonempty (Subst rhs Y (Arden Y yrhs))"
by (simp add:nonempty_yrhs
Subst_keeps_nonempty Arden_keeps_nonempty)
} thus ?thesis by (auto simp add:ardenable_def Subst_all_def)
qed
show "finite_rhs (Subst_all ES Y (Arden Y yrhs))"
proof-
have "finite_rhs ES" using invariant_ES
by (simp add:invariant_def finite_rhs_def)
moreover have "finite (Arden Y yrhs)"
proof -
have "finite yrhs" using invariant_ES
by (auto simp:invariant_def finite_rhs_def)
thus ?thesis using Arden_keeps_finite by simp
qed
ultimately show ?thesis
by (simp add:Subst_all_keeps_finite_rhs)
qed
show "self_contained (Subst_all ES Y (Arden Y yrhs))"
using invariant_ES Subst_all_keeps_self_contained by (simp add:invariant_def)
qed
lemma Remove_in_card_measure:
assumes finite: "finite ES"
and in_ES: "(X, rhs) \<in> ES"
shows "(Remove ES X rhs, ES) \<in> measure card"
proof -
def f \<equiv> "\<lambda> x. ((fst x)::lang, Subst (snd x) X (Arden X rhs))"
def ES' \<equiv> "ES - {(X, rhs)}"
have "Subst_all ES' X (Arden X rhs) = f ` ES'"
apply (auto simp: Subst_all_def f_def image_def)
by (rule_tac x = "(Y, yrhs)" in bexI, simp+)
then have "card (Subst_all ES' X (Arden X rhs)) \<le> card ES'"
unfolding ES'_def using finite by (auto intro: card_image_le)
also have "\<dots> < card ES" unfolding ES'_def
using in_ES finite by (rule_tac card_Diff1_less)
finally show "(Remove ES X rhs, ES) \<in> measure card"
unfolding Remove_def ES'_def by simp
qed
lemma Subst_all_cls_remains:
"(X, xrhs) \<in> ES \<Longrightarrow> \<exists> xrhs'. (X, xrhs') \<in> (Subst_all ES Y yrhs)"
by (auto simp: Subst_all_def)
lemma card_noteq_1_has_more:
assumes card:"Cond ES"
and e_in: "(X, xrhs) \<in> ES"
and finite: "finite ES"
shows "\<exists>(Y, yrhs) \<in> ES. (X, xrhs) \<noteq> (Y, yrhs)"
proof-
have "card ES > 1" using card e_in finite
by (cases "card ES") (auto)
then have "card (ES - {(X, xrhs)}) > 0"
using finite e_in by auto
then have "(ES - {(X, xrhs)}) \<noteq> {}" using finite by (rule_tac notI, simp)
then show "\<exists>(Y, yrhs) \<in> ES. (X, xrhs) \<noteq> (Y, yrhs)"
by auto
qed
lemma iteration_step_measure:
assumes Inv_ES: "invariant ES"
and X_in_ES: "(X, xrhs) \<in> ES"
and not_T: "Cond ES "
shows "(Iter X ES, ES) \<in> measure card"
proof -
have finite_ES: "finite ES" using Inv_ES by (simp add: invariant_def)
then obtain Y yrhs
where Y_in_ES: "(Y, yrhs) \<in> ES" and not_eq: "(X, xrhs) \<noteq> (Y, yrhs)"
using not_T X_in_ES by (drule_tac card_noteq_1_has_more) (auto)
then have "(Y, yrhs) \<in> ES " "X \<noteq> Y"
using X_in_ES Inv_ES unfolding invariant_def distinct_equas_def
by auto
then show "(Iter X ES, ES) \<in> measure card"
apply(rule IterI2)
apply(rule Remove_in_card_measure)
apply(simp_all add: finite_ES)
done
qed
lemma iteration_step_invariant:
assumes Inv_ES: "invariant ES"
and X_in_ES: "(X, xrhs) \<in> ES"
and not_T: "Cond ES"
shows "invariant (Iter X ES)"
proof -
have finite_ES: "finite ES" using Inv_ES by (simp add: invariant_def)
then obtain Y yrhs
where Y_in_ES: "(Y, yrhs) \<in> ES" and not_eq: "(X, xrhs) \<noteq> (Y, yrhs)"
using not_T X_in_ES by (drule_tac card_noteq_1_has_more) (auto)
then have "(Y, yrhs) \<in> ES" "X \<noteq> Y"
using X_in_ES Inv_ES unfolding invariant_def distinct_equas_def
by auto
then show "invariant (Iter X ES)"
proof(rule IterI2)
fix Y yrhs
assume h: "(Y, yrhs) \<in> ES" "X \<noteq> Y"
then have "ES - {(Y, yrhs)} \<union> {(Y, yrhs)} = ES" by auto
then show "invariant (Remove ES Y yrhs)" unfolding Remove_def
using Inv_ES by (rule_tac Subst_all_satisfies_invariant) (simp)
qed
qed
lemma iteration_step_ex:
assumes Inv_ES: "invariant ES"
and X_in_ES: "(X, xrhs) \<in> ES"
and not_T: "Cond ES"
shows "\<exists>xrhs'. (X, xrhs') \<in> (Iter X ES)"
proof -
have finite_ES: "finite ES" using Inv_ES by (simp add: invariant_def)
then obtain Y yrhs
where Y_in_ES: "(Y, yrhs) \<in> ES" and not_eq: "(X, xrhs) \<noteq> (Y, yrhs)"
using not_T X_in_ES by (drule_tac card_noteq_1_has_more) (auto)
then have "(Y, yrhs) \<in> ES " "X \<noteq> Y"
using X_in_ES Inv_ES unfolding invariant_def distinct_equas_def
by auto
then show "\<exists>xrhs'. (X, xrhs') \<in> (Iter X ES)"
apply(rule IterI2)
unfolding Remove_def
apply(rule Subst_all_cls_remains)
using X_in_ES
apply(auto)
done
qed
subsubsection {* Conclusion of the proof *}
lemma Solve:
assumes fin: "finite (UNIV // \<approx>A)"
and X_in: "X \<in> (UNIV // \<approx>A)"
shows "\<exists>xrhs. Solve X (Init (UNIV // \<approx>A)) = {(X, xrhs)} \<and> invariant {(X, xrhs)}"
proof -
def Inv \<equiv> "\<lambda>ES. invariant ES \<and> (\<exists>xrhs. (X, xrhs) \<in> ES)"
have "Inv (Init (UNIV // \<approx>A))" unfolding Inv_def
using fin X_in by (simp add: Init_ES_satisfies_invariant, simp add: Init_def)
moreover
{ fix ES
assume inv: "Inv ES" and crd: "Cond ES"
then have "Inv (Iter X ES)"
unfolding Inv_def
by (auto simp add: iteration_step_invariant iteration_step_ex) }
moreover
{ fix ES
assume "Inv ES" and "\<not> Cond ES"
then have "\<exists>xrhs'. ES = {(X, xrhs')} \<and> invariant ES"
unfolding Inv_def invariant_def
apply (auto, rule_tac x = xrhs in exI)
apply (auto dest!: card_Suc_Diff1 simp: card_eq_0_iff)
done
then have "\<exists>xrhs'. ES = {(X, xrhs')} \<and> invariant {(X, xrhs')}"
by auto }
moreover
have "wf (measure card)" by simp
moreover
{ fix ES
assume inv: "Inv ES" and crd: "Cond ES"
then have "(Iter X ES, ES) \<in> measure card"
unfolding Inv_def
apply(clarify)
apply(rule_tac iteration_step_measure)
apply(auto)
done }
ultimately
show "\<exists>xrhs. Solve X (Init (UNIV // \<approx>A)) = {(X, xrhs)} \<and> invariant {(X, xrhs)}"
unfolding Solve_def by (rule while_rule)
qed
lemma last_cl_exists_rexp:
assumes Inv_ES: "invariant {(X, xrhs)}"
shows "\<exists>r::rexp. L r = X"
proof-
def A \<equiv> "Arden X xrhs"
have eq: "{Lam r | r. Lam r \<in> A} = A"
proof -
have "classes_of A = {}" using Inv_ES
unfolding A_def self_contained_def invariant_def lhss_def
by (simp add: Arden_removes_cl)
thus ?thesis unfolding A_def classes_of_def
apply(auto simp only:)
apply(case_tac x)
apply(auto)
done
qed
have "finite A" using Inv_ES unfolding A_def invariant_def finite_rhs_def
using Arden_keeps_finite by auto
then have "finite {r. Lam r \<in> A}" by (rule finite_Lam)
then have "L (\<Uplus>{r. Lam r \<in> A}) = L ({Lam r | r. Lam r \<in> A})"
by auto
also have "\<dots> = L A" by (simp add: eq)
also have "\<dots> = X"
proof -
have "X = L xrhs" using Inv_ES unfolding invariant_def valid_eqns_def
by auto
moreover
from Inv_ES have "[] \<notin> L (\<Uplus>{r. Trn X r \<in> xrhs})"
unfolding invariant_def ardenable_def finite_rhs_def
by(simp add: rexp_of_empty)
moreover
from Inv_ES have "finite xrhs" unfolding invariant_def finite_rhs_def
by simp
ultimately show "L A = X" unfolding A_def
by (rule Arden_keeps_eq[symmetric])
qed
finally have "L (\<Uplus>{r. Lam r \<in> A}) = X" .
then show "\<exists>r::rexp. L r = X" by blast
qed
lemma every_eqcl_has_reg:
assumes finite_CS: "finite (UNIV // \<approx>A)"
and X_in_CS: "X \<in> (UNIV // \<approx>A)"
shows "\<exists>r::rexp. L r = X"
proof -
from finite_CS X_in_CS
obtain xrhs where "invariant {(X, xrhs)}"
using Solve by metis
then show "\<exists>r::rexp. L r = X"
using last_cl_exists_rexp by auto
qed
lemma bchoice_finite_set:
assumes a: "\<forall>x \<in> S. \<exists>y. x = f y"
and b: "finite S"
shows "\<exists>ys. (\<Union> S) = \<Union>(f ` ys) \<and> finite ys"
using bchoice[OF a] b
apply(erule_tac exE)
apply(rule_tac x="fa ` S" in exI)
apply(auto)
done
theorem Myhill_Nerode1:
assumes finite_CS: "finite (UNIV // \<approx>A)"
shows "\<exists>r::rexp. A = L r"
proof -
have f: "finite (finals A)"
using finals_in_partitions finite_CS by (rule finite_subset)
have "\<forall>X \<in> (UNIV // \<approx>A). \<exists>r::rexp. X = L r"
using finite_CS every_eqcl_has_reg by blast
then have a: "\<forall>X \<in> finals A. \<exists>r::rexp. X = L r"
using finals_in_partitions by auto
then obtain rs::"rexp set" where "\<Union> (finals A) = \<Union>(L ` rs)" "finite rs"
using f by (auto dest: bchoice_finite_set)
then have "A = L (\<Uplus>rs)"
unfolding lang_is_union_of_finals[symmetric] by simp
then show "\<exists>r::rexp. A = L r" by blast
qed
end