theory BasicIdentities 

  imports "RfltsRdistinctProps" 

begin

lemma rder_rsimp_ALTs_commute:

  shows "  (rder x (rsimp_ALTs rs)) = rsimp_ALTs (map (rder x) rs)"

  apply(induct rs)

   apply simp

  apply(case_tac rs)

   apply simp

  apply auto

  done

lemma rsimp_aalts_smaller:

  shows "rsize (rsimp_ALTs  rs) \<le> rsize (RALTS rs)"

  apply(induct rs)

   apply simp

  apply simp

  apply(case_tac "rs = []")

   apply simp

  apply(subgoal_tac "\<exists>rsp ap. rs = ap # rsp")

   apply(erule exE)+

   apply simp

  apply simp

  by(meson neq_Nil_conv)

lemma rSEQ_mono:

  shows "rsize (rsimp_SEQ r1 r2) \<le>rsize (RSEQ r1 r2)"

  apply auto

  apply(induct r1)

       apply auto

      apply(case_tac "r2")

       apply simp_all

     apply(case_tac r2)

          apply simp_all

     apply(case_tac r2)

         apply simp_all

     apply(case_tac r2)

        apply simp_all

     apply(case_tac r2)

  apply simp_all

  done

lemma ralts_cap_mono:

  shows "rsize (RALTS rs) \<le> Suc (rsizes rs)"

  by simp

lemma rflts_mono:

  shows "rsizes (rflts rs) \<le> rsizes rs"

  apply(induct rs)

  apply simp

  apply(case_tac "a = RZERO")

   apply simp

  apply(case_tac "\<exists>rs1. a = RALTS rs1")

  apply(erule exE)

   apply simp

  apply(subgoal_tac "rflts (a # rs) = a # (rflts rs)")

   prefer 2

  using rflts_def_idiot apply blast

  apply simp

  done

lemma rdistinct_smaller: 

  shows "rsizes (rdistinct rs ss) \<le> rsizes rs"

  apply (induct rs arbitrary: ss)

   apply simp

  by (simp add: trans_le_add2)

