theory Abs

imports "../Nominal-General/Nominal2_Atoms" 

        "../Nominal-General/Nominal2_Eqvt" 

        "../Nominal-General/Nominal2_Supp" 

        "Quotient" 

        "Quotient_List"

        "Quotient_Product" 

begin

fun

  alpha_gen 

where

  alpha_gen[simp del]:

  "alpha_gen (bs, x) R f pi (cs, y) \<longleftrightarrow> 

     f x - bs = f y - cs \<and> 

     (f x - bs) \<sharp>* pi \<and> 

     R (pi \<bullet> x) y \<and>

     pi \<bullet> bs = cs"

fun

  alpha_res

where

  alpha_res[simp del]:

  "alpha_res (bs, x) R f pi (cs, y) \<longleftrightarrow> 

     f x - bs = f y - cs \<and> 

     (f x - bs) \<sharp>* pi \<and> 

     R (pi \<bullet> x) y"

fun

  alpha_lst

where

  alpha_lst[simp del]:

  "alpha_lst (bs, x) R f pi (cs, y) \<longleftrightarrow> 

     f x - set bs = f y - set cs \<and> 

     (f x - set bs) \<sharp>* pi \<and> 

     R (pi \<bullet> x) y \<and>

     pi \<bullet> bs = cs"

lemmas alphas = alpha_gen.simps alpha_res.simps alpha_lst.simps

notation

  alpha_gen ("_ \<approx>gen _ _ _ _" [100, 100, 100, 100, 100] 100) and

  alpha_res ("_ \<approx>res _ _ _ _" [100, 100, 100, 100, 100] 100) and

  alpha_lst ("_ \<approx>lst _ _ _ _" [100, 100, 100, 100, 100] 100) 

(* monos *)

lemma [mono]: 

  shows "R1 \<le> R2 \<Longrightarrow> alpha_gen bs R1 \<le> alpha_gen bs R2"

  and   "R1 \<le> R2 \<Longrightarrow> alpha_res bs R1 \<le> alpha_res bs R2"

  and   "R1 \<le> R2 \<Longrightarrow> alpha_lst cs R1 \<le> alpha_lst cs R2"

  by (case_tac [!] bs, case_tac [!] cs) 

     (auto simp add: le_fun_def le_bool_def alphas)

(* equivariance *)

lemma alpha_gen_eqvt[eqvt]:

  shows "(bs, x) \<approx>gen R f q (cs, y) \<Longrightarrow> (p \<bullet> bs, p \<bullet> x) \<approx>gen (p \<bullet> R) (p \<bullet> f) (p \<bullet> q) (p \<bullet> cs, p \<bullet> y)"

  and   "(bs, x) \<approx>res R f q (cs, y) \<Longrightarrow> (p \<bullet> bs, p \<bullet> x) \<approx>res (p \<bullet> R) (p \<bullet> f) (p \<bullet> q) (p \<bullet> cs, p \<bullet> y)"

  and   "(ds, x) \<approx>lst R f q (es, y) \<Longrightarrow> (p \<bullet> ds, p \<bullet> x) \<approx>lst (p \<bullet> R) (p \<bullet> f) (p \<bullet> q) (p \<bullet> es, p \<bullet> y)" 

  unfolding alphas

  unfolding permute_eqvt[symmetric]

  unfolding set_eqvt[symmetric]

  unfolding permute_fun_app_eq[symmetric]

  unfolding Diff_eqvt[symmetric]

  by (auto simp add: permute_bool_def fresh_star_permute_iff)

(* equivalence *)

lemma alpha_gen_refl:

  assumes a: "R x x"

  shows "(bs, x) \<approx>gen R f 0 (bs, x)"

  and   "(bs, x) \<approx>res R f 0 (bs, x)"

  and   "(cs, x) \<approx>lst R f 0 (cs, x)"

  using a 

  unfolding alphas

  unfolding fresh_star_def

  by (simp_all add: fresh_zero_perm)

lemma alpha_gen_sym:

  assumes a: "R (p \<bullet> x) y \<Longrightarrow> R (- p \<bullet> y) x"

  shows "(bs, x) \<approx>gen R f p (cs, y) \<Longrightarrow> (cs, y) \<approx>gen R f (- p) (bs, x)"

  and   "(bs, x) \<approx>res R f p (cs, y) \<Longrightarrow> (cs, y) \<approx>res R f (- p) (bs, x)"

  and   "(ds, x) \<approx>lst R f p (es, y) \<Longrightarrow> (es, y) \<approx>lst R f (- p) (ds, x)"

  unfolding alphas fresh_star_def

  using a

  by (auto simp add:  fresh_minus_perm)

