theory SpecExt

  imports Main "~~/src/HOL/Library/Sublist"

begin

section {* Sequential Composition of Languages *}

definition

  Sequ :: "string set \<Rightarrow> string set \<Rightarrow> string set" ("_ ;; _" [100,100] 100)

where 

  "A ;; B = {s1 @ s2 | s1 s2. s1 \<in> A \<and> s2 \<in> B}"

text {* Two Simple Properties about Sequential Composition *}

lemma Sequ_empty_string [simp]:

  shows "A ;; {[]} = A"

  and   "{[]} ;; A = A"

by (simp_all add: Sequ_def)

lemma Sequ_empty [simp]:

  shows "A ;; {} = {}"

  and   "{} ;; A = {}"

by (simp_all add: Sequ_def)

lemma Sequ_assoc:

  shows "(A ;; B) ;; C = A ;; (B ;; C)"

apply(auto simp add: Sequ_def)

apply blast

by (metis append_assoc)

lemma Sequ_Union_in:

  shows "(A ;; (\<Union>x\<in> B. C x)) = (\<Union>x\<in> B. A ;; C x)" 

by (auto simp add: Sequ_def)

section {* Semantic Derivative (Left Quotient) of Languages *}

definition

  Der :: "char \<Rightarrow> string set \<Rightarrow> string set"

where

  "Der c A \<equiv> {s. c # s \<in> A}"

definition

  Ders :: "string \<Rightarrow> string set \<Rightarrow> string set"

where

  "Ders s A \<equiv> {s'. s @ s' \<in> A}"

lemma Der_null [simp]:

  shows "Der c {} = {}"

unfolding Der_def

by auto

lemma Der_empty [simp]:

  shows "Der c {[]} = {}"

unfolding Der_def

by auto

lemma Der_char [simp]:

  shows "Der c {[d]} = (if c = d then {[]} else {})"

unfolding Der_def

by auto

lemma Der_union [simp]:

  shows "Der c (A \<union> B) = Der c A \<union> Der c B"

unfolding Der_def

by auto

lemma Der_UNION [simp]: 

  shows "Der c (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. Der c (B x))"

by (auto simp add: Der_def)

lemma Der_Sequ [simp]:

  shows "Der c (A ;; B) = (Der c A) ;; B \<union> (if [] \<in> A then Der c B else {})"

unfolding Der_def Sequ_def

by (auto simp add: Cons_eq_append_conv)

section {* Kleene Star for Languages *}

inductive_set

  Star :: "string set \<Rightarrow> string set" ("_\<star>" [101] 102)

  for A :: "string set"

where

  start[intro]: "[] \<in> A\<star>"

| step[intro]:  "\<lbrakk>s1 \<in> A; s2 \<in> A\<star>\<rbrakk> \<Longrightarrow> s1 @ s2 \<in> A\<star>"