lemma rsimp_alts_mono :

  shows "\<And>x. (\<And>xa. xa \<in> set x \<Longrightarrow> rsize (rsimp xa) \<le> rsize xa)  \<Longrightarrow>

      rsize (rsimp_ALTs (rdistinct (rflts (map rsimp x)) {})) \<le> Suc (rsizes x)"

  apply(subgoal_tac "rsize (rsimp_ALTs (rdistinct (rflts (map rsimp x)) {} )) 

                    \<le> rsize (RALTS (rdistinct (rflts (map rsimp x)) {} ))")

  prefer 2

  using rsimp_aalts_smaller apply auto[1]

  apply(subgoal_tac "rsize (RALTS (rdistinct (rflts (map rsimp x)) {})) \<le>Suc (rsizes (rdistinct (rflts (map rsimp x)) {}))")

  prefer 2

  using ralts_cap_mono apply blast

  apply(subgoal_tac "rsizes (rdistinct (rflts (map rsimp x)) {}) \<le> rsizes (rflts (map rsimp x))")

  prefer 2

  using rdistinct_smaller apply presburger

  apply(subgoal_tac "rsizes (rflts (map rsimp x)) \<le> rsizes (map rsimp x)")

  prefer 2

  using rflts_mono apply blast

  apply(subgoal_tac "rsizes (map rsimp x) \<le> rsizes x")

  prefer 2

  apply (simp add: sum_list_mono)

  by linarith

lemma rsimp_mono:

  shows "rsize (rsimp r) \<le> rsize r"

  apply(induct r)

  apply simp_all

  apply(subgoal_tac "rsize (rsimp_SEQ (rsimp r1) (rsimp r2)) \<le> rsize (RSEQ (rsimp r1) (rsimp r2))")

    apply force

  using rSEQ_mono

   apply presburger

  using rsimp_alts_mono by auto

lemma idiot:

  shows "rsimp_SEQ RONE r = r"

  apply(case_tac r)

       apply simp_all

  done

lemma idiot2:

  shows " \<lbrakk>r1 \<noteq> RZERO; r1 \<noteq> RONE;r2 \<noteq> RZERO\<rbrakk>

    \<Longrightarrow> rsimp_SEQ r1 r2 = RSEQ r1 r2"

  apply(case_tac r1)

       apply(case_tac r2)

  apply simp_all

     apply(case_tac r2)

  apply simp_all

     apply(case_tac r2)

  apply simp_all

   apply(case_tac r2)

  apply simp_all

  apply(case_tac r2)

       apply simp_all

  done

lemma rders__onechar:

  shows " (rders_simp r [c]) =  (rsimp (rders r [c]))"

  by simp

lemma rders_append:

  "rders c (s1 @ s2) = rders (rders c s1) s2"

  apply(induct s1 arbitrary: c s2)

  apply(simp_all)

  done

lemma rders_simp_append:

  "rders_simp c (s1 @ s2) = rders_simp (rders_simp c s1) s2"

  apply(induct s1 arbitrary: c s2)

   apply(simp_all)

  done

lemma rders_simp_one_char:

  shows "rders_simp r [c] = rsimp (rder c r)"

  apply auto

  done

lemma  k0a:

  shows "rflts [RALTS rs] =   rs"

  apply(simp)

  done

lemma bbbbs:

  assumes "good r" "r = RALTS rs"

  shows "rsimp_ALTs  (rflts [r]) = RALTS rs"

  using  assms

  by (metis good.simps(4) good.simps(5) k0a rsimp_ALTs.elims)

lemma bbbbs1:

  shows "nonalt r \<or> (\<exists> rs. r  = RALTS  rs)"

  by (meson nonalt.elims(3))

lemma good0:

  assumes "rs \<noteq> Nil" "\<forall>r \<in> set rs. nonalt r" "distinct rs"

  shows "good (rsimp_ALTs rs) \<longleftrightarrow> (\<forall>r \<in> set rs. good r)"

  using  assms

  apply(induct  rs rule: rsimp_ALTs.induct)

  apply(auto)

  done

lemma flts1:

  assumes "good r" 

  shows "rflts [r] \<noteq> []"

  using  assms

  apply(induct r)

       apply(simp_all)

  using good.simps(4) by blast

lemma flts2:

  assumes "good r" 

  shows "\<forall>r' \<in> set (rflts [r]). good r' \<and> nonalt r'"

  using  assms

  apply(induct r)

       apply(simp)

      apply(simp)

     apply(simp)

    prefer 2

    apply(simp)

    apply(auto)[1]

     apply (metis flts1 good.simps(5) good.simps(6) k0a neq_Nil_conv)

    apply (metis flts1 good.simps(5) good.simps(6) k0a neq_Nil_conv)

   apply fastforce

  apply(simp)

  done  

lemma flts3:

  assumes "\<forall>r \<in> set rs. good r \<or> r = RZERO" 

  shows "\<forall>r \<in> set (rflts rs). good r"

  using  assms

  apply(induct rs rule: rflts.induct)

        apply(simp_all)

  by (metis UnE flts2 k0a)

lemma  k0:

  shows "rflts (r # rs1) = rflts [r] @ rflts rs1"

  apply(induct r arbitrary: rs1)

   apply(auto)

  done

lemma good_SEQ:

  assumes "r1 \<noteq> RZERO" "r2 \<noteq> RZERO" " r1 \<noteq> RONE"

  shows "good (RSEQ r1 r2) = (good r1 \<and> good r2)"

  using assms

  apply(case_tac r1)

       apply(simp_all)

  apply(case_tac r2)

          apply(simp_all)

  apply(case_tac r2)

         apply(simp_all)

  apply(case_tac r2)

        apply(simp_all)

  apply(case_tac r2)

       apply(simp_all)

  done

lemma rsize0:

  shows "0 < rsize r"

  apply(induct  r)

       apply(auto)

  done

lemma nn1qq:

  assumes "nonnested (RALTS rs)"

  shows "\<nexists> rs1. RALTS rs1 \<in> set rs"

  using assms

  apply(induct rs rule: rflts.induct)

  apply(auto)

  done

lemma n0:

  shows "nonnested (RALTS rs) \<longleftrightarrow> (\<forall>r \<in> set rs. nonalt r)"

  apply(induct rs )

   apply(auto)

    apply (metis list.set_intros(1) nn1qq nonalt.elims(3))

  apply (metis nonalt.elims(2) nonnested.simps(3) nonnested.simps(4) nonnested.simps(5) nonnested.simps(6) nonnested.simps(7))

  using bbbbs1 apply fastforce

  by (metis bbbbs1 list.set_intros(2) nn1qq)

lemma nn1c:

  assumes "\<forall>r \<in> set rs. nonnested r"

  shows "\<forall>r \<in> set (rflts rs). nonalt r"

  using assms

  apply(induct rs rule: rflts.induct)

        apply(auto)

  using n0 by blast

lemma nn1bb:

  assumes "\<forall>r \<in> set rs. nonalt r"

  shows "nonnested (rsimp_ALTs  rs)"

  using assms

  apply(induct  rs rule: rsimp_ALTs.induct)

    apply(auto)

  using nonalt.simps(1) nonnested.elims(3) apply blast

  using n0 by auto

lemma bsimp_ASEQ0:

  shows "rsimp_SEQ  r1 RZERO = RZERO"

  apply(induct r1)

  apply(auto)

  done

lemma nn1b:

  shows "nonnested (rsimp r)"

  apply(induct r)

       apply(simp_all)

  apply(case_tac "rsimp r1 = RZERO")

    apply(simp)

 apply(case_tac "rsimp r2 = RZERO")

   apply(simp)

    apply(subst bsimp_ASEQ0)

  apply(simp)

  apply(case_tac "\<exists>bs. rsimp r1 = RONE")

    apply(auto)[1]

  using idiot apply fastforce

  using idiot2 nonnested.simps(11) apply presburger

  by (metis (mono_tags, lifting) Diff_empty image_iff list.set_map nn1bb nn1c rdistinct_set_equality1)

lemma nonalt_flts_rd:

  shows "\<lbrakk>xa \<in> set (rdistinct (rflts (map rsimp rs)) {})\<rbrakk>

       \<Longrightarrow> nonalt xa"

  by (metis Diff_empty ex_map_conv nn1b nn1c rdistinct_set_equality1)

lemma bsimp_ASEQ2:

  shows "rsimp_SEQ RONE r2 =  r2"

  apply(induct r2)

  apply(auto)

  done

lemma elem_smaller_than_set:

  shows "xa \<in> set  list \<Longrightarrow> rsize xa < Suc (rsizes list)"

  apply(induct list)

   apply simp

  by (metis image_eqI le_imp_less_Suc list.set_map member_le_sum_list)

lemma rsimp_list_mono:

  shows "rsizes (map rsimp rs) \<le> rsizes rs"

  apply(induct rs)

   apply simp+

  by (simp add: add_mono_thms_linordered_semiring(1) rsimp_mono)

(*says anything coming out of simp+flts+db will be good*)

lemma good2_obv_simplified:

  shows " \<lbrakk>\<forall>y. rsize y < Suc (rsizes rs) \<longrightarrow> good (rsimp y) \<or> rsimp y = RZERO;

           xa \<in> set (rdistinct (rflts (map rsimp rs)) {})\<rbrakk> \<Longrightarrow> good xa"

  apply(subgoal_tac " \<forall>xa' \<in> set (map rsimp rs). good xa' \<or> xa' = RZERO")

  prefer 2

   apply (simp add: elem_smaller_than_set)

  by (metis Diff_empty flts3 rdistinct_set_equality1)

lemma good1:

  shows "good (rsimp a) \<or> rsimp a = RZERO"

  apply(induct a taking: rsize rule: measure_induct)

  apply(case_tac x)

  apply(simp)

  apply(simp)

  apply(simp)

  prefer 3

    apply(simp)

   prefer 2

   apply(simp only:)

   apply simp

  apply (smt (verit, ccfv_threshold) add_mono_thms_linordered_semiring(1) elem_smaller_than_set good0 good2_obv_simplified le_eq_less_or_eq nonalt_flts_rd order_less_trans plus_1_eq_Suc rdistinct_does_the_job rdistinct_smaller rflts_mono rsimp_ALTs.simps(1) rsimp_list_mono)

  apply simp

  apply(subgoal_tac "good (rsimp x41) \<or> rsimp x41 = RZERO")

   apply(subgoal_tac "good (rsimp x42) \<or> rsimp x42 = RZERO")

    apply(case_tac "rsimp x41 = RZERO")

     apply simp

    apply(case_tac "rsimp x42 = RZERO")

     apply simp

  using bsimp_ASEQ0 apply blast

    apply(subgoal_tac "good (rsimp x41)")

     apply(subgoal_tac "good (rsimp x42)")

      apply simp

  apply (metis bsimp_ASEQ2 good_SEQ idiot2)

  apply blast

  apply fastforce

  using less_add_Suc2 apply blast  

  using less_iff_Suc_add by blast

lemma RL_rnullable:

  shows "rnullable r = ([] \<in> RL r)"

  apply(induct r)

  apply(auto simp add: Sequ_def)

  done

lemma RL_rder:

  shows "RL (rder c r) = Der c (RL r)"

  apply(induct r)

  apply(auto simp add: Sequ_def Der_def)

        apply (metis append_Cons)

  using RL_rnullable apply blast

  apply (metis append_eq_Cons_conv)

  apply (metis append_Cons)

  apply (metis RL_rnullable append_eq_Cons_conv)

  apply (metis Star.step append_Cons)

  using Star_decomp by auto

lemma RL_rsimp_RSEQ:

  shows "RL (rsimp_SEQ r1 r2) = (RL r1 ;; RL r2)"

  apply(induct r1 r2 rule: rsimp_SEQ.induct)

  apply(simp_all)

  done

lemma RL_rsimp_RALTS:

  shows "RL (rsimp_ALTs rs) = (\<Union> (set (map RL rs)))"

  apply(induct rs rule: rsimp_ALTs.induct)

  apply(simp_all)

  done

lemma RL_rsimp_rdistinct:

  shows "(\<Union> (set (map RL (rdistinct rs {})))) = (\<Union> (set (map RL rs)))"

  apply(auto)

  apply (metis Diff_iff rdistinct_set_equality1)

  by (metis Diff_empty rdistinct_set_equality1)

lemma RL_rsimp_rflts:

  shows "(\<Union> (set (map RL (rflts rs)))) = (\<Union> (set (map RL rs)))"

  apply(induct rs rule: rflts.induct)

  apply(simp_all)

  done

lemma RL_rsimp:

  shows "RL r = RL (rsimp r)"

  apply(induct r rule: rsimp.induct)

       apply(auto simp add: Sequ_def RL_rsimp_RSEQ)

  using RL_rsimp_RALTS RL_rsimp_rdistinct RL_rsimp_rflts apply auto[1]

  by (smt (verit, del_insts) RL_rsimp_RALTS RL_rsimp_rdistinct RL_rsimp_rflts UN_E image_iff list.set_map)

lemma der_simp_nullability:

  shows "rnullable r = rnullable (rsimp r)"

  using RL_rnullable RL_rsimp by auto

lemma qqq1:

  shows "RZERO \<notin> set (rflts (map rsimp rs))"

  by (metis ex_map_conv flts3 good.simps(1) good1)

lemma flts_single1:

  assumes "nonalt r" "nonazero r"

  shows "rflts [r] = [r]"

  using assms

  apply(induct r)

  apply(auto)

  done

lemma nonalt0_flts_keeps:

  shows "(a \<noteq> RZERO) \<and> (\<forall>rs. a \<noteq> RALTS rs) \<Longrightarrow> rflts (a # xs) = a # rflts xs"

  apply(case_tac a)

       apply simp+

  done

lemma nonalt0_fltseq:

  shows "\<forall>r \<in> set rs. r \<noteq> RZERO \<and> nonalt r \<Longrightarrow> rflts rs = rs"

  apply(induct rs)

   apply simp

  apply(case_tac "a = RZERO")

   apply fastforce

  apply(case_tac "\<exists>rs1. a = RALTS rs1")

   apply(erule exE)

   apply simp+

  using nonalt0_flts_keeps by presburger

lemma goodalts_nonalt:

  shows "good (RALTS rs) \<Longrightarrow> rflts rs = rs"

  apply(induct x == "RALTS rs" arbitrary: rs rule: good.induct)

    apply simp

  using good.simps(5) apply blast

  apply simp

  apply(case_tac "r1 = RZERO")

  using good.simps(1) apply force

  apply(case_tac "r2 = RZERO")

  using good.simps(1) apply force

  apply(subgoal_tac "rflts (r1 # r2 # rs) = r1 # r2 # rflts rs")

  prefer 2

   apply (metis nonalt.simps(1) rflts_def_idiot)

  apply(subgoal_tac "\<forall>r \<in> set rs. r \<noteq> RZERO \<and> nonalt r")

   apply(subgoal_tac "rflts rs = rs")

    apply presburger

  using nonalt0_fltseq apply presburger

  using good.simps(1) by blast

lemma test:

  assumes "good r"

  shows "rsimp r = r"

  using assms

  apply(induct rule: good.induct)

                      apply simp