lemma alpha_gen_sym_eqvt:

  assumes a: "R (p \<bullet> x) y \<Longrightarrow> R y (p \<bullet> x)" 

  and     b: "p \<bullet> R = R"

  shows "(bs, x) \<approx>gen R f p (cs, y) \<Longrightarrow> (cs, y) \<approx>gen R f (- p) (bs, x)" 

  and   "(bs, x) \<approx>res R f p (cs, y) \<Longrightarrow> (cs, y) \<approx>res R f (- p) (bs, x)" 

  and   "(ds, x) \<approx>lst R f p (es, y) \<Longrightarrow> (es, y) \<approx>lst R f (- p) (ds, x)"

apply(auto intro!: alpha_gen_sym)

apply(drule_tac [!] a)

apply(rule_tac [!] p="p" in permute_boolE)

apply(perm_simp add: permute_minus_cancel b)

apply(assumption)

apply(perm_simp add: permute_minus_cancel b)

apply(assumption)

apply(perm_simp add: permute_minus_cancel b)

apply(assumption)

done

lemma alpha_gen_trans:

  assumes a: "\<lbrakk>R (p \<bullet> x) y; R (q \<bullet> y) z\<rbrakk> \<Longrightarrow> R ((q + p) \<bullet> x) z"

  shows "\<lbrakk>(bs, x) \<approx>gen R f p (cs, y); (cs, y) \<approx>gen R f q (ds, z)\<rbrakk> \<Longrightarrow> (bs, x) \<approx>gen R f (q + p) (ds, z)"

  and   "\<lbrakk>(bs, x) \<approx>res R f p (cs, y); (cs, y) \<approx>res R f q (ds, z)\<rbrakk> \<Longrightarrow> (bs, x) \<approx>res R f (q + p) (ds, z)"

  and   "\<lbrakk>(es, x) \<approx>lst R f p (gs, y); (gs, y) \<approx>lst R f q (hs, z)\<rbrakk> \<Longrightarrow> (es, x) \<approx>lst R f (q + p) (hs, z)"

  using a

  unfolding alphas fresh_star_def

  by (simp_all add: fresh_plus_perm)

lemma alpha_gen_trans_eqvt:

  assumes b: "(cs, y) \<approx>gen R f q (ds, z)"

  and     a: "(bs, x) \<approx>gen R f p (cs, y)" 

  and     d: "q \<bullet> R = R"

  and     c: "\<lbrakk>R (p \<bullet> x) y; R y (- q \<bullet> z)\<rbrakk> \<Longrightarrow> R (p \<bullet> x) (- q \<bullet> z)"

  shows "(bs, x) \<approx>gen R f (q + p) (ds, z)"

apply(rule alpha_gen_trans)

defer

apply(rule a)

apply(rule b)

apply(drule c)

apply(rule_tac p="q" in permute_boolE)

apply(perm_simp add: permute_minus_cancel d)

apply(assumption)

apply(rotate_tac -1)

apply(drule_tac p="q" in permute_boolI)

apply(perm_simp add: permute_minus_cancel d)

apply(simp add: permute_eqvt[symmetric])

done

lemma alpha_res_trans_eqvt:

  assumes  b: "(cs, y) \<approx>res R f q (ds, z)"

  and     a: "(bs, x) \<approx>res R f p (cs, y)" 

  and     d: "q \<bullet> R = R"

  and     c: "\<lbrakk>R (p \<bullet> x) y; R y (- q \<bullet> z)\<rbrakk> \<Longrightarrow> R (p \<bullet> x) (- q \<bullet> z)"

  shows "(bs, x) \<approx>res R f (q + p) (ds, z)"

apply(rule alpha_gen_trans)

defer

apply(rule a)

apply(rule b)

apply(drule c)

apply(rule_tac p="q" in permute_boolE)

apply(perm_simp add: permute_minus_cancel d)

apply(assumption)

apply(rotate_tac -1)

apply(drule_tac p="q" in permute_boolI)

apply(perm_simp add: permute_minus_cancel d)

