theory Ext

imports Prio

begin

locale highest_create =

  fixes s' th prio fixes s 

  defines s_def : "s \<equiv> (Create th prio#s')"

  assumes vt_s: "vt step s"

  and highest: "cp s th = Max ((cp s)`threads s)"

context highest_create

begin

lemma threads_s: "threads s = threads s' \<union> {th}"

  by (unfold s_def, simp)

lemma vt_s': "vt step s'"

  by (insert vt_s, unfold s_def, drule_tac step_back_vt, simp)

lemma step_create: "step s' (Create th prio)"

  by (insert vt_s, unfold s_def, drule_tac step_back_step, simp)

lemma step_create_elim: 

  "\<lbrakk>\<And>max_prio. \<lbrakk>prio \<le> max_prio; th \<notin> threads s'\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"

  by (insert step_create, ind_cases "step s' (Create th prio)", auto)

lemma eq_cp_s: 

  assumes th'_in: "th' \<in> threads s'"

  shows "cp s th' = cp s' th'"

proof(unfold cp_eq_cpreced cpreced_def cs_dependents_def s_def 

    eq_depend depend_create_unchanged)

  show "Max ((\<lambda>tha. preced tha (Create th prio # s')) `

         ({th'} \<union> {th'a. (Th th'a, Th th') \<in> (depend s')\<^sup>+})) =

        Max ((\<lambda>th. preced th s') ` ({th'} \<union> {th'a. (Th th'a, Th th') \<in> (depend s')\<^sup>+}))"

    (is "Max (?f ` ?A) = Max (?g ` ?A)")

  proof -

    have "?f ` ?A = ?g ` ?A"

    proof(rule f_image_eq)

      fix a

      assume a_in: "a \<in> ?A"

      thus "?f a = ?g a" 

      proof -

        from a_in

        have "a = th' \<or> (Th a, Th th') \<in> (depend s')\<^sup>+" by auto 

        hence "a \<noteq> th"

        proof

          assume "a = th'"

          moreover have "th' \<noteq> th"

          proof(rule step_create_elim)

            assume th_not_in: "th \<notin> threads s'" with th'_in

            show ?thesis by auto

          qed

          ultimately show ?thesis by auto

        next

          assume "(Th a, Th th') \<in> (depend s')\<^sup>+"

          hence "Th a \<in> Domain \<dots>"

            by (auto simp:Domain_def)

          hence "Th a \<in> Domain (depend s')"

            by (simp add:trancl_domain)

          from dm_depend_threads[OF vt_s' this]

          have h: "a \<in> threads s'" .

          show ?thesis

          proof(rule step_create_elim)

            assume "th \<notin> threads s'" with h

            show ?thesis by auto

          qed

        qed

        thus ?thesis 

          by (unfold preced_def, auto)

      qed

    qed

    thus ?thesis by auto

  qed

qed

lemma same_depend: "depend s = depend s'"

  by (insert depend_create_unchanged, unfold s_def, simp)

lemma same_dependents:

  "dependents (wq s) th = dependents (wq s') th"

  apply (unfold cs_dependents_def)

  by (unfold eq_depend same_depend, simp)

lemma nil_dependents_s': "dependents (wq s') th = {}"

proof -

  { assume ne: "dependents (wq s') th \<noteq> {}"

    then obtain th' where "th' \<in>  dependents (wq s') th"

      by (unfold cs_dependents_def, auto)

    hence "(Th th', Th th) \<in> (depend (wq s'))^+"

      by (unfold cs_dependents_def, auto)

    hence "(Th th', Th th) \<in> (depend s')^+"

      by (simp add:eq_depend)

    hence "Th th \<in> Range ((depend s')^+)" by (auto simp:Range_def Domain_def)

    hence "Th th \<in> Range (depend s')" by (simp add:trancl_range)

    from range_in [OF vt_s' this]

    have h: "th \<in> threads s'" .

    have "False"

    proof(rule step_create_elim)

      assume "th \<notin> threads s'" with h show ?thesis by auto

    qed

  } thus ?thesis by auto

qed

lemma nil_dependents: "dependents (wq s) th = {}"

proof -

  have "wq s' = wq s"

    by (unfold wq_def s_def, auto simp:Let_def)

  with nil_dependents_s' show ?thesis by auto

qed

lemma eq_cp_s_th: "cp s th = preced th s"

  by (unfold cp_eq_cpreced cpreced_def nil_dependents, auto)

lemma highest_cp_preced: "cp s th = Max ((\<lambda> th'. preced th' s) ` threads s)"

  by (fold max_cp_eq[OF vt_s], unfold highest, simp)

lemma highest_preced_thread: "preced th s = Max ((\<lambda> th'. preced th' s) ` threads s)"

  by (fold eq_cp_s_th, unfold highest_cp_preced, simp)

lemma is_ready: "th \<in> readys s"

proof -

  { assume "th \<notin> readys s"

    with threads_s obtain cs where 

      "waiting s th cs"

      by (unfold readys_def, auto)

    hence "(Th th, Cs cs) \<in> depend s"

      by (unfold s_depend_def, unfold eq_waiting, simp)

    hence "Th th \<in> Domain (depend s')"

      by (unfold same_depend, auto simp:Domain_def)

    from dm_depend_threads [OF vt_s' this] 

    have h: "th \<in> threads s'" .

    have "False"

    proof (rule_tac step_create_elim)

      assume "th \<notin> threads s'" with h show ?thesis by simp

    qed

  } thus ?thesis by auto

qed

lemma is_runing: "th \<in> runing s"

proof -

  have "Max (cp s ` threads s) = Max (cp s ` readys s)"

  proof -

    have " Max (cp s ` readys s) = cp s th"

    proof(rule Max_eqI)

      from finite_threads[OF vt_s] readys_threads finite_subset

      have "finite (readys s)" by blast

      thus "finite (cp s ` readys s)" by auto

    next

      from is_ready show "cp s th \<in> cp s ` readys s" by auto

    next

      fix y

      assume h: "y \<in> cp s ` readys s"

      have "y \<le> Max (cp s ` readys s)"

      proof(rule Max_ge [OF _ h])

        from finite_threads[OF vt_s] readys_threads finite_subset

        have "finite (readys s)" by blast

        thus "finite (cp s ` readys s)" by auto

      qed

      moreover have "\<dots> \<le> Max (cp s ` threads s)"

      proof(rule Max_mono)

        from readys_threads 

        show "cp s ` readys s \<subseteq> cp s ` threads s" by auto

      next

        from is_ready show "cp s ` readys s \<noteq> {}" by auto

      next

        from finite_threads [OF vt_s]

        show "finite (cp s ` threads s)" by auto

      qed

      moreover note highest

      ultimately show "y \<le> cp s th" by auto

    qed

    with highest show ?thesis by auto

  qed

  thus ?thesis

    by (unfold runing_def, insert highest is_ready, auto)

qed

end

locale extend_highest = highest_create + 

  fixes t 

  assumes vt_t: "vt step (t@s)"

  and create_low: "Create th' prio' \<in> set t \<Longrightarrow> prio' \<le> prio"

  and set_diff_low: "Set th' prio' \<in> set t \<Longrightarrow> th' \<noteq> th \<and> prio' \<le> prio"

  and exit_diff: "Exit th' \<in> set t \<Longrightarrow> th' \<noteq> th"

lemma step_back_vt_app: 

  assumes vt_ts: "vt cs (t@s)" 

  shows "vt cs s"

proof -

  from vt_ts show ?thesis

  proof(induct t)

    case Nil

    from Nil show ?case by auto

  next

    case (Cons e t)

    assume ih: " vt cs (t @ s) \<Longrightarrow> vt cs s"

      and vt_et: "vt cs ((e # t) @ s)"

    show ?case

    proof(rule ih)

      show "vt cs (t @ s)"

      proof(rule step_back_vt)

        from vt_et show "vt cs (e # t @ s)" by simp

      qed

    qed

  qed

qed

context extend_highest

begin

lemma red_moment:

  "extend_highest s' th prio (moment i t)"

  apply (insert extend_highest_axioms, subst (asm) (1) moment_restm_s [of i t, symmetric])

  apply (unfold extend_highest_def extend_highest_axioms_def, clarsimp)

  by (unfold highest_create_def, auto dest:step_back_vt_app)

lemma ind [consumes 0, case_names Nil Cons, induct type]:

  assumes 

    h0: "R []"

  and h2: "\<And> e t. \<lbrakk>vt step (t@s); step (t@s) e; 

                    extend_highest s' th prio t; 

                    extend_highest s' th prio (e#t); R t\<rbrakk> \<Longrightarrow> R (e#t)"

  shows "R t"

proof -

  from vt_t extend_highest_axioms show ?thesis

  proof(induct t)

    from h0 show "R []" .

  next

    case (Cons e t')

    assume ih: "\<lbrakk>vt step (t' @ s); extend_highest s' th prio t'\<rbrakk> \<Longrightarrow> R t'"

      and vt_e: "vt step ((e # t') @ s)"

      and et: "extend_highest s' th prio (e # t')"

    from vt_e and step_back_step have stp: "step (t'@s) e" by auto

    from vt_e and step_back_vt have vt_ts: "vt step (t'@s)" by auto

    show ?case

    proof(rule h2 [OF vt_ts stp _ _ _ ])

      show "R t'"

      proof(rule ih)

        from et show ext': "extend_highest s' th prio t'"

          by (unfold extend_highest_def extend_highest_axioms_def, auto dest:step_back_vt)

      next

        from vt_ts show "vt step (t' @ s)" .

      qed

    next

      from et show "extend_highest s' th prio (e # t')" .

    next

      from et show ext': "extend_highest s' th prio t'"

          by (unfold extend_highest_def extend_highest_axioms_def, auto dest:step_back_vt)

    qed

  qed

qed

lemma th_kept: "th \<in> threads (t @ s) \<and> 

        preced th (t@s) = preced th s" (is "?Q t")

proof -

  show ?thesis

  proof(induct rule:ind)

    case Nil

    from threads_s

    show "th \<in> threads ([] @ s) \<and> preced th ([] @ s) = preced th s"

      by auto

  next

    case (Cons e t)

    show ?case

    proof(cases e)

      case (Create thread prio)

      assume eq_e: " e = Create thread prio"

      show ?thesis

      proof -

        from Cons and eq_e have "step (t@s) (Create thread prio)" by auto

        hence "th \<noteq> thread"

        proof(cases)

          assume "thread \<notin> threads (t @ s)"

          with Cons show ?thesis by auto

        qed

        hence "preced th ((e # t) @ s)  = preced th (t @ s)"

          by (unfold eq_e, auto simp:preced_def)

        moreover note Cons

        ultimately show ?thesis

          by (auto simp:eq_e)

      qed

    next

      case (Exit thread)

      assume eq_e: "e = Exit thread"

      from Cons have "extend_highest s' th prio (e # t)" by auto

      from extend_highest.exit_diff [OF this] and eq_e

      have neq_th: "thread \<noteq> th" by auto

      with Cons

      show ?thesis

        by (unfold eq_e, auto simp:preced_def)

    next

      case (P thread cs)

      assume eq_e: "e = P thread cs"

      with Cons

      show ?thesis 

        by (auto simp:eq_e preced_def)

    next

      case (V thread cs)

      assume eq_e: "e = V thread cs"

      with Cons

      show ?thesis 

        by (auto simp:eq_e preced_def)

    next

      case (Set thread prio')

      assume eq_e: " e = Set thread prio'"

      show ?thesis

      proof -

        from Cons have "extend_highest s' th prio (e # t)" by auto

        from extend_highest.set_diff_low[OF this] and eq_e

        have "th \<noteq> thread" by auto

        hence "preced th ((e # t) @ s)  = preced th (t @ s)"

          by (unfold eq_e, auto simp:preced_def)

        moreover note Cons

        ultimately show ?thesis

          by (auto simp:eq_e)

      qed

    qed

  qed

qed

lemma max_kept: "Max ((\<lambda> th'. preced th' (t @ s)) ` (threads (t@s))) = preced th s"

proof(induct rule:ind)

  case Nil

  from highest_preced_thread

  show "Max ((\<lambda>th'. preced th' ([] @ s)) ` threads ([] @ s)) = preced th s"

    by simp

next

  case (Cons e t)

  show ?case

  proof(cases e)

    case (Create thread prio')

    assume eq_e: " e = Create thread prio'"

    from Cons and eq_e have stp: "step (t@s) (Create thread prio')" by auto

    hence neq_thread: "thread \<noteq> th"

    proof(cases)

      assume "thread \<notin> threads (t @ s)"

      moreover have "th \<in> threads (t@s)"

      proof -

        from Cons have "extend_highest s' th prio t" by auto

        from extend_highest.th_kept[OF this] show ?thesis by (simp add:s_def)

      qed

      ultimately show ?thesis by auto

    qed

    from Cons have "extend_highest s' th prio t" by auto

    from extend_highest.th_kept[OF this]

    have h': " th \<in> threads (t @ s) \<and> preced th (t @ s) = preced th s" 

      by (auto simp:s_def)

    from stp

    have thread_ts: "thread \<notin> threads (t @ s)"

      by (cases, auto)

    show ?thesis (is "Max (?f ` ?A) = ?t")

    proof -

      have "Max (?f ` ?A) = Max(insert (?f thread) (?f ` (threads (t@s))))"

        by (unfold eq_e, simp)

      moreover have "\<dots> = max (?f thread) (Max (?f ` (threads (t@s))))"

      proof(rule Max_insert)

        from Cons have "vt step (t @ s)" by auto

        from finite_threads[OF this]

        show "finite (?f ` (threads (t@s)))" by simp

      next

        from h' show "(?f ` (threads (t@s))) \<noteq> {}" by auto

      qed

      moreover have "(Max (?f ` (threads (t@s)))) = ?t"

      proof -

        have "(\<lambda>th'. preced th' ((e # t) @ s)) ` threads (t @ s) = 

          (\<lambda>th'. preced th' (t @ s)) ` threads (t @ s)" (is "?f1 ` ?B = ?f2 ` ?B")

        proof -

          { fix th' 

            assume "th' \<in> ?B"

            with thread_ts eq_e

            have "?f1 th' = ?f2 th'" by (auto simp:preced_def)

          } thus ?thesis 

            apply (auto simp:Image_def)

          proof -

            fix th'

            assume h: "\<And>th'. th' \<in> threads (t @ s) \<Longrightarrow> 

              preced th' (e # t @ s) = preced th' (t @ s)"

              and h1: "th' \<in> threads (t @ s)"

            show "preced th' (t @ s) \<in> (\<lambda>th'. preced th' (e # t @ s)) ` threads (t @ s)"

            proof -

              from h1 have "?f1 th' \<in> ?f1 ` ?B" by auto

              moreover from h[OF h1] have "?f1 th' = ?f2 th'" by simp

              ultimately show ?thesis by simp

            qed

          qed

        qed

        with Cons show ?thesis by auto

      qed

      moreover have "?f thread < ?t"

      proof -

        from Cons have " extend_highest s' th prio (e # t)" by auto

        from extend_highest.create_low[OF this] and eq_e

        have "prio' \<le> prio" by auto

        thus ?thesis

        by (unfold eq_e, auto simp:preced_def s_def precedence_less_def)

    qed

    ultimately show ?thesis by (auto simp:max_def)

  qed

next

    case (Exit thread)

    assume eq_e: "e = Exit thread"

    from Cons have vt_e: "vt step (e#(t @ s))" by auto

    from Cons and eq_e have stp: "step (t@s) (Exit thread)" by auto

    from stp have thread_ts: "thread \<in> threads (t @ s)"

      by(cases, unfold runing_def readys_def, auto)

    from Cons have "extend_highest s' th prio (e # t)" by auto

    from extend_highest.exit_diff[OF this] and eq_e

    have neq_thread: "thread \<noteq> th" by auto

    from Cons have "extend_highest s' th prio t" by auto

    from extend_highest.th_kept[OF this, folded s_def]

    have h': "th \<in> threads (t @ s) \<and> preced th (t @ s) = preced th s" .

    show ?thesis (is "Max (?f ` ?A) = ?t")

    proof -

      have "threads (t@s) = insert thread ?A"

        by (insert stp thread_ts, unfold eq_e, auto)

      hence "Max (?f ` (threads (t@s))) = Max (?f ` \<dots>)" by simp

      also from this have "\<dots> = Max (insert (?f thread) (?f ` ?A))" by simp

      also have "\<dots> = max (?f thread) (Max (?f ` ?A))"

      proof(rule Max_insert)

        from finite_threads [OF vt_e]

        show "finite (?f ` ?A)" by simp

      next

        from Cons have "extend_highest s' th prio (e # t)" by auto

        from extend_highest.th_kept[OF this]

        show "?f ` ?A \<noteq> {}" by  (auto simp:s_def)

      qed

      finally have "Max (?f ` (threads (t@s))) = max (?f thread) (Max (?f ` ?A))" .

      moreover have "Max (?f ` (threads (t@s))) = ?t"

      proof -

        from Cons show ?thesis

          by (unfold eq_e, auto simp:preced_def)

      qed

      ultimately have "max (?f thread) (Max (?f ` ?A)) = ?t" by simp

      moreover have "?f thread < ?t"

      proof(unfold eq_e, simp add:preced_def, fold preced_def)

        show "preced thread (t @ s) < ?t"

        proof -

          have "preced thread (t @ s) \<le> ?t" 

          proof -

            from Cons

            have "?t = Max ((\<lambda>th'. preced th' (t @ s)) ` threads (t @ s))" 

              (is "?t = Max (?g ` ?B)") by simp

            moreover have "?g thread \<le> \<dots>"

            proof(rule Max_ge)

              have "vt step (t@s)" by fact

              from finite_threads [OF this]

              show "finite (?g ` ?B)" by simp

            next

              from thread_ts

              show "?g thread \<in> (?g ` ?B)" by auto

            qed

            ultimately show ?thesis by auto

          qed

          moreover have "preced thread (t @ s) \<noteq> ?t"

          proof

            assume "preced thread (t @ s) = preced th s"

            with h' have "preced thread (t @ s) = preced th (t@s)" by simp

            from preced_unique [OF this] have "thread = th"

            proof

              from h' show "th \<in> threads (t @ s)" by simp

            next

              from thread_ts show "thread \<in> threads (t @ s)" .

            qed(simp)

            with neq_thread show "False" by simp

          qed

          ultimately show ?thesis by auto

        qed

      qed

      ultimately show ?thesis 

        by (auto simp:max_def split:if_splits)

    qed

  next

    case (P thread cs)

    with Cons

    show ?thesis by (auto simp:preced_def)

  next

    case (V thread cs)

    with Cons

    show ?thesis by (auto simp:preced_def)

  next

    case (Set thread prio')

    show ?thesis (is "Max (?f ` ?A) = ?t")

    proof -

      let ?B = "threads (t@s)"

      from Cons have "extend_highest s' th prio (e # t)" by auto

      from extend_highest.set_diff_low[OF this] and Set

      have neq_thread: "thread \<noteq> th" and le_p: "prio' \<le> prio" by auto

      from Set have "Max (?f ` ?A) = Max (?f ` ?B)" by simp

      also have "\<dots> = ?t"

      proof(rule Max_eqI)

        fix y

        assume y_in: "y \<in> ?f ` ?B"

        then obtain th1 where 

          th1_in: "th1 \<in> ?B" and eq_y: "y = ?f th1" by auto

        show "y \<le> ?t"

        proof(cases "th1 = thread")

          case True

          with neq_thread le_p eq_y s_def Set

          show ?thesis

            by (auto simp:preced_def precedence_le_def)

        next

          case False

          with Set eq_y

          have "y  = preced th1 (t@s)"

            by (simp add:preced_def)

          moreover have "\<dots> \<le> ?t"

          proof -

            from Cons

            have "?t = Max ((\<lambda> th'. preced th' (t@s)) ` (threads (t@s)))"

              by auto

            moreover have "preced th1 (t@s) \<le> \<dots>"

            proof(rule Max_ge)

              from th1_in 

              show "preced th1 (t @ s) \<in> (\<lambda>th'. preced th' (t @ s)) ` threads (t @ s)"

                by simp

            next

              show "finite ((\<lambda>th'. preced th' (t @ s)) ` threads (t @ s))"

              proof -

                from Cons have "vt step (t @ s)" by auto

                from finite_threads[OF this] show ?thesis by auto

              qed

            qed

            ultimately show ?thesis by auto

          qed

          ultimately show ?thesis by auto

        qed

      next

        from Cons and finite_threads