(* Arden's lemma *)

lemma Star_cases:

  shows "A\<star> = {[]} \<union> A ;; A\<star>"

unfolding Sequ_def

by (auto) (metis Star.simps)

lemma Star_decomp: 

  assumes "c # x \<in> A\<star>" 

  shows "\<exists>s1 s2. x = s1 @ s2 \<and> c # s1 \<in> A \<and> s2 \<in> A\<star>"

using assms

by (induct x\<equiv>"c # x" rule: Star.induct) 

   (auto simp add: append_eq_Cons_conv)

lemma Star_Der_Sequ: 

  shows "Der c (A\<star>) \<subseteq> (Der c A) ;; A\<star>"

unfolding Der_def Sequ_def

by(auto simp add: Star_decomp)

lemma Der_star [simp]:

  shows "Der c (A\<star>) = (Der c A) ;; A\<star>"

proof -    

  have "Der c (A\<star>) = Der c ({[]} \<union> A ;; A\<star>)"  

    by (simp only: Star_cases[symmetric])

  also have "... = Der c (A ;; A\<star>)"

    by (simp only: Der_union Der_empty) (simp)

  also have "... = (Der c A) ;; A\<star> \<union> (if [] \<in> A then Der c (A\<star>) else {})"

    by simp

  also have "... =  (Der c A) ;; A\<star>"

    using Star_Der_Sequ by auto

  finally show "Der c (A\<star>) = (Der c A) ;; A\<star>" .

qed

section {* Power operation for Sets *}

fun 

  Pow :: "string set \<Rightarrow> nat \<Rightarrow> string set" ("_ \<up> _" [101, 102] 101)

where

   "A \<up> 0 = {[]}"

|  "A \<up> (Suc n) = A ;; (A \<up> n)"

lemma Pow_empty [simp]:

  shows "[] \<in> A \<up> n \<longleftrightarrow> (n = 0 \<or> [] \<in> A)"

by(induct n) (auto simp add: Sequ_def)

lemma Pow_Suc_rev:

  "A \<up> (Suc n) =  (A \<up> n) ;; A"

apply(induct n arbitrary: A)

apply(simp_all)

by (metis Sequ_assoc)

lemma Pow_decomp: 

  assumes "c # x \<in> A \<up> n" 

  shows "\<exists>s1 s2. x = s1 @ s2 \<and> c # s1 \<in> A \<and> s2 \<in> A \<up> (n - 1)"

using assms

apply(induct n) 

apply(auto simp add: Cons_eq_append_conv Sequ_def)

apply(case_tac n)

apply(auto simp add: Sequ_def)

apply(blast)

done

lemma Star_Pow:

  assumes "s \<in> A\<star>"

  shows "\<exists>n. s \<in> A \<up> n"

using assms

apply(induct)

apply(auto)

apply(rule_tac x="Suc n" in exI)

apply(auto simp add: Sequ_def)

done

lemma Pow_Star:

  assumes "s \<in> A \<up> n"

  shows "s \<in> A\<star>"

using assms

apply(induct n arbitrary: s)

apply(auto simp add: Sequ_def)

done

lemma Der_Pow_0:

  shows "Der c (A \<up> 0) = {}"

by(simp add: Der_def)

lemma Der_Pow_Suc:

  shows "Der c (A \<up> (Suc n)) = (Der c A) ;; (A \<up> n)"

unfolding Der_def Sequ_def 

apply(auto simp add: Cons_eq_append_conv Sequ_def dest!: Pow_decomp)

apply(case_tac n)

apply(force simp add: Sequ_def)+

done

lemma Der_Pow [simp]:

  shows "Der c (A \<up> n) = (if n = 0 then {} else (Der c A) ;; (A \<up> (n - 1)))"

apply(case_tac n)

apply(simp_all del: Pow.simps add: Der_Pow_0 Der_Pow_Suc)

done

lemma Der_Pow_Sequ [simp]:

  shows "Der c (A ;; A \<up> n) = (Der c A) ;; (A \<up> n)"

by (simp only: Pow.simps[symmetric] Der_Pow) (simp)

lemma Pow_Sequ_Un:

  assumes "0 < x"

  shows "(\<Union>n \<in> {..x}. (A \<up> n)) = ({[]} \<union> (\<Union>n \<in> {..x - Suc 0}. A ;; (A \<up> n)))"

using assms

apply(auto simp add: Sequ_def)

apply(smt Pow.elims Sequ_def Suc_le_mono Suc_pred atMost_iff empty_iff insert_iff mem_Collect_eq)

apply(rule_tac x="Suc xa" in bexI)

apply(auto simp add: Sequ_def)

done

lemma Pow_Sequ_Un2:

  assumes "0 < x"

  shows "(\<Union>n \<in> {x..}. (A \<up> n)) = (\<Union>n \<in> {x - Suc 0..}. A ;; (A \<up> n))"

using assms

apply(auto simp add: Sequ_def)

apply(case_tac n)

apply(auto simp add: Sequ_def)

apply fastforce

apply(case_tac x)

apply(auto)

apply(rule_tac x="Suc xa" in bexI)

apply(auto simp add: Sequ_def)

done

section {* Regular Expressions *}

datatype rexp =

  ZERO

| ONE

| CHAR char

| SEQ rexp rexp

| ALT rexp rexp

| STAR rexp

| UPNTIMES rexp nat

| NTIMES rexp nat

| FROMNTIMES rexp nat

| NMTIMES rexp nat nat

section {* Semantics of Regular Expressions *}

fun

  L :: "rexp \<Rightarrow> string set"

where

  "L (ZERO) = {}"

| "L (ONE) = {[]}"

| "L (CHAR c) = {[c]}"

| "L (SEQ r1 r2) = (L r1) ;; (L r2)"

| "L (ALT r1 r2) = (L r1) \<union> (L r2)"

| "L (STAR r) = (L r)\<star>"

| "L (UPNTIMES r n) = (\<Union>i\<in> {..n} . (L r) \<up> i)"

| "L (NTIMES r n) = (L r) \<up> n"

| "L (FROMNTIMES r n) = (\<Union>i\<in> {n..} . (L r) \<up> i)"

| "L (NMTIMES r n m) = (\<Union>i\<in>{n..m} . (L r) \<up> i)" 

section {* Nullable, Derivatives *}

fun

 nullable :: "rexp \<Rightarrow> bool"

where

  "nullable (ZERO) = False"

| "nullable (ONE) = True"

| "nullable (CHAR c) = False"

| "nullable (ALT r1 r2) = (nullable r1 \<or> nullable r2)"

| "nullable (SEQ r1 r2) = (nullable r1 \<and> nullable r2)"

| "nullable (STAR r) = True"

| "nullable (UPNTIMES r n) = True"

| "nullable (NTIMES r n) = (if n = 0 then True else nullable r)"

| "nullable (FROMNTIMES r n) = (if n = 0 then True else nullable r)"

| "nullable (NMTIMES r n m) = (if m < n then False else (if n = 0 then True else nullable r))"

fun

 der :: "char \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "der c (ZERO) = ZERO"

| "der c (ONE) = ZERO"

| "der c (CHAR d) = (if c = d then ONE else ZERO)"

| "der c (ALT r1 r2) = ALT (der c r1) (der c r2)"

| "der c (SEQ r1 r2) = 

     (if nullable r1

      then ALT (SEQ (der c r1) r2) (der c r2)

      else SEQ (der c r1) r2)"

| "der c (STAR r) = SEQ (der c r) (STAR r)"

| "der c (UPNTIMES r n) = (if n = 0 then ZERO else SEQ (der c r) (UPNTIMES r (n - 1)))"

| "der c (NTIMES r n) = (if n = 0 then ZERO else SEQ (der c r) (NTIMES r (n - 1)))"

| "der c (FROMNTIMES r n) = 

     (if n = 0 

      then SEQ (der c r) (STAR r)

      else SEQ (der c r) (FROMNTIMES r (n - 1)))"

| "der c (NMTIMES r n m) = 

     (if m < n then ZERO 

      else (if n = 0 then (if m = 0 then ZERO else 

                           SEQ (der c r) (UPNTIMES r (m - 1))) else 

                           SEQ (der c r) (NMTIMES r (n - 1) (m - 1))))" 

fun 

 ders :: "string \<Rightarrow> rexp \<Rightarrow> rexp"

where

  "ders [] r = r"

| "ders (c # s) r = ders s (der c r)"

lemma nullable_correctness:

  shows "nullable r  \<longleftrightarrow> [] \<in> (L r)"

by(induct r) (auto simp add: Sequ_def) 

lemma der_correctness:

  shows "L (der c r) = Der c (L r)"

apply(induct r) 

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

prefer 2

apply(simp add: nullable_correctness del: Der_UNION)

apply(simp add: nullable_correctness del: Der_UNION)

apply(rule impI)

apply(subst Sequ_Union_in)

apply(subst Der_Pow_Sequ[symmetric])

apply(subst Pow.simps[symmetric])

apply(subst Der_UNION[symmetric])

apply(subst Pow_Sequ_Un)

apply(simp)

apply(simp only: Der_union Der_empty)

    apply(simp)

(* FROMNTIMES *)    

   apply(simp add: nullable_correctness del: Der_UNION)

  apply(rule conjI)

prefer 2    

apply(subst Sequ_Union_in)

apply(subst Der_Pow_Sequ[symmetric])

apply(subst Pow.simps[symmetric])

apply(case_tac x2)

prefer 2

apply(subst Pow_Sequ_Un2)

apply(simp)

apply(simp)

    apply(auto simp add: Sequ_def Der_def)[1]

   apply(auto simp add: Sequ_def split: if_splits)[1]

  using Star_Pow apply fastforce

  using Pow_Star apply blast

(* NMTIMES *)    

apply(simp add: nullable_correctness del: Der_UNION)

apply(rule impI)

apply(rule conjI)

apply(rule impI)

apply(subst Sequ_Union_in)

apply(subst Der_Pow_Sequ[symmetric])

apply(subst Pow.simps[symmetric])

apply(subst Der_UNION[symmetric])

apply(case_tac x3a)

apply(simp)

apply(clarify)

apply(auto simp add: Sequ_def Der_def Cons_eq_append_conv)[1]

apply(rule_tac x="Suc xa" in bexI)

apply(auto simp add: Sequ_def)[2]

apply (metis append_Cons)

apply (metis (no_types, hide_lams) Pow_decomp atMost_iff diff_Suc_eq_diff_pred diff_is_0_eq)

apply(rule impI)+

apply(subst Sequ_Union_in)

apply(subst Der_Pow_Sequ[symmetric])

apply(subst Pow.simps[symmetric])

apply(subst Der_UNION[symmetric])

apply(case_tac x2)

apply(simp)

apply(simp del: Pow.simps)

apply(auto simp add: Sequ_def Der_def)

apply (metis One_nat_def Suc_le_D Suc_le_mono atLeastAtMost_iff diff_Suc_1 not_le)

by fastforce

lemma ders_correctness:

  shows "L (ders s r) = Ders s (L r)"

by (induct s arbitrary: r)

   (simp_all add: Ders_def der_correctness Der_def)

section {* Values *}

datatype val = 

  Void

| Char char

| Seq val val

| Right val

| Left val

| Stars "val list"

section {* The string behind a value *}

fun 

  flat :: "val \<Rightarrow> string"

where

  "flat (Void) = []"

| "flat (Char c) = [c]"

| "flat (Left v) = flat v"

| "flat (Right v) = flat v"

| "flat (Seq v1 v2) = (flat v1) @ (flat v2)"

| "flat (Stars []) = []"

| "flat (Stars (v#vs)) = (flat v) @ (flat (Stars vs))" 

abbreviation

  "flats vs \<equiv> concat (map flat vs)"

lemma flat_Stars [simp]:

 "flat (Stars vs) = flats vs"

by (induct vs) (auto)

lemma Star_concat:

  assumes "\<forall>s \<in> set ss. s \<in> A"  

  shows "concat ss \<in> A\<star>"

using assms by (induct ss) (auto)

lemma Star_cstring:

  assumes "s \<in> A\<star>"

  shows "\<exists>ss. concat ss = s \<and> (\<forall>s \<in> set ss. s \<in> A \<and> s \<noteq> [])"

using assms

apply(induct rule: Star.induct)

apply(auto)[1]

apply(rule_tac x="[]" in exI)

apply(simp)

apply(erule exE)

apply(clarify)

apply(case_tac "s1 = []")

apply(rule_tac x="ss" in exI)

apply(simp)

apply(rule_tac x="s1#ss" in exI)

apply(simp)

done

lemma Aux:

  assumes "\<forall>s\<in>set ss. s = []"

  shows "concat ss = []"

using assms

by (induct ss) (auto)

lemma Pow_cstring_nonempty:

  assumes "s \<in> A \<up> n"

  shows "\<exists>ss. concat ss = s \<and> length ss \<le> n \<and> (\<forall>s \<in> set ss. s \<in> A \<and> s \<noteq> [])"

using assms

apply(induct n arbitrary: s)

apply(auto)

apply(simp add: Sequ_def)

apply(erule exE)+

apply(clarify)

apply(drule_tac x="s2" in meta_spec)

apply(simp)

apply(clarify)

apply(case_tac "s1 = []")

apply(simp)

apply(rule_tac x="ss" in exI)

apply(simp)

apply(rule_tac x="s1 # ss" in exI)

apply(simp)

done

lemma Pow_cstring:

  assumes "s \<in> A \<up> n"

  shows "\<exists>ss1 ss2. concat (ss1 @ ss2) = s \<and> length (ss1 @ ss2) = n \<and> 

         (\<forall>s \<in> set ss1. s \<in> A \<and> s \<noteq> []) \<and> (\<forall>s \<in> set ss2. s \<in> A \<and> s = [])"

using assms

apply(induct n arbitrary: s)

apply(auto)[1]

apply(simp only: Pow_Suc_rev)

apply(simp add: Sequ_def)

apply(erule exE)+

apply(clarify)

apply(drule_tac x="s1" in meta_spec)

apply(simp)

apply(erule exE)+

apply(clarify)

apply(case_tac "s2 = []")

apply(simp)

apply(rule_tac x="ss1" in exI)

apply(rule_tac x="s2#ss2" in exI)

apply(simp)

apply(rule_tac x="ss1 @ [s2]" in exI)

apply(rule_tac x="ss2" in exI)

apply(simp)

apply(subst Aux)

apply(auto)[1]

apply(subst Aux)

apply(auto)[1]

apply(simp)

done

section {* Lexical Values *}

inductive 

  Prf :: "val \<Rightarrow> rexp \<Rightarrow> bool" ("\<Turnstile> _ : _" [100, 100] 100)

where

 "\<lbrakk>\<Turnstile> v1 : r1; \<Turnstile> v2 : r2\<rbrakk> \<Longrightarrow> \<Turnstile>  Seq v1 v2 : SEQ r1 r2"

| "\<Turnstile> v1 : r1 \<Longrightarrow> \<Turnstile> Left v1 : ALT r1 r2"

| "\<Turnstile> v2 : r2 \<Longrightarrow> \<Turnstile> Right v2 : ALT r1 r2"

| "\<Turnstile> Void : ONE"

| "\<Turnstile> Char c : CHAR c"

| "\<lbrakk>\<forall>v \<in> set vs. \<Turnstile> v : r \<and> flat v \<noteq> []\<rbrakk> \<Longrightarrow> \<Turnstile> Stars vs : STAR r"

| "\<lbrakk>\<forall>v \<in> set vs. \<Turnstile> v : r \<and> flat v \<noteq> []; length vs \<le> n\<rbrakk> \<Longrightarrow> \<Turnstile> Stars vs : UPNTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs1. \<Turnstile> v : r \<and> flat v \<noteq> []; 

    \<forall>v \<in> set vs2. \<Turnstile> v : r \<and> flat v = []; 

    length (vs1 @ vs2) = n\<rbrakk> \<Longrightarrow> \<Turnstile> Stars (vs1 @ vs2) : NTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs1. \<Turnstile> v : r  \<and> flat v \<noteq> []; 

    \<forall>v \<in> set vs2. \<Turnstile> v : r \<and> flat v = []; 

    length (vs1 @ vs2) = n\<rbrakk> \<Longrightarrow> \<Turnstile> Stars (vs1 @ vs2) : FROMNTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs. \<Turnstile> v : r  \<and> flat v \<noteq> []; length vs > n\<rbrakk> \<Longrightarrow> \<Turnstile> Stars vs : FROMNTIMES r n"

| "\<lbrakk>\<forall>v \<in> set vs1. \<Turnstile> v : r \<and> flat v \<noteq> [];

    \<forall>v \<in> set vs2. \<Turnstile> v : r \<and> flat v = []; 

    length (vs1 @ vs2) = n; length (vs1 @ vs2) \<le> m\<rbrakk> \<Longrightarrow> \<Turnstile> Stars (vs1 @ vs2) : NMTIMES r n m"

| "\<lbrakk>\<forall>v \<in> set vs. \<Turnstile> v : r \<and> flat v \<noteq> [];

    length vs > n; length vs \<le> m\<rbrakk> \<Longrightarrow> \<Turnstile> Stars vs : NMTIMES r n m"

inductive_cases Prf_elims:

  "\<Turnstile> v : ZERO"

  "\<Turnstile> v : SEQ r1 r2"

  "\<Turnstile> v : ALT r1 r2"

  "\<Turnstile> v : ONE"

  "\<Turnstile> v : CHAR c"

  "\<Turnstile> vs : STAR r"

  "\<Turnstile> vs : UPNTIMES r n"

  "\<Turnstile> vs : NTIMES r n"

  "\<Turnstile> vs : FROMNTIMES r n"

  "\<Turnstile> vs : NMTIMES r n m"

lemma Prf_Stars_appendE:

  assumes "\<Turnstile> Stars (vs1 @ vs2) : STAR r"

  shows "\<Turnstile> Stars vs1 : STAR r \<and> \<Turnstile> Stars vs2 : STAR r" 

using assms

by (auto intro: Prf.intros elim!: Prf_elims)