apply(simp add: permute_eqvt[symmetric])

done

lemma alpha_lst_trans_eqvt:

  assumes b: "(cs, y) \<approx>lst R f q (ds, z)"

  and     a: "(bs, x) \<approx>lst R f p (cs, y)" 

  and     d: "q \<bullet> R = R"

  and     c: "\<lbrakk>R (p \<bullet> x) y; R y (- q \<bullet> z)\<rbrakk> \<Longrightarrow> R (p \<bullet> x) (- q \<bullet> z)"

  shows "(bs, x) \<approx>lst R f (q + p) (ds, z)"

apply(rule alpha_gen_trans)

defer

apply(rule a)

apply(rule b)

apply(drule c)

apply(rule_tac p="q" in permute_boolE)

apply(perm_simp add: permute_minus_cancel d)

apply(assumption)

apply(rotate_tac -1)

apply(drule_tac p="q" in permute_boolI)

apply(perm_simp add: permute_minus_cancel d)

apply(simp add: permute_eqvt[symmetric])

done

lemmas alpha_trans_eqvt = alpha_gen_trans_eqvt alpha_res_trans_eqvt alpha_lst_trans_eqvt

lemma test:

  shows "(as, t) \<approx>gen R f pi (bs, s) \<Longrightarrow> R (pi \<bullet> t) s"

  and   "(as, t) \<approx>res R f pi (bs, s) \<Longrightarrow> R (pi \<bullet> t) s"

  and   "(cs, t) \<approx>lst R f pi (ds, s) \<Longrightarrow> R (pi \<bullet> t) s"

  by (simp_all add: alphas)

section {* General Abstractions *}

fun

  alpha_abs 

where

  [simp del]:

  "alpha_abs (bs, x) (cs, y) \<longleftrightarrow> (\<exists>p. (bs, x) \<approx>gen (op=) supp p (cs, y))"

fun

  alpha_abs_lst

where

  [simp del]:

  "alpha_abs_lst (bs, x) (cs, y) \<longleftrightarrow> (\<exists>p. (bs, x) \<approx>lst (op=) supp p (cs, y))"

fun

  alpha_abs_res

where

  [simp del]:

  "alpha_abs_res (bs, x) (cs, y) \<longleftrightarrow> (\<exists>p. (bs, x) \<approx>res (op=) supp p (cs, y))"

notation

  alpha_abs (infix "\<approx>abs" 50) and

  alpha_abs_lst (infix "\<approx>abs'_lst" 50) and

  alpha_abs_res (infix "\<approx>abs'_res" 50)

lemmas alphas_abs = alpha_abs.simps alpha_abs_res.simps alpha_abs_lst.simps

lemma alphas_abs_refl:

  shows "(bs, x) \<approx>abs (bs, x)"

  and   "(bs, x) \<approx>abs_res (bs, x)"

  and   "(cs, x) \<approx>abs_lst (cs, x)" 

  unfolding alphas_abs

  unfolding alphas

  unfolding fresh_star_def

  by (rule_tac [!] x="0" in exI)

     (simp_all add: fresh_zero_perm)

lemma alphas_abs_sym:

  shows "(bs, x) \<approx>abs (cs, y) \<Longrightarrow> (cs, y) \<approx>abs (bs, x)"

  and   "(bs, x) \<approx>abs_res (cs, y) \<Longrightarrow> (cs, y) \<approx>abs_res (bs, x)"

  and   "(ds, x) \<approx>abs_lst (es, y) \<Longrightarrow> (es, y) \<approx>abs_lst (ds, x)"

  unfolding alphas_abs

  unfolding alphas

  unfolding fresh_star_def

  by (erule_tac [!] exE, rule_tac [!] x="-p" in exI)

     (auto simp add: fresh_minus_perm)

lemma alphas_abs_trans:

  shows "\<lbrakk>(bs, x) \<approx>abs (cs, y); (cs, y) \<approx>abs (ds, z)\<rbrakk> \<Longrightarrow> (bs, x) \<approx>abs (ds, z)"

  and   "\<lbrakk>(bs, x) \<approx>abs_res (cs, y); (cs, y) \<approx>abs_res (ds, z)\<rbrakk> \<Longrightarrow> (bs, x) \<approx>abs_res (ds, z)"

  and   "\<lbrakk>(es, x) \<approx>abs_lst (gs, y); (gs, y) \<approx>abs_lst (hs, z)\<rbrakk> \<Longrightarrow> (es, x) \<approx>abs_lst (hs, z)"

  unfolding alphas_abs

  unfolding alphas

  unfolding fresh_star_def

  apply(erule_tac [!] exE, erule_tac [!] exE)

  apply(rule_tac [!] x="pa + p" in exI)

  by (simp_all add: fresh_plus_perm)

