theory SizeBound4
imports "Lexer" "PDerivs"
begin
section \<open>Bit-Encodings\<close>
datatype bit = Z | S
fun code :: "val \<Rightarrow> bit list"
where
"code Void = []"
| "code (Char c) = []"
| "code (Left v) = Z # (code v)"
| "code (Right v) = S # (code v)"
| "code (Seq v1 v2) = (code v1) @ (code v2)"
| "code (Stars []) = [S]"
| "code (Stars (v # vs)) = (Z # code v) @ code (Stars vs)"
fun
Stars_add :: "val \<Rightarrow> val \<Rightarrow> val"
where
"Stars_add v (Stars vs) = Stars (v # vs)"
function
decode' :: "bit list \<Rightarrow> rexp \<Rightarrow> (val * bit list)"
where
"decode' bs ZERO = (undefined, bs)"
| "decode' bs ONE = (Void, bs)"
| "decode' bs (CH d) = (Char d, bs)"
| "decode' [] (ALT r1 r2) = (Void, [])"
| "decode' (Z # bs) (ALT r1 r2) = (let (v, bs') = decode' bs r1 in (Left v, bs'))"
| "decode' (S # bs) (ALT r1 r2) = (let (v, bs') = decode' bs r2 in (Right v, bs'))"
| "decode' bs (SEQ r1 r2) = (let (v1, bs') = decode' bs r1 in
let (v2, bs'') = decode' bs' r2 in (Seq v1 v2, bs''))"
| "decode' [] (STAR r) = (Void, [])"
| "decode' (S # bs) (STAR r) = (Stars [], bs)"
| "decode' (Z # bs) (STAR r) = (let (v, bs') = decode' bs r in
let (vs, bs'') = decode' bs' (STAR r)
in (Stars_add v vs, bs''))"
by pat_completeness auto
lemma decode'_smaller:
assumes "decode'_dom (bs, r)"
shows "length (snd (decode' bs r)) \<le> length bs"
using assms
apply(induct bs r)
apply(auto simp add: decode'.psimps split: prod.split)
using dual_order.trans apply blast
by (meson dual_order.trans le_SucI)
termination "decode'"
apply(relation "inv_image (measure(%cs. size cs) <*lex*> measure(%s. size s)) (%(ds,r). (r,ds))")
apply(auto dest!: decode'_smaller)
by (metis less_Suc_eq_le snd_conv)
definition
decode :: "bit list \<Rightarrow> rexp \<Rightarrow> val option"
where
"decode ds r \<equiv> (let (v, ds') = decode' ds r
in (if ds' = [] then Some v else None))"
lemma decode'_code_Stars:
assumes "\<forall>v\<in>set vs. \<Turnstile> v : r \<and> (\<forall>x. decode' (code v @ x) r = (v, x)) \<and> flat v \<noteq> []"
shows "decode' (code (Stars vs) @ ds) (STAR r) = (Stars vs, ds)"
using assms
apply(induct vs)
apply(auto)
done
lemma decode'_code:
assumes "\<Turnstile> v : r"
shows "decode' ((code v) @ ds) r = (v, ds)"
using assms
apply(induct v r arbitrary: ds)
apply(auto)
using decode'_code_Stars by blast
lemma decode_code:
assumes "\<Turnstile> v : r"
shows "decode (code v) r = Some v"
using assms unfolding decode_def
by (smt append_Nil2 decode'_code old.prod.case)
section {* Annotated Regular Expressions *}
datatype arexp =
AZERO
| AONE "bit list"
| ACHAR "bit list" char
| ASEQ "bit list" arexp arexp
| AALTs "bit list" "arexp list"
| ASTAR "bit list" arexp
abbreviation
"AALT bs r1 r2 \<equiv> AALTs bs [r1, r2]"
fun asize :: "arexp \<Rightarrow> nat" where
"asize AZERO = 1"
| "asize (AONE cs) = 1"
| "asize (ACHAR cs c) = 1"
| "asize (AALTs cs rs) = Suc (sum_list (map asize rs))"
| "asize (ASEQ cs r1 r2) = Suc (asize r1 + asize r2)"
| "asize (ASTAR cs r) = Suc (asize r)"
fun
erase :: "arexp \<Rightarrow> rexp"
where
"erase AZERO = ZERO"
| "erase (AONE _) = ONE"
| "erase (ACHAR _ c) = CH c"
| "erase (AALTs _ []) = ZERO"
| "erase (AALTs _ [r]) = (erase r)"
| "erase (AALTs bs (r#rs)) = ALT (erase r) (erase (AALTs bs rs))"
| "erase (ASEQ _ r1 r2) = SEQ (erase r1) (erase r2)"
| "erase (ASTAR _ r) = STAR (erase r)"
fun fuse :: "bit list \<Rightarrow> arexp \<Rightarrow> arexp" where
"fuse bs AZERO = AZERO"
| "fuse bs (AONE cs) = AONE (bs @ cs)"
| "fuse bs (ACHAR cs c) = ACHAR (bs @ cs) c"
| "fuse bs (AALTs cs rs) = AALTs (bs @ cs) rs"
| "fuse bs (ASEQ cs r1 r2) = ASEQ (bs @ cs) r1 r2"
| "fuse bs (ASTAR cs r) = ASTAR (bs @ cs) r"
lemma fuse_append:
shows "fuse (bs1 @ bs2) r = fuse bs1 (fuse bs2 r)"
apply(induct r)
apply(auto)
done
fun intern :: "rexp \<Rightarrow> arexp" where
"intern ZERO = AZERO"
| "intern ONE = AONE []"
| "intern (CH c) = ACHAR [] c"
| "intern (ALT r1 r2) = AALT [] (fuse [Z] (intern r1))
(fuse [S] (intern r2))"
| "intern (SEQ r1 r2) = ASEQ [] (intern r1) (intern r2)"
| "intern (STAR r) = ASTAR [] (intern r)"
fun retrieve :: "arexp \<Rightarrow> val \<Rightarrow> bit list" where
"retrieve (AONE bs) Void = bs"
| "retrieve (ACHAR bs c) (Char d) = bs"
| "retrieve (AALTs bs [r]) v = bs @ retrieve r v"
| "retrieve (AALTs bs (r#rs)) (Left v) = bs @ retrieve r v"
| "retrieve (AALTs bs (r#rs)) (Right v) = bs @ retrieve (AALTs [] rs) v"
| "retrieve (ASEQ bs r1 r2) (Seq v1 v2) = bs @ retrieve r1 v1 @ retrieve r2 v2"
| "retrieve (ASTAR bs r) (Stars []) = bs @ [S]"
| "retrieve (ASTAR bs r) (Stars (v#vs)) =
bs @ [Z] @ retrieve r v @ retrieve (ASTAR [] r) (Stars vs)"
fun
bnullable :: "arexp \<Rightarrow> bool"
where
"bnullable (AZERO) = False"
| "bnullable (AONE bs) = True"
| "bnullable (ACHAR bs c) = False"
| "bnullable (AALTs bs rs) = (\<exists>r \<in> set rs. bnullable r)"
| "bnullable (ASEQ bs r1 r2) = (bnullable r1 \<and> bnullable r2)"
| "bnullable (ASTAR bs r) = True"
abbreviation
bnullables :: "arexp list \<Rightarrow> bool"
where
"bnullables rs \<equiv> (\<exists>r \<in> set rs. bnullable r)"
fun
bmkeps :: "arexp \<Rightarrow> bit list" and
bmkepss :: "arexp list \<Rightarrow> bit list"
where
"bmkeps(AONE bs) = bs"
| "bmkeps(ASEQ bs r1 r2) = bs @ (bmkeps r1) @ (bmkeps r2)"
| "bmkeps(AALTs bs rs) = bs @ (bmkepss rs)"
| "bmkeps(ASTAR bs r) = bs @ [S]"
(*| "bmkepss [] = []"*)
| "bmkepss (r # rs) = (if bnullable(r) then (bmkeps r) else (bmkepss rs))"
lemma bmkepss1:
assumes "\<not> bnullables rs1"
shows "bmkepss (rs1 @ rs2) = bmkepss rs2"
using assms
by (induct rs1) (auto)
lemma bmkepss2:
assumes "bnullables rs1"
shows "bmkepss (rs1 @ rs2) = bmkepss rs1"
using assms
by (induct rs1) (auto)
fun
bder :: "char \<Rightarrow> arexp \<Rightarrow> arexp"
where
"bder c (AZERO) = AZERO"
| "bder c (AONE bs) = AZERO"
| "bder c (ACHAR bs d) = (if c = d then AONE bs else AZERO)"
| "bder c (AALTs bs rs) = AALTs bs (map (bder c) rs)"
| "bder c (ASEQ bs r1 r2) =
(if bnullable r1
then AALT bs (ASEQ [] (bder c r1) r2) (fuse (bmkeps r1) (bder c r2))
else ASEQ bs (bder c r1) r2)"
| "bder c (ASTAR bs r) = ASEQ (bs @ [Z]) (bder c r) (ASTAR [] r)"
fun
bders :: "arexp \<Rightarrow> string \<Rightarrow> arexp"
where
"bders r [] = r"
| "bders r (c#s) = bders (bder c r) s"
lemma bders_append:
"bders c (s1 @ s2) = bders (bders c s1) s2"
apply(induct s1 arbitrary: c s2)
apply(simp_all)
done
lemma bnullable_correctness:
shows "nullable (erase r) = bnullable r"
apply(induct r rule: erase.induct)
apply(simp_all)
done
lemma erase_fuse:
shows "erase (fuse bs r) = erase r"
apply(induct r rule: erase.induct)
apply(simp_all)
done
lemma erase_intern [simp]:
shows "erase (intern r) = r"
apply(induct r)
apply(simp_all add: erase_fuse)
done
lemma erase_bder [simp]:
shows "erase (bder a r) = der a (erase r)"
apply(induct r rule: erase.induct)
apply(simp_all add: erase_fuse bnullable_correctness)
done
lemma erase_bders [simp]:
shows "erase (bders r s) = ders s (erase r)"
apply(induct s arbitrary: r )
apply(simp_all)
done
lemma bnullable_fuse:
shows "bnullable (fuse bs r) = bnullable r"
apply(induct r arbitrary: bs)
apply(auto)
done
lemma retrieve_encode_STARS:
assumes "\<forall>v\<in>set vs. \<Turnstile> v : r \<and> code v = retrieve (intern r) v"
shows "code (Stars vs) = retrieve (ASTAR [] (intern r)) (Stars vs)"
using assms
apply(induct vs)
apply(simp_all)
done
lemma retrieve_fuse2:
assumes "\<Turnstile> v : (erase r)"
shows "retrieve (fuse bs r) v = bs @ retrieve r v"
using assms
apply(induct r arbitrary: v bs)
apply(auto elim: Prf_elims)[4]
apply(case_tac x2a)
apply(simp)
using Prf_elims(1) apply blast
apply(case_tac x2a)
apply(simp)
apply(simp)
apply(case_tac list)
apply(simp)
apply(simp)
apply (smt (verit, best) Prf_elims(3) append_assoc retrieve.simps(4) retrieve.simps(5))
apply(simp)
using retrieve_encode_STARS
apply(auto elim!: Prf_elims)[1]
apply(case_tac vs)
apply(simp)
apply(simp)
done
lemma retrieve_fuse:
assumes "\<Turnstile> v : r"
shows "retrieve (fuse bs (intern r)) v = bs @ retrieve (intern r) v"
using assms
by (simp_all add: retrieve_fuse2)
lemma retrieve_code:
assumes "\<Turnstile> v : r"
shows "code v = retrieve (intern r) v"
using assms
apply(induct v r )
apply(simp_all add: retrieve_fuse retrieve_encode_STARS)
done
lemma retrieve_AALTs_bnullable1:
assumes "bnullable r"
shows "retrieve (AALTs bs (r # rs)) (mkeps (erase (AALTs bs (r # rs))))
= bs @ retrieve r (mkeps (erase r))"
using assms
apply(case_tac rs)
apply(auto simp add: bnullable_correctness)
done
lemma retrieve_AALTs_bnullable2:
assumes "\<not>bnullable r" "bnullables rs"
shows "retrieve (AALTs bs (r # rs)) (mkeps (erase (AALTs bs (r # rs))))
= retrieve (AALTs bs rs) (mkeps (erase (AALTs bs rs)))"
using assms
apply(induct rs arbitrary: r bs)
apply(auto)
using bnullable_correctness apply blast
apply(case_tac rs)
apply(auto)
using bnullable_correctness apply blast
apply(case_tac rs)
apply(auto)
done
lemma bmkeps_retrieve_AALTs:
assumes "\<forall>r \<in> set rs. bnullable r \<longrightarrow> bmkeps r = retrieve r (mkeps (erase r))"
"bnullables rs"
shows "bs @ bmkepss rs = retrieve (AALTs bs rs) (mkeps (erase (AALTs bs rs)))"
using assms
apply(induct rs arbitrary: bs)
apply(auto)
using retrieve_AALTs_bnullable1 apply presburger
apply (metis retrieve_AALTs_bnullable2)
apply (simp add: retrieve_AALTs_bnullable1)
by (metis retrieve_AALTs_bnullable2)
lemma bmkeps_retrieve:
assumes "bnullable r"
shows "bmkeps r = retrieve r (mkeps (erase r))"
using assms
apply(induct r)
apply(auto)
using bmkeps_retrieve_AALTs by auto
lemma bder_retrieve:
assumes "\<Turnstile> v : der c (erase r)"
shows "retrieve (bder c r) v = retrieve r (injval (erase r) c v)"
using assms
apply(induct r arbitrary: v rule: erase.induct)
using Prf_elims(1) apply auto[1]
using Prf_elims(1) apply auto[1]
apply(auto)[1]
apply (metis Prf_elims(4) injval.simps(1) retrieve.simps(1) retrieve.simps(2))
using Prf_elims(1) apply blast
(* AALTs case *)
apply(simp)
apply(erule Prf_elims)
apply(simp)
apply(simp)
apply(rename_tac "r\<^sub>1" "r\<^sub>2" rs v)
apply(erule Prf_elims)
apply(simp)
apply(simp)
apply(case_tac rs)
apply(simp)
apply(simp)
using Prf_elims(3) apply fastforce
(* ASEQ case *)
apply(simp)
apply(case_tac "nullable (erase r1)")
apply(simp)
apply(erule Prf_elims)
using Prf_elims(2) bnullable_correctness apply force
apply (simp add: bmkeps_retrieve bnullable_correctness retrieve_fuse2)
apply (simp add: bmkeps_retrieve bnullable_correctness retrieve_fuse2)
using Prf_elims(2) apply force
(* ASTAR case *)
apply(rename_tac bs r v)
apply(simp)
apply(erule Prf_elims)
apply(clarify)
apply(erule Prf_elims)
apply(clarify)
by (simp add: retrieve_fuse2)
lemma MAIN_decode:
assumes "\<Turnstile> v : ders s r"
shows "Some (flex r id s v) = decode (retrieve (bders (intern r) s) v) r"
using assms
proof (induct s arbitrary: v rule: rev_induct)
case Nil
have "\<Turnstile> v : ders [] r" by fact
then have "\<Turnstile> v : r" by simp
then have "Some v = decode (retrieve (intern r) v) r"
using decode_code retrieve_code by auto
then show "Some (flex r id [] v) = decode (retrieve (bders (intern r) []) v) r"
by simp
next
case (snoc c s v)
have IH: "\<And>v. \<Turnstile> v : ders s r \<Longrightarrow>
Some (flex r id s v) = decode (retrieve (bders (intern r) s) v) r" by fact
have asm: "\<Turnstile> v : ders (s @ [c]) r" by fact
then have asm2: "\<Turnstile> injval (ders s r) c v : ders s r"
by (simp add: Prf_injval ders_append)
have "Some (flex r id (s @ [c]) v) = Some (flex r id s (injval (ders s r) c v))"
by (simp add: flex_append)
also have "... = decode (retrieve (bders (intern r) s) (injval (ders s r) c v)) r"
using asm2 IH by simp
also have "... = decode (retrieve (bder c (bders (intern r) s)) v) r"
using asm by (simp_all add: bder_retrieve ders_append)
finally show "Some (flex r id (s @ [c]) v) =
decode (retrieve (bders (intern r) (s @ [c])) v) r" by (simp add: bders_append)
qed
definition blexer where
"blexer r s \<equiv> if bnullable (bders (intern r) s) then
decode (bmkeps (bders (intern r) s)) r else None"
lemma blexer_correctness:
shows "blexer r s = lexer r s"
proof -
{ define bds where "bds \<equiv> bders (intern r) s"
define ds where "ds \<equiv> ders s r"
assume asm: "nullable ds"
have era: "erase bds = ds"
unfolding ds_def bds_def by simp
have mke: "\<Turnstile> mkeps ds : ds"
using asm by (simp add: mkeps_nullable)
have "decode (bmkeps bds) r = decode (retrieve bds (mkeps ds)) r"
using bmkeps_retrieve
using asm era
using bnullable_correctness by force
also have "... = Some (flex r id s (mkeps ds))"
using mke by (simp_all add: MAIN_decode ds_def bds_def)
finally have "decode (bmkeps bds) r = Some (flex r id s (mkeps ds))"
unfolding bds_def ds_def .
}
then show "blexer r s = lexer r s"
unfolding blexer_def lexer_flex
by (auto simp add: bnullable_correctness[symmetric])
qed
fun distinctBy :: "'a list \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b set \<Rightarrow> 'a list"
where
"distinctBy [] f acc = []"
| "distinctBy (x#xs) f acc =
(if (f x) \<in> acc then distinctBy xs f acc
else x # (distinctBy xs f ({f x} \<union> acc)))"
fun flts :: "arexp list \<Rightarrow> arexp list"
where
"flts [] = []"
| "flts (AZERO # rs) = flts rs"
| "flts ((AALTs bs rs1) # rs) = (map (fuse bs) rs1) @ flts rs"
| "flts (r1 # rs) = r1 # flts rs"
fun bsimp_ASEQ :: "bit list \<Rightarrow> arexp \<Rightarrow> arexp \<Rightarrow> arexp"
where
"bsimp_ASEQ _ AZERO _ = AZERO"
| "bsimp_ASEQ _ _ AZERO = AZERO"
| "bsimp_ASEQ bs1 (AONE bs2) r2 = fuse (bs1 @ bs2) r2"
| "bsimp_ASEQ bs1 r1 r2 = ASEQ bs1 r1 r2"
lemma bsimp_ASEQ0[simp]:
shows "bsimp_ASEQ bs r1 AZERO = AZERO"
by (case_tac r1)(simp_all)
lemma bsimp_ASEQ1:
assumes "r1 \<noteq> AZERO" "r2 \<noteq> AZERO" "\<nexists>bs. r1 = AONE bs"
shows "bsimp_ASEQ bs r1 r2 = ASEQ bs r1 r2"
using assms
apply(induct bs r1 r2 rule: bsimp_ASEQ.induct)
apply(auto)
done
lemma bsimp_ASEQ2[simp]:
shows "bsimp_ASEQ bs1 (AONE bs2) r2 = fuse (bs1 @ bs2) r2"
by (case_tac r2) (simp_all)
fun bsimp_AALTs :: "bit list \<Rightarrow> arexp list \<Rightarrow> arexp"
where
"bsimp_AALTs _ [] = AZERO"
| "bsimp_AALTs bs1 [r] = fuse bs1 r"
| "bsimp_AALTs bs1 rs = AALTs bs1 rs"
fun bsimp :: "arexp \<Rightarrow> arexp"
where
"bsimp (ASEQ bs1 r1 r2) = bsimp_ASEQ bs1 (bsimp r1) (bsimp r2)"
| "bsimp (AALTs bs1 rs) = bsimp_AALTs bs1 (distinctBy (flts (map bsimp rs)) erase {}) "
| "bsimp r = r"
fun
bders_simp :: "arexp \<Rightarrow> string \<Rightarrow> arexp"
where
"bders_simp r [] = r"
| "bders_simp r (c # s) = bders_simp (bsimp (bder c r)) s"
definition blexer_simp where
"blexer_simp r s \<equiv> if bnullable (bders_simp (intern r) s) then
decode (bmkeps (bders_simp (intern r) s)) r else None"
lemma bders_simp_append:
shows "bders_simp r (s1 @ s2) = bders_simp (bders_simp r s1) s2"
apply(induct s1 arbitrary: r s2)
apply(simp_all)
done
lemma bmkeps_fuse:
assumes "bnullable r"
shows "bmkeps (fuse bs r) = bs @ bmkeps r"
using assms
by (metis bmkeps_retrieve bnullable_correctness erase_fuse mkeps_nullable retrieve_fuse2)
lemma bmkepss_fuse:
assumes "bnullables rs"
shows "bmkepss (map (fuse bs) rs) = bs @ bmkepss rs"
using assms
apply(induct rs arbitrary: bs)
apply(auto simp add: bmkeps_fuse bnullable_fuse)
done
lemma bder_fuse:
shows "bder c (fuse bs a) = fuse bs (bder c a)"
apply(induct a arbitrary: bs c)
apply(simp_all)
done
inductive
rrewrite:: "arexp \<Rightarrow> arexp \<Rightarrow> bool" ("_ \<leadsto> _" [99, 99] 99)
and
srewrite:: "arexp list \<Rightarrow> arexp list \<Rightarrow> bool" (" _ s\<leadsto> _" [100, 100] 100)
where
bs1: "ASEQ bs AZERO r2 \<leadsto> AZERO"
| bs2: "ASEQ bs r1 AZERO \<leadsto> AZERO"
| bs3: "ASEQ bs1 (AONE bs2) r \<leadsto> fuse (bs1@bs2) r"
| bs4: "r1 \<leadsto> r2 \<Longrightarrow> ASEQ bs r1 r3 \<leadsto> ASEQ bs r2 r3"
| bs5: "r3 \<leadsto> r4 \<Longrightarrow> ASEQ bs r1 r3 \<leadsto> ASEQ bs r1 r4"
| bs6: "AALTs bs [] \<leadsto> AZERO"
| bs7: "AALTs bs [r] \<leadsto> fuse bs r"
| bs8: "rs1 s\<leadsto> rs2 \<Longrightarrow> AALTs bs rs1 \<leadsto> AALTs bs rs2"
(*| ss1: "[] s\<leadsto> []"*)
| ss2: "rs1 s\<leadsto> rs2 \<Longrightarrow> (r # rs1) s\<leadsto> (r # rs2)"
| ss3: "r1 \<leadsto> r2 \<Longrightarrow> (r1 # rs) s\<leadsto> (r2 # rs)"
| ss4: "(AZERO # rs) s\<leadsto> rs"
| ss5: "(AALTs bs1 rs1 # rsb) s\<leadsto> ((map (fuse bs1) rs1) @ rsb)"
| ss6: "L(erase a2) \<subseteq> L(erase a1) \<Longrightarrow> (rsa@[a1]@rsb@[a2]@rsc) s\<leadsto> (rsa@[a1]@rsb@rsc)"
(*| extra: "bnullable r1 \<Longrightarrow> ASEQ bs0 (ASEQ bs1 r1 r2) r3 \<leadsto>
ASEQ (bs0 @ bs1) r1 (ASEQ [] r2 r3)"
*)
inductive
rrewrites:: "arexp \<Rightarrow> arexp \<Rightarrow> bool" ("_ \<leadsto>* _" [100, 100] 100)
where
rs1[intro, simp]:"r \<leadsto>* r"
| rs2[intro]: "\<lbrakk>r1 \<leadsto>* r2; r2 \<leadsto> r3\<rbrakk> \<Longrightarrow> r1 \<leadsto>* r3"
inductive
srewrites:: "arexp list \<Rightarrow> arexp list \<Rightarrow> bool" ("_ s\<leadsto>* _" [100, 100] 100)
where
sss1[intro, simp]:"rs s\<leadsto>* rs"
| sss2[intro]: "\<lbrakk>rs1 s\<leadsto> rs2; rs2 s\<leadsto>* rs3\<rbrakk> \<Longrightarrow> rs1 s\<leadsto>* rs3"
lemma r_in_rstar:
shows "r1 \<leadsto> r2 \<Longrightarrow> r1 \<leadsto>* r2"
using rrewrites.intros(1) rrewrites.intros(2) by blast
lemma rs_in_rstar:
shows "r1 s\<leadsto> r2 \<Longrightarrow> r1 s\<leadsto>* r2"
using rrewrites.intros(1) rrewrites.intros(2) by blast
lemma rrewrites_trans[trans]:
assumes a1: "r1 \<leadsto>* r2" and a2: "r2 \<leadsto>* r3"
shows "r1 \<leadsto>* r3"
using a2 a1
apply(induct r2 r3 arbitrary: r1 rule: rrewrites.induct)
apply(auto)
done
lemma srewrites_trans[trans]:
assumes a1: "r1 s\<leadsto>* r2" and a2: "r2 s\<leadsto>* r3"
shows "r1 s\<leadsto>* r3"
using a1 a2
apply(induct r1 r2 arbitrary: r3 rule: srewrites.induct)
apply(auto)
done
lemma contextrewrites0:
"rs1 s\<leadsto>* rs2 \<Longrightarrow> AALTs bs rs1 \<leadsto>* AALTs bs rs2"
apply(induct rs1 rs2 rule: srewrites.inducts)
apply simp
using bs8 r_in_rstar rrewrites_trans by blast
lemma contextrewrites1:
"r \<leadsto>* r' \<Longrightarrow> AALTs bs (r # rs) \<leadsto>* AALTs bs (r' # rs)"
apply(induct r r' rule: rrewrites.induct)
apply simp
using bs8 ss3 by blast
lemma srewrite1:
shows "rs1 s\<leadsto> rs2 \<Longrightarrow> (rs @ rs1) s\<leadsto> (rs @ rs2)"
apply(induct rs)
apply(auto)
using ss2 by auto
lemma srewrites1:
shows "rs1 s\<leadsto>* rs2 \<Longrightarrow> (rs @ rs1) s\<leadsto>* (rs @ rs2)"
apply(induct rs1 rs2 rule: srewrites.induct)
apply(auto)
using srewrite1 by blast
lemma srewrite2:
shows "r1 \<leadsto> r2 \<Longrightarrow> True"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> (rs1 @ rs) s\<leadsto>* (rs2 @ rs)"
apply(induct rule: rrewrite_srewrite.inducts)
apply(auto)
apply (metis append_Cons append_Nil srewrites1)
apply(meson srewrites.simps ss3)
apply (meson srewrites.simps ss4)
apply (meson srewrites.simps ss5)
by (metis append_Cons append_Nil srewrites.simps ss6)
lemma srewrites3:
shows "rs1 s\<leadsto>* rs2 \<Longrightarrow> (rs1 @ rs) s\<leadsto>* (rs2 @ rs)"
apply(induct rs1 rs2 arbitrary: rs rule: srewrites.induct)
apply(auto)
by (meson srewrite2(2) srewrites_trans)
(*
lemma srewrites4:
assumes "rs3 s\<leadsto>* rs4" "rs1 s\<leadsto>* rs2"
shows "(rs1 @ rs3) s\<leadsto>* (rs2 @ rs4)"
using assms
apply(induct rs3 rs4 arbitrary: rs1 rs2 rule: srewrites.induct)
apply (simp add: srewrites3)
using srewrite1 by blast
*)
lemma srewrites6:
assumes "r1 \<leadsto>* r2"
shows "[r1] s\<leadsto>* [r2]"
using assms
apply(induct r1 r2 rule: rrewrites.induct)
apply(auto)
by (meson srewrites.simps srewrites_trans ss3)
lemma srewrites7:
assumes "rs3 s\<leadsto>* rs4" "r1 \<leadsto>* r2"
shows "(r1 # rs3) s\<leadsto>* (r2 # rs4)"
using assms
by (smt (verit, del_insts) append.simps srewrites1 srewrites3 srewrites6 srewrites_trans)
lemma ss6_stronger_aux:
shows "(rs1 @ rs2) s\<leadsto>* (rs1 @ distinctBy rs2 erase (set (map erase rs1)))"
apply(induct rs2 arbitrary: rs1)
apply(auto)
prefer 2
apply(drule_tac x="rs1 @ [a]" in meta_spec)
apply(simp)
apply(drule_tac x="rs1" in meta_spec)
apply(subgoal_tac "(rs1 @ a # rs2) s\<leadsto>* (rs1 @ rs2)")
using srewrites_trans apply blast
apply(subgoal_tac "\<exists>rs1a rs1b. rs1 = rs1a @ [x] @ rs1b")
prefer 2
apply (simp add: split_list)
apply(erule exE)+
apply(simp)
using ss6[simplified]
using rs_in_rstar by force
lemma ss6_stronger:
shows "rs1 s\<leadsto>* distinctBy rs1 erase {}"
using ss6_stronger_aux[of "[]" _] by auto
lemma rewrite_preserves_fuse:
shows "r2 \<leadsto> r3 \<Longrightarrow> fuse bs r2 \<leadsto> fuse bs r3"
and "rs2 s\<leadsto> rs3 \<Longrightarrow> map (fuse bs) rs2 s\<leadsto> map (fuse bs) rs3"
proof(induct rule: rrewrite_srewrite.inducts)
case (bs3 bs1 bs2 r)
then show "fuse bs (ASEQ bs1 (AONE bs2) r) \<leadsto> fuse bs (fuse (bs1 @ bs2) r)"
by (metis fuse.simps(5) fuse_append rrewrite_srewrite.bs3)
next
case (bs7 bs1 r)
then show "fuse bs (AALTs bs1 [r]) \<leadsto> fuse bs (fuse bs1 r)"
by (metis fuse.simps(4) fuse_append rrewrite_srewrite.bs7)
next
case (ss2 rs1 rs2 r)
then show "map (fuse bs) (r # rs1) s\<leadsto> map (fuse bs) (r # rs2)"
by (simp add: rrewrite_srewrite.ss2)
next
case (ss3 r1 r2 rs)
then show "map (fuse bs) (r1 # rs) s\<leadsto> map (fuse bs) (r2 # rs)"
by (simp add: rrewrite_srewrite.ss3)
next
case (ss5 bs1 rs1 rsb)
have "map (fuse bs) (AALTs bs1 rs1 # rsb) = AALTs (bs @ bs1) rs1 # (map (fuse bs) rsb)" by simp
also have "... s\<leadsto> ((map (fuse (bs @ bs1)) rs1) @ (map (fuse bs) rsb))"
by (simp add: rrewrite_srewrite.ss5)
finally show "map (fuse bs) (AALTs bs1 rs1 # rsb) s\<leadsto> map (fuse bs) (map (fuse bs1) rs1 @ rsb)"
by (simp add: comp_def fuse_append)
next
case (ss6 a2 a1 rsa rsb rsc)
have "L (erase a2) \<subseteq> L (erase a1)" by fact
then show "map (fuse bs) (rsa @ [a1] @ rsb @ [a2] @ rsc) s\<leadsto> map (fuse bs) (rsa @ [a1] @ rsb @ rsc)"
apply(simp)
apply(rule rrewrite_srewrite.ss6[simplified])
apply(simp add: erase_fuse)
done
(*next
case (extra bs0 bs1 r1 r2 r3)
then show ?case
by (metis append_assoc fuse.simps(5) rrewrite_srewrite.extra)*)
qed (auto intro: rrewrite_srewrite.intros)
lemma rewrites_fuse:
assumes "r1 \<leadsto>* r2"
shows "fuse bs r1 \<leadsto>* fuse bs r2"
using assms
apply(induction r1 r2 arbitrary: bs rule: rrewrites.induct)
apply(auto intro: rewrite_preserves_fuse)
done
lemma star_seq:
assumes "r1 \<leadsto>* r2"
shows "ASEQ bs r1 r3 \<leadsto>* ASEQ bs r2 r3"
using assms
apply(induct r1 r2 arbitrary: r3 rule: rrewrites.induct)
apply(auto intro: rrewrite_srewrite.intros)
done
lemma star_seq2:
assumes "r3 \<leadsto>* r4"
shows "ASEQ bs r1 r3 \<leadsto>* ASEQ bs r1 r4"
using assms
apply(induct r3 r4 arbitrary: r1 rule: rrewrites.induct)
apply(auto intro: rrewrite_srewrite.intros)
done
lemma continuous_rewrite:
assumes "r1 \<leadsto>* AZERO"
shows "ASEQ bs1 r1 r2 \<leadsto>* AZERO"
using assms bs1 star_seq by blast
(*
lemma continuous_rewrite2:
assumes "r1 \<leadsto>* AONE bs"
shows "ASEQ bs1 r1 r2 \<leadsto>* (fuse (bs1 @ bs) r2)"
using assms by (meson bs3 rrewrites.simps star_seq)
*)
lemma bsimp_aalts_simpcases:
shows "AONE bs \<leadsto>* bsimp (AONE bs)"
and "AZERO \<leadsto>* bsimp AZERO"
and "ACHAR bs c \<leadsto>* bsimp (ACHAR bs c)"
by (simp_all)
lemma bsimp_AALTs_rewrites:
shows "AALTs bs1 rs \<leadsto>* bsimp_AALTs bs1 rs"
by (smt (verit) bs6 bs7 bsimp_AALTs.elims rrewrites.simps)
lemma trivialbsimp_srewrites:
assumes "\<And>x. x \<in> set rs \<Longrightarrow> x \<leadsto>* f x"
shows "rs s\<leadsto>* (map f rs)"
using assms
apply(induction rs)
apply(simp_all add: srewrites7)
done
lemma fltsfrewrites: "rs s\<leadsto>* flts rs"
apply(induction rs rule: flts.induct)
apply(auto intro: rrewrite_srewrite.intros)
apply (meson srewrites.simps srewrites1 ss5)
using rs1 srewrites7 apply presburger
using srewrites7 apply force
apply (simp add: srewrites7)
by (simp add: srewrites7)
lemma bnullable0:
shows "r1 \<leadsto> r2 \<Longrightarrow> bnullable r1 = bnullable r2"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> bnullables rs1 = bnullables rs2"
apply(induct rule: rrewrite_srewrite.inducts)
apply(auto simp add: bnullable_fuse)
apply (meson UnCI bnullable_fuse imageI)
using bnullable_correctness nullable_correctness by blast
lemma rewrites_bnullable_eq:
assumes "r1 \<leadsto>* r2"
shows "bnullable r1 = bnullable r2"
using assms
apply(induction r1 r2 rule: rrewrites.induct)
apply simp
using bnullable0(1) by auto
lemma rewrite_bmkeps_aux:
shows "r1 \<leadsto> r2 \<Longrightarrow> bnullable r1 \<Longrightarrow> bmkeps r1 = bmkeps r2"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> bnullables rs1 \<Longrightarrow> bmkepss rs1 = bmkepss rs2"
proof (induct rule: rrewrite_srewrite.inducts)
case (bs3 bs1 bs2 r)
have IH2: "bnullable (ASEQ bs1 (AONE bs2) r)" by fact
then show "bmkeps (ASEQ bs1 (AONE bs2) r) = bmkeps (fuse (bs1 @ bs2) r)"
by (simp add: bmkeps_fuse)
next
case (bs7 bs r)
have IH2: "bnullable (AALTs bs [r])" by fact
then show "bmkeps (AALTs bs [r]) = bmkeps (fuse bs r)"
by (simp add: bmkeps_fuse)
next
case (ss3 r1 r2 rs)
have IH1: "bnullable r1 \<Longrightarrow> bmkeps r1 = bmkeps r2" by fact
have as: "r1 \<leadsto> r2" by fact
from IH1 as show "bmkepss (r1 # rs) = bmkepss (r2 # rs)"
by (simp add: bnullable0)
next
case (ss5 bs1 rs1 rsb)
have "bnullables (AALTs bs1 rs1 # rsb)" by fact
then show "bmkepss (AALTs bs1 rs1 # rsb) = bmkepss (map (fuse bs1) rs1 @ rsb)"
by (simp add: bmkepss1 bmkepss2 bmkepss_fuse bnullable_fuse)
next
case (ss6 a2 a1 rsa rsb rsc)
have as1: "L(erase a2) \<subseteq> L(erase a1)" by fact
have as3: "bnullables (rsa @ [a1] @ rsb @ [a2] @ rsc)" by fact
show "bmkepss (rsa @ [a1] @ rsb @ [a2] @ rsc) = bmkepss (rsa @ [a1] @ rsb @ rsc)" using as1 as3
by (smt (verit, ccfv_SIG) append_Cons bmkepss.simps(1) bmkepss1 bmkepss2 bnullable_correctness nullable_correctness subset_eq)
(*next
case (extra bs0 bs1 r1 bs2 r2 bs4 bs3)
then show ?case
apply(subst bmkeps.simps)
apply(subst bmkeps.simps)
apply(subst bmkeps.simps)
apply(subst bmkeps.simps)
apply(subst bmkeps.simps)
apply(subst bmkeps.simps)
apply(simp)
done*)
qed (auto)
lemma rewrites_bmkeps:
assumes "r1 \<leadsto>* r2" "bnullable r1"
shows "bmkeps r1 = bmkeps r2"
using assms
proof(induction r1 r2 rule: rrewrites.induct)
case (rs1 r)
then show "bmkeps r = bmkeps r" by simp
next
case (rs2 r1 r2 r3)
then have IH: "bmkeps r1 = bmkeps r2" by simp
have a1: "bnullable r1" by fact
have a2: "r1 \<leadsto>* r2" by fact
have a3: "r2 \<leadsto> r3" by fact
have a4: "bnullable r2" using a1 a2 by (simp add: rewrites_bnullable_eq)
then have "bmkeps r2 = bmkeps r3"
using a3 bnullable0(1) rewrite_bmkeps_aux(1) by blast
then show "bmkeps r1 = bmkeps r3" using IH by simp
qed
lemma rewrites_to_bsimp:
shows "r \<leadsto>* bsimp r"
proof (induction r rule: bsimp.induct)
case (1 bs1 r1 r2)
have IH1: "r1 \<leadsto>* bsimp r1" by fact
have IH2: "r2 \<leadsto>* bsimp r2" by fact
{ assume as: "bsimp r1 = AZERO \<or> bsimp r2 = AZERO"
with IH1 IH2 have "r1 \<leadsto>* AZERO \<or> r2 \<leadsto>* AZERO" by auto
then have "ASEQ bs1 r1 r2 \<leadsto>* AZERO"
by (metis bs2 continuous_rewrite rrewrites.simps star_seq2)
then have "ASEQ bs1 r1 r2 \<leadsto>* bsimp (ASEQ bs1 r1 r2)" using as by auto
}
moreover
{ assume "\<exists>bs. bsimp r1 = AONE bs"
then obtain bs where as: "bsimp r1 = AONE bs" by blast
with IH1 have "r1 \<leadsto>* AONE bs" by simp
then have "ASEQ bs1 r1 r2 \<leadsto>* fuse (bs1 @ bs) r2" using bs3 star_seq by blast
with IH2 have "ASEQ bs1 r1 r2 \<leadsto>* fuse (bs1 @ bs) (bsimp r2)"
using rewrites_fuse by (meson rrewrites_trans)
then have "ASEQ bs1 r1 r2 \<leadsto>* bsimp (ASEQ bs1 (AONE bs) r2)" by simp
then have "ASEQ bs1 r1 r2 \<leadsto>* bsimp (ASEQ bs1 r1 r2)" by (simp add: as)
}
moreover
{ assume as1: "bsimp r1 \<noteq> AZERO" "bsimp r2 \<noteq> AZERO" and as2: "(\<nexists>bs. bsimp r1 = AONE bs)"
then have "bsimp_ASEQ bs1 (bsimp r1) (bsimp r2) = ASEQ bs1 (bsimp r1) (bsimp r2)"
by (simp add: bsimp_ASEQ1)
then have "ASEQ bs1 r1 r2 \<leadsto>* bsimp_ASEQ bs1 (bsimp r1) (bsimp r2)" using as1 as2 IH1 IH2
by (metis rrewrites_trans star_seq star_seq2)
then have "ASEQ bs1 r1 r2 \<leadsto>* bsimp (ASEQ bs1 r1 r2)" by simp
}
ultimately show "ASEQ bs1 r1 r2 \<leadsto>* bsimp (ASEQ bs1 r1 r2)" by blast
next
case (2 bs1 rs)
have IH: "\<And>x. x \<in> set rs \<Longrightarrow> x \<leadsto>* bsimp x" by fact
then have "rs s\<leadsto>* (map bsimp rs)" by (simp add: trivialbsimp_srewrites)
also have "... s\<leadsto>* flts (map bsimp rs)" by (simp add: fltsfrewrites)
also have "... s\<leadsto>* distinctBy (flts (map bsimp rs)) erase {}" by (simp add: ss6_stronger)
finally have "AALTs bs1 rs \<leadsto>* AALTs bs1 (distinctBy (flts (map bsimp rs)) erase {})"
using contextrewrites0 by blast
also have "... \<leadsto>* bsimp_AALTs bs1 (distinctBy (flts (map bsimp rs)) erase {})"
by (simp add: bsimp_AALTs_rewrites)
finally show "AALTs bs1 rs \<leadsto>* bsimp (AALTs bs1 rs)" by simp
qed (simp_all)
lemma to_zero_in_alt:
shows "AALT bs (ASEQ [] AZERO r) r2 \<leadsto> AALT bs AZERO r2"
by (simp add: bs1 bs8 ss3)
lemma bder_fuse_list:
shows "map (bder c \<circ> fuse bs1) rs1 = map (fuse bs1 \<circ> bder c) rs1"
apply(induction rs1)
apply(simp_all add: bder_fuse)
done
lemma map_single:
shows "map f [x] = [f x]"
by simp
lemma rewrite_preserves_bder:
shows "r1 \<leadsto> r2 \<Longrightarrow> bder c r1 \<leadsto>* bder c r2"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> map (bder c) rs1 s\<leadsto>* map (bder c) rs2"
proof(induction rule: rrewrite_srewrite.inducts)
case (bs1 bs r2)
show "bder c (ASEQ bs AZERO r2) \<leadsto>* bder c AZERO"
by (simp add: continuous_rewrite)
next
case (bs2 bs r1)
show "bder c (ASEQ bs r1 AZERO) \<leadsto>* bder c AZERO"
apply(auto)
apply (meson bs6 contextrewrites0 rrewrite_srewrite.bs2 rs2 ss3 ss4 sss1 sss2)
by (simp add: r_in_rstar rrewrite_srewrite.bs2)
next
case (bs3 bs1 bs2 r)
show "bder c (ASEQ bs1 (AONE bs2) r) \<leadsto>* bder c (fuse (bs1 @ bs2) r)"
apply(simp)
by (metis (no_types, lifting) bder_fuse bs8 bs7 fuse_append rrewrites.simps ss4 to_zero_in_alt)
next
case (bs4 r1 r2 bs r3)
have as: "r1 \<leadsto> r2" by fact
have IH: "bder c r1 \<leadsto>* bder c r2" by fact
from as IH show "bder c (ASEQ bs r1 r3) \<leadsto>* bder c (ASEQ bs r2 r3)"
by (metis bder.simps(5) bnullable0(1) contextrewrites1 rewrite_bmkeps_aux(1) star_seq)
next
case (bs5 r3 r4 bs r1)
have as: "r3 \<leadsto> r4" by fact
have IH: "bder c r3 \<leadsto>* bder c r4" by fact
from as IH show "bder c (ASEQ bs r1 r3) \<leadsto>* bder c (ASEQ bs r1 r4)"
apply(simp)
apply(auto)
using contextrewrites0 r_in_rstar rewrites_fuse srewrites6 srewrites7 star_seq2 apply presburger
using star_seq2 by blast
next
case (bs6 bs)
show "bder c (AALTs bs []) \<leadsto>* bder c AZERO"
using rrewrite_srewrite.bs6 by force
next
case (bs7 bs r)
show "bder c (AALTs bs [r]) \<leadsto>* bder c (fuse bs r)"
by (simp add: bder_fuse r_in_rstar rrewrite_srewrite.bs7)
next
case (bs8 rs1 rs2 bs)
have IH1: "map (bder c) rs1 s\<leadsto>* map (bder c) rs2" by fact
then show "bder c (AALTs bs rs1) \<leadsto>* bder c (AALTs bs rs2)"
using contextrewrites0 by force
(*next
case ss1
show "map (bder c) [] s\<leadsto>* map (bder c) []" by simp*)
next
case (ss2 rs1 rs2 r)
have IH1: "map (bder c) rs1 s\<leadsto>* map (bder c) rs2" by fact
then show "map (bder c) (r # rs1) s\<leadsto>* map (bder c) (r # rs2)"
by (simp add: srewrites7)
next
case (ss3 r1 r2 rs)
have IH: "bder c r1 \<leadsto>* bder c r2" by fact
then show "map (bder c) (r1 # rs) s\<leadsto>* map (bder c) (r2 # rs)"
by (simp add: srewrites7)
next
case (ss4 rs)
show "map (bder c) (AZERO # rs) s\<leadsto>* map (bder c) rs"
using rrewrite_srewrite.ss4 by fastforce
next
case (ss5 bs1 rs1 rsb)
show "map (bder c) (AALTs bs1 rs1 # rsb) s\<leadsto>* map (bder c) (map (fuse bs1) rs1 @ rsb)"
apply(simp)
using bder_fuse_list map_map rrewrite_srewrite.ss5 srewrites.simps by blast
next
case (ss6 a2 a1 bs rsa rsb)
have as: "L(erase a2) \<subseteq> L(erase a1)" by fact
show "map (bder c) (bs @ [a1] @ rsa @ [a2] @ rsb) s\<leadsto>* map (bder c) (bs @ [a1] @ rsa @ rsb)"
apply(simp only: map_append)
apply(simp only: map_single)
apply(rule rs_in_rstar)
thm rrewrite_srewrite.intros
apply(rule rrewrite_srewrite.ss6)
using as
apply(auto simp add: der_correctness Der_def)
done
(*next
case (extra bs0 bs1 r1 r2 r3)
then show ?case
apply(auto simp add: comp_def)
defer
using r_in_rstar rrewrite_srewrite.extra apply presburger
prefer 2
using r_in_rstar rrewrite_srewrite.extra apply presburger
prefer 2
sorry*)
qed
lemma rewrites_preserves_bder:
assumes "r1 \<leadsto>* r2"
shows "bder c r1 \<leadsto>* bder c r2"
using assms
apply(induction r1 r2 rule: rrewrites.induct)
apply(simp_all add: rewrite_preserves_bder rrewrites_trans)
done
lemma central:
shows "bders r s \<leadsto>* bders_simp r s"
proof(induct s arbitrary: r rule: rev_induct)
case Nil
then show "bders r [] \<leadsto>* bders_simp r []" by simp
next
case (snoc x xs)
have IH: "\<And>r. bders r xs \<leadsto>* bders_simp r xs" by fact
have "bders r (xs @ [x]) = bders (bders r xs) [x]" by (simp add: bders_append)
also have "... \<leadsto>* bders (bders_simp r xs) [x]" using IH
by (simp add: rewrites_preserves_bder)
also have "... \<leadsto>* bders_simp (bders_simp r xs) [x]" using IH
by (simp add: rewrites_to_bsimp)
finally show "bders r (xs @ [x]) \<leadsto>* bders_simp r (xs @ [x])"
by (simp add: bders_simp_append)
qed
lemma main_aux:
assumes "bnullable (bders r s)"
shows "bmkeps (bders r s) = bmkeps (bders_simp r s)"
proof -
have "bders r s \<leadsto>* bders_simp r s" by (rule central)
then
show "bmkeps (bders r s) = bmkeps (bders_simp r s)" using assms
by (rule rewrites_bmkeps)
qed
theorem main_blexer_simp:
shows "blexer r s = blexer_simp r s"
unfolding blexer_def blexer_simp_def
by (metis central main_aux rewrites_bnullable_eq)
theorem blexersimp_correctness:
shows "lexer r s = blexer_simp r s"
using blexer_correctness main_blexer_simp by simp
(* some tests *)
definition
bders_simp_Set :: "string set \<Rightarrow> arexp \<Rightarrow> arexp set"
where
"bders_simp_Set A r \<equiv> bders_simp r ` A"
lemma pders_Set_union:
shows "bders_simp_Set (A \<union> B) r = (bders_simp_Set A r \<union> bders_simp_Set B r)"
apply (simp add: bders_simp_Set_def)
by (simp add: image_Un)
lemma pders_Set_subset:
shows "A \<subseteq> B \<Longrightarrow> bders_simp_Set A r \<subseteq> bders_simp_Set B r"
apply (auto simp add: bders_simp_Set_def)
done
lemma AZERO_r:
"bders_simp AZERO s = AZERO"
apply(induct s)
apply(auto)
done
lemma bders_simp_Set_ZERO [simp]:
shows "bders_simp_Set UNIV1 AZERO \<subseteq> {AZERO}"
unfolding UNIV1_def bders_simp_Set_def
apply(auto)
using AZERO_r by blast
lemma AONE_r:
shows "bders_simp (AONE bs) s = AZERO \<or> bders_simp (AONE bs) s = AONE bs"
apply(induct s)
apply(auto)
using AZERO_r apply blast
using AZERO_r by blast
lemma bders_simp_Set_ONE [simp]:
shows "bders_simp_Set UNIV1 (AONE bs) \<subseteq> {AZERO, AONE bs}"
unfolding UNIV1_def bders_simp_Set_def
apply(auto split: if_splits)
using AONE_r by blast
lemma ACHAR_r:
shows "bders_simp (ACHAR bs c) s = AZERO \<or>
bders_simp (ACHAR bs c) s = AONE bs \<or>
bders_simp (ACHAR bs c) s = ACHAR bs c"
apply(induct s)
apply(auto)
using AONE_r apply blast
using AZERO_r apply force
using AONE_r apply blast
using AZERO_r apply blast
using AONE_r apply blast
using AZERO_r by blast
lemma bders_simp_Set_CHAR [simp]:
shows "bders_simp_Set UNIV1 (ACHAR bs c) \<subseteq> {AZERO, AONE bs, ACHAR bs c}"
unfolding UNIV1_def bders_simp_Set_def
apply(auto)
using ACHAR_r by blast
lemma bders_simp_Set_ALT [simp]:
shows "bders_simp_Set UNIV1 (AALT bs r1 r2) = bders_simp_Set UNIV1 r1 \<union> bders_simp_Set UNIV1 r2"
unfolding UNIV1_def bders_simp_Set_def
apply(auto)
oops
(*
lemma asize_fuse:
shows "asize (fuse bs r) = asize r"
apply(induct r arbitrary: bs)
apply(auto)
done
lemma asize_rewrite2:
shows "r1 \<leadsto> r2 \<Longrightarrow> asize r1 \<ge> asize r2"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> (sum_list (map asize rs1)) \<ge> (sum_list (map asize rs2))"
apply(induct rule: rrewrite_srewrite.inducts)
apply(auto simp add: asize_fuse comp_def)
done
lemma asize_rrewrites:
assumes "r1 \<leadsto>* r2"
shows "asize r1 \<ge> asize r2"
using assms
apply(induct rule: rrewrites.induct)
apply(auto)
using asize_rewrite2(1) le_trans by blast
fun asize2 :: "arexp \<Rightarrow> nat" where
"asize2 AZERO = 1"
| "asize2 (AONE cs) = 1"
| "asize2 (ACHAR cs c) = 1"
| "asize2 (AALTs cs rs) = Suc (Suc (sum_list (map asize2 rs)))"
| "asize2 (ASEQ cs r1 r2) = Suc (asize2 r1 + asize2 r2)"
| "asize2 (ASTAR cs r) = Suc (asize2 r)"
lemma asize2_fuse:
shows "asize2 (fuse bs r) = asize2 r"
apply(induct r arbitrary: bs)
apply(auto)
done
lemma asize2_not_zero:
shows "0 < asize2 r"
apply(induct r)
apply(auto)
done
lemma asize_rewrite:
shows "r1 \<leadsto> r2 \<Longrightarrow> asize2 r1 > asize2 r2"
and "rs1 s\<leadsto> rs2 \<Longrightarrow> (sum_list (map asize2 rs1)) > (sum_list (map asize2 rs2))"
apply(induct rule: rrewrite_srewrite.inducts)
apply(auto simp add: asize2_fuse comp_def)
apply(simp add: asize2_not_zero)
done
lemma asize2_bsimp_ASEQ:
shows "asize2 (bsimp_ASEQ bs r1 r2) \<le> Suc (asize2 r1 + asize2 r2)"
apply(induct bs r1 r2 rule: bsimp_ASEQ.induct)
apply(auto)
done
lemma asize2_bsimp_AALTs:
shows "asize2 (bsimp_AALTs bs rs) \<le> Suc (Suc (sum_list (map asize2 rs)))"
apply(induct bs rs rule: bsimp_AALTs.induct)
apply(auto simp add: asize2_fuse)
done
lemma distinctBy_asize2:
shows "sum_list (map asize2 (distinctBy rs f acc)) \<le> sum_list (map asize2 rs)"
apply(induct rs f acc rule: distinctBy.induct)
apply(auto)
done
lemma flts_asize2:
shows "sum_list (map asize2 (flts rs)) \<le> sum_list (map asize2 rs)"
apply(induct rs rule: flts.induct)
apply(auto simp add: comp_def asize2_fuse)
done
lemma sumlist_asize2:
assumes "\<And>x. x \<in> set rs \<Longrightarrow> asize2 (f x) \<le> asize2 x"
shows "sum_list (map asize2 (map f rs)) \<le> sum_list (map asize2 rs)"
using assms
apply(induct rs)
apply(auto simp add: comp_def)
by (simp add: add_le_mono)
lemma test0:
assumes "r1 \<leadsto>* r2"
shows "r1 = r2 \<or> (\<exists>r3. r1 \<leadsto> r3 \<and> r3 \<leadsto>* r2)"
using assms
apply(induct r1 r2 rule: rrewrites.induct)
apply(auto)
done
lemma test2:
assumes "r1 \<leadsto>* r2"
shows "asize2 r1 \<ge> asize2 r2"
using assms
apply(induct r1 r2 rule: rrewrites.induct)
apply(auto)
using asize_rewrite(1) by fastforce
lemma test3:
shows "r = bsimp r \<or> (asize2 (bsimp r) < asize2 r)"
proof -
have "r \<leadsto>* bsimp r"
by (simp add: rewrites_to_bsimp)
then have "r = bsimp r \<or> (\<exists>r3. r \<leadsto> r3 \<and> r3 \<leadsto>* bsimp r)"
using test0 by blast
then show ?thesis
by (meson asize_rewrite(1) dual_order.strict_trans2 test2)
qed
lemma test3Q:
shows "r = bsimp r \<or> (asize (bsimp r) \<le> asize r)"
proof -
have "r \<leadsto>* bsimp r"
by (simp add: rewrites_to_bsimp)
then have "r = bsimp r \<or> (\<exists>r3. r \<leadsto> r3 \<and> r3 \<leadsto>* bsimp r)"
using test0 by blast
then show ?thesis
using asize_rewrite2(1) asize_rrewrites le_trans by blast
qed
lemma test4:
shows "asize2 (bsimp (bsimp r)) \<le> asize2 (bsimp r)"
apply(induct r rule: bsimp.induct)
apply(auto)
using rewrites_to_bsimp test2 apply fastforce
using rewrites_to_bsimp test2 by presburger
lemma test4Q:
shows "asize (bsimp (bsimp r)) \<le> asize (bsimp r)"
apply(induct r rule: bsimp.induct)
apply(auto)
apply (metis order_refl test3Q)
by (metis le_refl test3Q)
lemma testb0:
shows "fuse bs1 (bsimp_ASEQ bs r1 r2) = bsimp_ASEQ (bs1 @ bs) r1 r2"
apply(induct bs r1 r2 arbitrary: bs1 rule: bsimp_ASEQ.induct)
apply(auto)
done
lemma testb1:
shows "fuse bs1 (bsimp_AALTs bs rs) = bsimp_AALTs (bs1 @ bs) rs"
apply(induct bs rs arbitrary: bs1 rule: bsimp_AALTs.induct)
apply(auto simp add: fuse_append)
done
lemma testb2:
shows "bsimp (bsimp_ASEQ bs r1 r2) = bsimp_ASEQ bs (bsimp r1) (bsimp r2)"
apply(induct bs r1 r2 rule: bsimp_ASEQ.induct)
apply(auto simp add: testb0 testb1)
done
lemma testb3:
shows "\<nexists>r'. (bsimp r \<leadsto> r') \<and> asize2 (bsimp r) > asize2 r'"
apply(induct r rule: bsimp.induct)
apply(auto)
defer
defer
using rrewrite.cases apply blast
using rrewrite.cases apply blast
using rrewrite.cases apply blast
using rrewrite.cases apply blast
oops
lemma testb4:
assumes "sum_list (map asize rs1) \<le> sum_list (map asize rs2)"
shows "asize (bsimp_AALTs bs1 rs1) \<le> Suc (asize (bsimp_AALTs bs1 rs2))"
using assms
apply(induct bs1 rs2 arbitrary: rs1 rule: bsimp_AALTs.induct)
apply(auto)
apply(case_tac rs1)
apply(auto)
using asize2.elims apply auto[1]
apply (metis One_nat_def Zero_not_Suc asize.elims)
apply(case_tac rs1)
apply(auto)
apply(case_tac list)
apply(auto)
using asize_fuse apply force
apply (simp add: asize_fuse)
by (smt (verit, ccfv_threshold) One_nat_def add.right_neutral asize.simps(1) asize.simps(4) asize_fuse bsimp_AALTs.elims le_Suc_eq list.map(1) list.map(2) not_less_eq_eq sum_list_simps(1) sum_list_simps(2))
lemma flts_asize:
shows "sum_list (map asize (flts rs)) \<le> sum_list (map asize rs)"
apply(induct rs rule: flts.induct)
apply(auto simp add: comp_def asize_fuse)
done
lemma test5:
shows "asize2 r \<ge> asize2 (bsimp r)"
apply(induct r rule: bsimp.induct)
apply(auto)
apply (meson Suc_le_mono add_le_mono asize2_bsimp_ASEQ order_trans)
apply(rule order_trans)
apply(rule asize2_bsimp_AALTs)
apply(simp)
apply(rule order_trans)
apply(rule distinctBy_asize2)
apply(rule order_trans)
apply(rule flts_asize2)
using sumlist_asize2 by force
fun awidth :: "arexp \<Rightarrow> nat" where
"awidth AZERO = 1"
| "awidth (AONE cs) = 1"
| "awidth (ACHAR cs c) = 1"
| "awidth (AALTs cs rs) = (sum_list (map awidth rs))"
| "awidth (ASEQ cs r1 r2) = (awidth r1 + awidth r2)"
| "awidth (ASTAR cs r) = (awidth r)"
lemma
shows "s \<notin> L r \<Longrightarrow> blexer_simp r s = None"
by (simp add: blexersimp_correctness lexer_correct_None)
lemma g1:
"bders_simp AZERO s = AZERO"
apply(induct s)
apply(simp)
apply(simp)
done
lemma g2:
"s \<noteq> Nil \<Longrightarrow> bders_simp (AONE bs) s = AZERO"
apply(induct s)
apply(simp)
apply(simp)
apply(case_tac s)
apply(simp)
apply(simp)
done
lemma finite_pder:
shows "finite (pder c r)"
apply(induct c r rule: pder.induct)
apply(auto)
done
lemma awidth_fuse:
shows "awidth (fuse bs r) = awidth r"
apply(induct r arbitrary: bs)
apply(auto)
done
lemma pders_SEQs:
assumes "finite A"
shows "card (SEQs A (STAR r)) \<le> card A"
using assms
by (simp add: SEQs_eq_image card_image_le)
lemma binullable_intern:
shows "bnullable (intern r) = nullable r"
apply(induct r)
apply(auto simp add: bnullable_fuse)
done
lemma
"card (pder c r) \<le> awidth (bder c (intern r))"
apply(induct c r rule: pder.induct)
apply(simp)
apply(simp)
apply(simp)
apply(simp)
apply(rule order_trans)
apply(rule card_Un_le)
apply (simp add: awidth_fuse bder_fuse)
defer
apply(simp)
apply(rule order_trans)
apply(rule pders_SEQs)
using finite_pder apply presburger
apply (simp add: awidth_fuse)
apply(auto)
apply(rule order_trans)
apply(rule card_Un_le)
apply(simp add: awidth_fuse)
defer
using binullable_intern apply blast
using binullable_intern apply blast
apply (smt (verit, best) SEQs_eq_image add.commute add_Suc_right card_image_le dual_order.trans finite_pder trans_le_add2)
apply(subgoal_tac "card (SEQs (pder c r1) r2) \<le> card (pder c r1)")
apply(linarith)
by (simp add: UNION_singleton_eq_range card_image_le finite_pder)
lemma
"card (pder c r) \<le> asize (bder c (intern r))"
apply(induct c r rule: pder.induct)
apply(simp)
apply(simp)
apply(simp)
apply(simp)
apply (metis add_mono_thms_linordered_semiring(1) asize_fuse bder_fuse card_Un_le le_Suc_eq order_trans)
defer
apply(simp)
apply(rule order_trans)
apply(rule pders_SEQs)
using finite_pder apply presburger
apply (simp add: asize_fuse)
apply(simp)
apply(auto)
apply(rule order_trans)
apply(rule card_Un_le)
apply (smt (z3) SEQs_eq_image add.commute add_Suc_right add_mono_thms_linordered_semiring(1) asize_fuse card_image_le dual_order.trans finite_pder le_add1)
apply(rule order_trans)
apply(rule card_Un_le)
using binullable_intern apply blast
using binullable_intern apply blast
by (smt (verit, best) SEQs_eq_image add.commute add_Suc_right card_image_le dual_order.trans finite_pder trans_le_add2)
lemma
"card (pder c r) \<le> asize (bsimp (bder c (intern r)))"
apply(induct c r rule: pder.induct)
apply(simp)
apply(simp)
apply(simp)
apply(simp)
apply(rule order_trans)
apply(rule card_Un_le)
prefer 3
apply(simp)
apply(rule order_trans)
apply(rule pders_SEQs)
using finite_pder apply blast
oops
*)
(* below is the idempotency of bsimp *)
(*
lemma bsimp_ASEQ_fuse:
shows "fuse bs1 (bsimp_ASEQ bs2 r1 r2) = bsimp_ASEQ (bs1 @ bs2) r1 r2"
apply(induct r1 r2 arbitrary: bs1 bs2 rule: bsimp_ASEQ.induct)
apply(auto)
done
lemma bsimp_AALTs_fuse:
assumes "\<forall>r \<in> set rs. fuse bs1 (fuse bs2 r) = fuse (bs1 @ bs2) r"
shows "fuse bs1 (bsimp_AALTs bs2 rs) = bsimp_AALTs (bs1 @ bs2) rs"
using assms
apply(induct bs2 rs arbitrary: bs1 rule: bsimp_AALTs.induct)
apply(auto)
done
lemma bsimp_fuse:
shows "fuse bs (bsimp r) = bsimp (fuse bs r)"
apply(induct r arbitrary: bs)
apply(simp_all add: bsimp_ASEQ_fuse bsimp_AALTs_fuse fuse_append)
done
lemma bsimp_ASEQ_idem:
assumes "bsimp (bsimp r1) = bsimp r1" "bsimp (bsimp r2) = bsimp r2"
shows "bsimp (bsimp_ASEQ x1 (bsimp r1) (bsimp r2)) = bsimp_ASEQ x1 (bsimp r1) (bsimp r2)"
using assms
apply(case_tac "bsimp r1 = AZERO")
apply(simp)
apply(case_tac "bsimp r2 = AZERO")
apply(simp)
apply(case_tac "\<exists>bs. bsimp r1 = AONE bs")
apply(auto)[1]
apply (metis bsimp_fuse)
apply(simp add: bsimp_ASEQ1)
done
lemma bsimp_AALTs_idem:
assumes "\<forall>r \<in> set rs. bsimp (bsimp r) = bsimp r"
shows "bsimp (bsimp_AALTs bs rs) = bsimp_AALTs bs (map bsimp rs)"
using assms
apply(induct bs rs rule: bsimp_AALTs.induct)
apply(simp)
apply(simp)
using bsimp_fuse apply presburger
oops
lemma bsimp_idem_rev:
shows "\<nexists>r2. bsimp r1 \<leadsto> r2"
apply(induct r1 rule: bsimp.induct)
apply(auto)
defer
defer
using rrewrite.simps apply blast
using rrewrite.cases apply blast
using rrewrite.simps apply blast
using rrewrite.cases apply blast
apply(case_tac "bsimp r1 = AZERO")
apply(simp)
apply(case_tac "bsimp r2 = AZERO")
apply(simp)
apply(case_tac "\<exists>bs. bsimp r1 = AONE bs")
apply(auto)[1]
prefer 2
apply (smt (verit, best) arexp.distinct(25) arexp.inject(3) bsimp_ASEQ1 rrewrite.simps)
defer
oops
lemma bsimp_idem:
shows "bsimp (bsimp r) = bsimp r"
apply(induct r rule: bsimp.induct)
apply(auto)
using bsimp_ASEQ_idem apply presburger
oops
lemma neg:
shows " \<not>(\<exists>r2. r1 \<leadsto> r2 \<and> (r2 \<leadsto>* bsimp r1) )"
apply(rule notI)
apply(erule exE)
apply(erule conjE)
oops
lemma reduction_always_in_bsimp:
shows " \<lbrakk> r1 \<leadsto> r2 ; \<not>(r2 \<leadsto>* bsimp r1)\<rbrakk> \<Longrightarrow> False"
apply(erule rrewrite.cases)
apply simp
apply auto
oops
*)
(*
AALTs [] [AZERO, AALTs(bs1, [a, b]) ]
rewrite seq 1: \<leadsto> AALTs [] [ AALTs(bs1, [a, b]) ] \<leadsto>
fuse [] (AALTs bs1, [a, b])
rewrite seq 2: \<leadsto> AALTs [] [AZERO, (fuse bs1 a), (fuse bs1 b)]) ]
*)
(*r' size bsimp r > size r'
r' \<leadsto>* bsimp bsimp r
size bsimp r > size r' \<ge> size bsimp bsimp r*)
unused_thms
(*
inductive aggressive:: "arexp \<Rightarrow> arexp \<Rightarrow> bool" ("_ \<leadsto>? _" [99, 99] 99)
where
"ASEQ bs (AALTs bs1 rs) r \<leadsto>? AALTs (bs@bs1) (map (\<lambda>r'. ASEQ [] r' r) rs) "
*)
end