theory Sulzmann

  imports "Lexer" 

begin

section {* Bit-Encodings *}

datatype bit = Z | S

fun 

  code :: "val \<Rightarrow> bit list"

where

  "code Void = []"

| "code (Char c) = []"

| "code (Left v) = Z # (code v)"

| "code (Right v) = S # (code v)"

| "code (Seq v1 v2) = (code v1) @ (code v2)"

| "code (Stars []) = [S]"

| "code (Stars (v # vs)) =  (Z # code v) @ code (Stars vs)"

fun 

  Stars_add :: "val \<Rightarrow> val \<Rightarrow> val"

where

  "Stars_add v (Stars vs) = Stars (v # vs)"

function

  decode' :: "bit list \<Rightarrow> rexp \<Rightarrow> (val * bit list)"

where

  "decode' ds ZERO = (Void, [])"

| "decode' ds ONE = (Void, ds)"

| "decode' ds (CH d) = (Char d, ds)"

| "decode' [] (ALT r1 r2) = (Void, [])"

| "decode' (Z # ds) (ALT r1 r2) = (let (v, ds') = decode' ds r1 in (Left v, ds'))"

| "decode' (S # ds) (ALT r1 r2) = (let (v, ds') = decode' ds r2 in (Right v, ds'))"

| "decode' ds (SEQ r1 r2) = (let (v1, ds') = decode' ds r1 in

                             let (v2, ds'') = decode' ds' r2 in (Seq v1 v2, ds''))"

| "decode' [] (STAR r) = (Void, [])"

| "decode' (S # ds) (STAR r) = (Stars [], ds)"

| "decode' (Z # ds) (STAR r) = (let (v, ds') = decode' ds r in

                                    let (vs, ds'') = decode' ds' (STAR r) 

                                    in (Stars_add v vs, ds''))"

by pat_completeness auto

lemma decode'_smaller:

  assumes "decode'_dom (ds, r)"

  shows "length (snd (decode' ds r)) \<le> length ds"

using assms

apply(induct ds r)