lemma alphas_abs_eqvt:

  shows "(bs, x) \<approx>abs (cs, y) \<Longrightarrow> (p \<bullet> bs, p \<bullet> x) \<approx>abs (p \<bullet> cs, p \<bullet> y)"

  and   "(bs, x) \<approx>abs_res (cs, y) \<Longrightarrow> (p \<bullet> bs, p \<bullet> x) \<approx>abs_res (p \<bullet> cs, p \<bullet> y)"

  and   "(ds, x) \<approx>abs_lst (es, y) \<Longrightarrow> (p \<bullet> ds, p \<bullet> x) \<approx>abs_lst (p \<bullet> es, p \<bullet> y)"

  unfolding alphas_abs

  unfolding alphas

  unfolding set_eqvt[symmetric]

  unfolding supp_eqvt[symmetric]

  unfolding Diff_eqvt[symmetric]

  apply(erule_tac [!] exE)

  apply(rule_tac [!] x="p \<bullet> pa" in exI)

  by (auto simp add: fresh_star_permute_iff permute_eqvt[symmetric])

quotient_type 

    'a abs_gen = "(atom set \<times> 'a::pt)" / "alpha_abs"

and 'b abs_res = "(atom set \<times> 'b::pt)" / "alpha_abs_res"

and 'c abs_lst = "(atom list \<times> 'c::pt)" / "alpha_abs_lst"

  apply(rule_tac [!] equivpI)

  unfolding reflp_def symp_def transp_def

  by (auto intro: alphas_abs_sym alphas_abs_refl alphas_abs_trans simp only:)

quotient_definition

  Abs ("[_]set. _" [60, 60] 60)

where

  "Abs::atom set \<Rightarrow> ('a::pt) \<Rightarrow> 'a abs_gen"

is

  "Pair::atom set \<Rightarrow> ('a::pt) \<Rightarrow> (atom set \<times> 'a)"

quotient_definition

  Abs_res ("[_]res. _" [60, 60] 60)

where

  "Abs_res::atom set \<Rightarrow> ('a::pt) \<Rightarrow> 'a abs_res"

is

  "Pair::atom set \<Rightarrow> ('a::pt) \<Rightarrow> (atom set \<times> 'a)"

quotient_definition

  Abs_lst ("[_]lst. _" [60, 60] 60)

where

  "Abs_lst::atom list \<Rightarrow> ('a::pt) \<Rightarrow> 'a abs_lst"

is

  "Pair::atom list \<Rightarrow> ('a::pt) \<Rightarrow> (atom list \<times> 'a)"

lemma [quot_respect]:

  shows "(op= ===> op= ===> alpha_abs) Pair Pair"

  and   "(op= ===> op= ===> alpha_abs_res) Pair Pair"

  and   "(op= ===> op= ===> alpha_abs_lst) Pair Pair"

  unfolding fun_rel_def

  by (auto intro: alphas_abs_refl simp only:)

lemma [quot_respect]:

  shows "(op= ===> alpha_abs ===> alpha_abs) permute permute"

  and   "(op= ===> alpha_abs_res ===> alpha_abs_res) permute permute"

  and   "(op= ===> alpha_abs_lst ===> alpha_abs_lst) permute permute"

  unfolding fun_rel_def

  by (auto intro: alphas_abs_eqvt simp only: Pair_eqvt)

lemma abs_exhausts:

  shows "(\<And>as (x::'a::pt). y1 = Abs as x \<Longrightarrow> P1) \<Longrightarrow> P1"

  and   "(\<And>as (x::'a::pt). y2 = Abs_res as x \<Longrightarrow> P2) \<Longrightarrow> P2"

  and   "(\<And>as (x::'a::pt). y3 = Abs_lst as x \<Longrightarrow> P3) \<Longrightarrow> P3"

  by (lifting prod.exhaust[where 'a="atom set" and 'b="'a"]

              prod.exhaust[where 'a="atom set" and 'b="'a"]

              prod.exhaust[where 'a="atom list" and 'b="'a"])

lemma abs_eq_iff:

  shows "Abs bs x = Abs cs y \<longleftrightarrow> (bs, x) \<approx>abs (cs, y)"

  and   "Abs_res bs x = Abs_res cs y \<longleftrightarrow> (bs, x) \<approx>abs_res (cs, y)"

  and   "Abs_lst ds x = Abs_lst hs y \<longleftrightarrow> (ds, x) \<approx>abs_lst (hs, y)"

  unfolding alphas_abs

  by (lifting alphas_abs)

instantiation abs_gen :: (pt) pt

begin

quotient_definition

  "permute_abs_gen::perm \<Rightarrow> ('a::pt abs_gen) \<Rightarrow> 'a abs_gen"

is

  "permute:: perm \<Rightarrow> (atom set \<times> 'a::pt) \<Rightarrow> (atom set \<times> 'a::pt)"

lemma permute_Abs[simp]:

  fixes x::"'a::pt"  

  shows "(p \<bullet> (Abs as x)) = Abs (p \<bullet> as) (p \<bullet> x)"

  by (lifting permute_prod.simps[where 'a="atom set" and 'b="'a"])

instance

  apply(default)

  apply(case_tac [!] x rule: abs_exhausts(1))

  apply(simp_all)

  done

end

instantiation abs_res :: (pt) pt

begin

quotient_definition

  "permute_abs_res::perm \<Rightarrow> ('a::pt abs_res) \<Rightarrow> 'a abs_res"

is

  "permute:: perm \<Rightarrow> (atom set \<times> 'a::pt) \<Rightarrow> (atom set \<times> 'a::pt)"

lemma permute_Abs_res[simp]:

  fixes x::"'a::pt"  

  shows "(p \<bullet> (Abs_res as x)) = Abs_res (p \<bullet> as) (p \<bullet> x)"

  by (lifting permute_prod.simps[where 'a="atom set" and 'b="'a"])

instance

  apply(default)

  apply(case_tac [!] x rule: abs_exhausts(2))

  apply(simp_all)

  done

end

instantiation abs_lst :: (pt) pt

begin

quotient_definition

  "permute_abs_lst::perm \<Rightarrow> ('a::pt abs_lst) \<Rightarrow> 'a abs_lst"

is

  "permute:: perm \<Rightarrow> (atom list \<times> 'a::pt) \<Rightarrow> (atom list \<times> 'a::pt)"

lemma permute_Abs_lst[simp]:

  fixes x::"'a::pt"  

  shows "(p \<bullet> (Abs_lst as x)) = Abs_lst (p \<bullet> as) (p \<bullet> x)"

  by (lifting permute_prod.simps[where 'a="atom list" and 'b="'a"])

instance

  apply(default)

  apply(case_tac [!] x rule: abs_exhausts(3))

  apply(simp_all)

  done

end

lemmas permute_abs = permute_Abs permute_Abs_res permute_Abs_lst

lemma abs_swap1:

  assumes a1: "a \<notin> (supp x) - bs"

  and     a2: "b \<notin> (supp x) - bs"

  shows "Abs bs x = Abs ((a \<rightleftharpoons> b) \<bullet> bs) ((a \<rightleftharpoons> b) \<bullet> x)"

  and   "Abs_res bs x = Abs_res ((a \<rightleftharpoons> b) \<bullet> bs) ((a \<rightleftharpoons> b) \<bullet> x)"

  unfolding abs_eq_iff

  unfolding alphas_abs

  unfolding alphas

  unfolding supp_eqvt[symmetric] Diff_eqvt[symmetric] 

  unfolding fresh_star_def fresh_def

  unfolding swap_set_not_in[OF a1 a2] 

  using a1 a2

  by (rule_tac [!] x="(a \<rightleftharpoons> b)" in exI)

     (auto simp add: supp_perm swap_atom)

lemma abs_swap2:

  assumes a1: "a \<notin> (supp x) - (set bs)"

  and     a2: "b \<notin> (supp x) - (set bs)"

  shows "Abs_lst bs x = Abs_lst ((a \<rightleftharpoons> b) \<bullet> bs) ((a \<rightleftharpoons> b) \<bullet> x)"

  unfolding abs_eq_iff

  unfolding alphas_abs

  unfolding alphas

  unfolding supp_eqvt[symmetric] Diff_eqvt[symmetric] set_eqvt[symmetric]

  unfolding fresh_star_def fresh_def

  unfolding swap_set_not_in[OF a1 a2]

  using a1 a2

  by (rule_tac [!] x="(a \<rightleftharpoons> b)" in exI)

     (auto simp add: supp_perm swap_atom)