apply(auto simp add: decode'.psimps split: prod.split)

using dual_order.trans apply blast

by (meson dual_order.trans le_SucI)

termination "decode'"  

apply(relation "inv_image (measure(%cs. size cs) <*lex*> measure(%s. size s)) (%(ds,r). (r,ds))") 

apply(auto dest!: decode'_smaller)

by (metis less_Suc_eq_le snd_conv)

definition

  decode :: "bit list \<Rightarrow> rexp \<Rightarrow> val option"

where

  "decode ds r \<equiv> (let (v, ds') = decode' ds r 

                  in (if ds' = [] then Some v else None))"

lemma decode'_code_Stars:

  assumes "\<forall>v\<in>set vs. \<Turnstile> v : r \<and> (\<forall>x. decode' (code v @ x) r = (v, x)) \<and> flat v \<noteq> []" 

  shows "decode' (code (Stars vs) @ ds) (STAR r) = (Stars vs, ds)"

  using assms

  apply(induct vs)

  apply(auto)

  done

lemma decode'_code:

  assumes "\<Turnstile> v : r"

  shows "decode' ((code v) @ ds) r = (v, ds)"

using assms

  apply(induct v r arbitrary: ds) 

  apply(auto)

  using decode'_code_Stars by blast

lemma decode_code:

  assumes "\<Turnstile> v : r"

  shows "decode (code v) r = Some v"

  using assms unfolding decode_def

  by (smt append_Nil2 decode'_code old.prod.case)

datatype arexp =

  AZERO

| AONE "bit list"

| ACH "bit list" char

| ASEQ "bit list" arexp arexp

| AALT "bit list" arexp arexp

| ASTAR "bit list" arexp

fun fuse :: "bit list \<Rightarrow> arexp \<Rightarrow> arexp" where

  "fuse bs AZERO = AZERO"

| "fuse bs (AONE cs) = AONE (bs @ cs)" 

| "fuse bs (ACH cs c) = ACH (bs @ cs) c"

| "fuse bs (AALT cs r1 r2) = AALT (bs @ cs) r1 r2"

| "fuse bs (ASEQ cs r1 r2) = ASEQ (bs @ cs) r1 r2"

| "fuse bs (ASTAR cs r) = ASTAR (bs @ cs) r"

fun intern :: "rexp \<Rightarrow> arexp" where

  "intern ZERO = AZERO"

| "intern ONE = AONE []"

| "intern (CH c) = ACH [] c"

| "intern (ALT r1 r2) = AALT [] (fuse [Z] (intern r1)) 

                                (fuse [S]  (intern r2))"

| "intern (SEQ r1 r2) = ASEQ [] (intern r1) (intern r2)"

| "intern (STAR r) = ASTAR [] (intern r)"

fun retrieve :: "arexp \<Rightarrow> val \<Rightarrow> bit list" where

  "retrieve (AONE bs) Void = bs"

| "retrieve (ACH bs c) (Char d) = bs"

| "retrieve (AALT bs r1 r2) (Left v) = bs @ retrieve r1 v"

| "retrieve (AALT bs r1 r2) (Right v) = bs @ retrieve r2 v"

| "retrieve (ASEQ bs r1 r2) (Seq v1 v2) = bs @ retrieve r1 v1 @ retrieve r2 v2"

| "retrieve (ASTAR bs r) (Stars []) = bs @ [S]"

| "retrieve (ASTAR bs r) (Stars (v#vs)) = 

     bs @ [Z] @ retrieve r v @ retrieve (ASTAR [] r) (Stars vs)"

fun 

  erase :: "arexp \<Rightarrow> rexp"

where

  "erase AZERO = ZERO"

| "erase (AONE _) = ONE"

| "erase (ACH _ c) = CH c"

| "erase (AALT _ r1 r2) = ALT (erase r1) (erase r2)"

| "erase (ASEQ _ r1 r2) = SEQ (erase r1) (erase r2)"

| "erase (ASTAR _ r) = STAR (erase r)"

fun

 bnullable :: "arexp \<Rightarrow> bool"

where

  "bnullable (AZERO) = False"

| "bnullable (AONE bs) = True"

| "bnullable (ACH bs c) = False"

| "bnullable (AALT bs r1 r2) = (bnullable r1 \<or> bnullable r2)"

| "bnullable (ASEQ bs r1 r2) = (bnullable r1 \<and> bnullable r2)"

| "bnullable (ASTAR bs r) = True"

fun 

  bmkeps :: "arexp \<Rightarrow> bit list"

where

  "bmkeps(AONE bs) = bs"

| "bmkeps(ASEQ bs r1 r2) = bs @ (bmkeps r1) @ (bmkeps r2)"

| "bmkeps(AALT bs r1 r2) = (if bnullable(r1) then bs @ (bmkeps r1) else bs @ (bmkeps r2))"

| "bmkeps(ASTAR bs r) = bs @ [S]"

fun

 bder :: "char \<Rightarrow> arexp \<Rightarrow> arexp"

where

  "bder c (AZERO) = AZERO"

| "bder c (AONE bs) = AZERO"

| "bder c (ACH bs d) = (if c = d then AONE bs else AZERO)"

| "bder c (AALT bs r1 r2) = AALT bs (bder c r1) (bder c r2)"

| "bder c (ASEQ bs r1 r2) = 

     (if bnullable r1

      then AALT bs (ASEQ [] (bder c r1) r2) (fuse (bmkeps r1) (bder c r2))

      else ASEQ bs (bder c r1) r2)"

| "bder c (ASTAR bs r) = ASEQ bs (fuse [Z] (bder c r)) (ASTAR [] r)"

fun 

  bders :: "arexp \<Rightarrow> string \<Rightarrow> arexp"

where

  "bders r [] = r"

| "bders r (c#s) = bders (bder c r) s"

lemma bders_append:

  "bders r (s1 @ s2) = bders (bders r s1) s2"

  apply(induct s1 arbitrary: r s2)

  apply(simp_all)

  done

lemma bnullable_correctness:

  shows "nullable (erase r) = bnullable r"

  apply(induct r)

  apply(simp_all)

  done

lemma erase_fuse:

  shows "erase (fuse bs r) = erase r"

  apply(induct r)

  apply(simp_all)

  done

lemma erase_intern[simp]:

  shows "erase (intern r) = r"

  apply(induct r)

  apply(simp_all add: erase_fuse)

  done

lemma erase_bder[simp]:

  shows "erase (bder a r) = der a (erase r)"

  apply(induct r)

  apply(simp_all add: erase_fuse bnullable_correctness)

  done

lemma erase_bders[simp]:

  shows "erase (bders r s) = ders s (erase r)"

  apply(induct s arbitrary: r )

  apply(simp_all)

  done

lemma retrieve_encode_STARS:

  assumes "\<forall>v\<in>set vs. \<Turnstile> v : r \<and> code v = retrieve (intern r) v"

  shows "code (Stars vs) = retrieve (ASTAR [] (intern r)) (Stars vs)"

  using assms

  apply(induct vs)

  apply(simp_all)

  done

lemma retrieve_fuse2:

  assumes "\<Turnstile> v : (erase r)"

  shows "retrieve (fuse bs r) v = bs @ retrieve r v"

  using assms

  apply(induct r arbitrary: v bs)

  using retrieve_encode_STARS

  apply(auto elim!: Prf_elims)

  apply(case_tac vs)

  apply(simp)

  apply(simp)

  done

lemma retrieve_fuse:

  assumes "\<Turnstile> v : r"

  shows "retrieve (fuse bs (intern r)) v = bs @ retrieve (intern r) v"

  using assms 

  by (simp_all add: retrieve_fuse2)

lemma retrieve_code:

  assumes "\<Turnstile> v : r"

  shows "code v = retrieve (intern r) v"

  using assms

  apply(induct v r)

  apply(simp_all add: retrieve_fuse retrieve_encode_STARS)

  done

lemma bmkeps_retrieve:

  assumes "nullable (erase r)"

  shows "bmkeps r = retrieve r (mkeps (erase r))"

  using assms

  apply(induct r)

       apply(simp)

      apply(simp)

     apply(simp)

    apply(simp) 

   apply(simp only: bmkeps.simps bnullable_correctness)

  apply(auto simp only: split: if_split)

  apply(auto simp add: bnullable_correctness)

  done

lemma bder_retrieve:

  assumes "\<Turnstile> v : der c (erase r)"

  shows "retrieve (bder c r) v = retrieve r (injval (erase r) c v)"

  using assms

  apply(induct r arbitrary: v)

  apply(auto elim!: Prf_elims simp add: retrieve_fuse2 bnullable_correctness bmkeps_retrieve)

  done

lemma MAIN_decode:

  assumes "\<Turnstile> v : ders s r"

  shows "Some (flex r id s v) = decode (retrieve (bders (intern r) s) v) r"

  using assms

proof (induct s arbitrary: v rule: rev_induct)

  case Nil

  have "\<Turnstile> v : ders [] r" by fact

  then have "\<Turnstile> v : r" by simp

  then have "Some v = decode (retrieve (intern r) v) r"

    using decode_code retrieve_code by auto

  then show "Some (flex r id [] v) = decode (retrieve (bders (intern r) []) v) r"

    by simp

next

  case (snoc c s v)

  have IH: "\<And>v. \<Turnstile> v : ders s r \<Longrightarrow> 

     Some (flex r id s v) = decode (retrieve (bders (intern r) s) v) r" by fact

  have asm: "\<Turnstile> v : ders (s @ [c]) r" by fact

  then have asm2: "\<Turnstile> injval (ders s r) c v : ders s r" 

    by(simp add: Prf_injval ders_append)

  have "Some (flex r id (s @ [c]) v) = Some (flex r id s (injval (ders s r) c v))"

    by (simp add: flex_append)

  also have "... = decode (retrieve (bders (intern r) s) (injval (ders s r) c v)) r"

    using asm2 IH by simp

  also have "... = decode (retrieve (bder c (bders (intern r) s)) v) r"

    using asm by(simp_all add: bder_retrieve ders_append)

  finally show "Some (flex r id (s @ [c]) v) = 

                 decode (retrieve (bders (intern r) (s @ [c])) v) r" by (simp add: bders_append)

qed

definition blexer where

 "blexer r s \<equiv> if bnullable (bders (intern r) s) then 

                decode (bmkeps (bders (intern r) s)) r else None"

lemma blexer_correctness:

  shows "blexer r s = lexer r s"

proof -

  { define bds where "bds \<equiv> bders (intern r) s"

    define ds  where "ds \<equiv> ders s r"

    assume asm: "nullable ds"

    have era: "erase bds = ds" 

      unfolding ds_def bds_def by simp

    have mke: "\<Turnstile> mkeps ds : ds"

      using asm by (simp add: mkeps_nullable)

    have "decode (bmkeps bds) r = decode (retrieve bds (mkeps ds)) r"

      using bmkeps_retrieve

      using asm era by (simp add: bmkeps_retrieve)

    also have "... =  Some (flex r id s (mkeps ds))"

      using mke by (simp_all add: MAIN_decode ds_def bds_def)

    finally have "decode (bmkeps bds) r = Some (flex r id s (mkeps ds))" 

      unfolding bds_def ds_def .

  }

  then show "blexer r s = lexer r s"

    unfolding blexer_def lexer_flex

    apply(subst bnullable_correctness[symmetric])

    apply(simp)

    done

qed

end