lemma abs_supports:

  shows "((supp x) - as) supports (Abs as x)"

  and   "((supp x) - as) supports (Abs_res as x)"

  and   "((supp x) - (set bs)) supports (Abs_lst bs x)"

  unfolding supports_def

  unfolding permute_abs

  by (simp_all add: abs_swap1[symmetric] abs_swap2[symmetric])

function

  supp_gen  :: "('a::pt) abs_gen \<Rightarrow> atom set"

where

  "supp_gen (Abs as x) = supp x - as"

apply(case_tac x rule: abs_exhausts(1))

apply(simp)

apply(simp add: abs_eq_iff alphas_abs alphas)

done

termination supp_gen 

  by (auto intro!: local.termination)

function

  supp_res :: "('a::pt) abs_res \<Rightarrow> atom set"

where

  "supp_res (Abs_res as x) = supp x - as"

apply(case_tac x rule: abs_exhausts(2))

apply(simp)

apply(simp add: abs_eq_iff alphas_abs alphas)

done

termination supp_res 

  by (auto intro!: local.termination)

function

  supp_lst :: "('a::pt) abs_lst \<Rightarrow> atom set"

where

  "supp_lst (Abs_lst cs x) = (supp x) - (set cs)"

apply(case_tac x rule: abs_exhausts(3))

apply(simp)

apply(simp add: abs_eq_iff alphas_abs alphas)

done

termination supp_lst 

  by (auto intro!: local.termination)

lemma [eqvt]:

  shows "(p \<bullet> supp_gen x) = supp_gen (p \<bullet> x)"

  and   "(p \<bullet> supp_res y) = supp_res (p \<bullet> y)"

  and   "(p \<bullet> supp_lst z) = supp_lst (p \<bullet> z)"

  apply(case_tac x rule: abs_exhausts(1))

  apply(simp add: supp_eqvt Diff_eqvt)

  apply(case_tac y rule: abs_exhausts(2))

  apply(simp add: supp_eqvt Diff_eqvt)

  apply(case_tac z rule: abs_exhausts(3))

  apply(simp add: supp_eqvt Diff_eqvt set_eqvt)

  done

lemma aux_fresh:

  shows "a \<sharp> Abs bs x \<Longrightarrow> a \<sharp> supp_gen (Abs bs x)"

  and   "a \<sharp> Abs_res bs x \<Longrightarrow> a \<sharp> supp_res (Abs_res bs x)"

  and   "a \<sharp> Abs_lst cs x \<Longrightarrow> a \<sharp> supp_lst (Abs_lst cs x)"

  by (rule_tac [!] fresh_fun_eqvt_app)

     (simp_all add: eqvts_raw)

lemma supp_abs_subset1:

  assumes a: "finite (supp x)"

  shows "(supp x) - as \<subseteq> supp (Abs as x)"

  and   "(supp x) - as \<subseteq> supp (Abs_res as x)"

  and   "(supp x) - (set bs) \<subseteq> supp (Abs_lst bs x)"

  unfolding supp_conv_fresh

  by (auto dest!: aux_fresh)

     (simp_all add: fresh_def supp_finite_atom_set a)

lemma supp_abs_subset2:

  assumes a: "finite (supp x)"

  shows "supp (Abs as x) \<subseteq> (supp x) - as"

  and   "supp (Abs_res as x) \<subseteq> (supp x) - as"

  and   "supp (Abs_lst bs x) \<subseteq> (supp x) - (set bs)"

  by (rule_tac [!] supp_is_subset)

     (simp_all add: abs_supports a)

lemma abs_finite_supp:

  assumes a: "finite (supp x)"

  shows "supp (Abs as x) = (supp x) - as"

  and   "supp (Abs_res as x) = (supp x) - as"

  and   "supp (Abs_lst bs x) = (supp x) - (set bs)"

  by (rule_tac [!] subset_antisym)

     (simp_all add: supp_abs_subset1[OF a] supp_abs_subset2[OF a])